Conversion Année/centième vers Année/Mois/jour

[GTA]

Bonjour,

Je souhaiterais pourvoir convertir le contenu de cellules contenant des valeurs en centièmes de type 50,77 qui représente une valeur en années soit 50 années et 0,77 année.

Comment peut-on convertir cette valeur 50,77 en Année / Mois et éventuellement les jours ? soit si mon calcul est juste : 50 ans, 9 mois et 7 jours ??

Merci d'avance pour vos réponses...

 

[tototiti2008]

Re : Conversion Année/centième vers Année/Mois/jour

Bonjour GTA,

Si 50,77 en C18

Années en D18 :

=ENT(C18)

Mois en E18 :

=ENT((C18-D18)*365,25/30)

Jours en F18 :

=ENT((C18-D18)*365,25-E18*30)

Sur une approximation de 365.25 jours par an et 30 jours par mois

 

[GTA]

Re : Conversion Année/centième vers Année/Mois/jour

Merci pour cette réponse rapide qui correspond tout à fait à mes attentes.

Pour un résultat cumulé dans la même cellule, j'ajoute simplement le caractère "&" entre les différentes formules ??

 

[hoerwind]

Re : Conversion Année/centième vers Année/Mois/jour

Bonjour,

Cela n'est possible que sur base d'une explications complémentaire.
0,77 d'une année bissextile ne renvoie pas le même résultat que pour une année non bissextile.
A moins qu'il faut tenir compte d'années de 360 jours, donc 12 mois de 30 jours.

Pour ton exemple, j'obtiens un autre résultat.
0,77 d'une année de 365 jours est égal à 281,05 jours (365*0,77) soit pour 2011 : 9 mois 9 jours 1 heure et 12 minutes

 

[tototiti2008]

Re : Conversion Année/centième vers Année/Mois/jour

Bonjour hoerwind 🙂,
Re,

@hoerwind : Tu as tout à fait raison, d'ailleurs si je considère 365,25 jours par an, je devrais plutôt faire une approximation à 30,4375 jours par mois... mais de toutes façons ce ne pourront être que des approximations

@GTA :

Pour un résultat cumulé dans la même cellule, j'ajoute simplement le caractère "&" entre les différentes formules ??

Euh, non, les formules sont en cascade et dépendent les unes des autres, pour tout regrouper dans la même cellule ça les complique un peu
Essaye de comprendre leur principe, et dis-nous sur quelle approximation tu souhaites travailler

 

[hoerwind]

Re : Conversion Année/centième vers Année/Mois/jour

Re, salut tototiti (pas vu au premier passage !)

Un essai de formule :
A1 : 50,77
=ENT(A1)&" années "&MOIS(365*MOD(A1;1))-1&" mois et "&JOUR(365*MOD(A1;1))+1&" jours"
on peut remplacer 365 par 365,25

 

[GTA]

Re : Conversion Année/centième vers Année/Mois/jour

Les valeurs sur lequelles je travaille sont des valeurs moyennes donc je n'ai pas forcément besoin de tenir compte des années bisextiles. Je considère que l'année fait 360 jours et qu'un mois compte trente jours. De plus, je n'ai finalement pas besoin des heures.

La formule ci-dessous (qui n'est peut-être pas la plus "belle"me donne un résultat satisfaisant :
=ENT(A1)&" ans,"&" " &ENT((A1-ENT(A1))*12)&" mois et "&ENT((((A1-ENT(A1))*12)-C1)*30)&" jours"
C1 contenant =ENT((A1-ENT(A1))*12)

Merci en tout cas pour vos réponses rapides...

 

[tototiti2008]

Re : Conversion Année/centième vers Année/Mois/jour

Re,

Bien vu, beaucoup plus court que ma proposition (Bizarre comment je peux oublier la fonction MOD quand je ne l'utilise plus pendant un certain temps 😉)
Si je comprend le -1 sur le mois (MOIS(365*MOD(A1;1))-1), je ne comprend pas bien le +1 sur le jour (JOUR(365*MOD(A1;1))+1), peux-tu m'expliquer ?

Edit : GTA, utilises plutôt la proposition d'hoerwind, c'est bien plus court

 

[hoerwind]

Re : Conversion Année/centième vers Année/Mois/jour

Salut tototiti,

Le -1 pour le mois parce que la formule renvoie une date : 07/10/1900, donc 9 mois (entiers) et 7 jours, là tu l'avais compris !
Le +1 pour le jour parce que Excel considère l'année 1900 comme bissextile (grosse erreur !), il faut donc enlever ce 29 février qui n'existe pas.

Pour être tout à fait correct, il faudrait ne pas ajouter ce jour si le résultat est inférieur à 1 mois et 29 jours, par exemple pour 50,15
On peut remplacer le +1 par +MOD(A1;1)>0,1616 ou 59/365

 

[tototiti2008]

Re : Conversion Année/centième vers Année/Mois/jour

Re,

Merci de ta réponse
ça y est, je me souviens : Excel considère qu'il y a un 29/02/1900, Et VBA pas... Les mystères de la gestion des dates chez Microsoft 😉