XL 2016 Conception et faisabilité

[Neo Hyuga]

Hello chers ami(e)s,

je reviens vers vous aujourd'hui pour un nouveau souci.

Ci joint un fichier exemple

Cadre : Excel 2016, sans macro ni vba, car desactivés (raison pro)
Probleme : Comment faire pour que sur le tableau 1 de ma feuille 1, dès qu'il y a la valeur "Hs", toute la ligne qui le contient, soit automatiquement reporté dans le tableau 2 sur la feuille 2 svp ?

Merci d'avance,

Cordialement

Ps : petite subtilité, une cellule par ligne du tableau 1 contient une photo (je pense "objet" mais pas sur), comment faire pour qu'elle soit reporté aussi automatiquement svp ?

 

[sylvanu]

Bonsoir Neo Hyuga,
Un essai en PJ avec :
- une colonne supplémentaire dans le ^premier tableau :

=NB.SI(Tableau1[[#Cette ligne];[table]:[muche]];"Hs")

- une formule de ce type dans le second tableau :

=SIERREUR(INDEX(Tableau1[table];PETITE.VALEUR(SI(Tableau1[Transfert]=1;LIGNE(INDIRECT("1:"&LIGNES(Tableau1[table]))));LIGNES(Feuil1!$1:1)));"")

A valider par Maj+Ctrl+Entrée car matricielle, sauf pour les dernières versions d'XL.
Pour les images, désolé je ne sais pas faire hors VBA.

 

[Neo Hyuga]

enorme, c'est parfait merci beaucoup

juste pour ma gouverne, la premiere formule nb.si sert a distinguer la valeur cherché "Hs" ?

et la seconde formule va chercher le resultat de la premiere formule, mais, et c'est la ma limite de connaissance, quel role a la formule indirect ?
je pense avoir compris a peu pres le reste.
merci a nouveau

 

[sylvanu]

la premiere formule nb.si sert a distinguer la valeur cherché "Hs" ?

Exact, cela permet d'avoir qu'un seul vecteur de recherche, en l'occurrence "1" dans la colonne Transfert.

quel role a la formule indirect ?

Indirect permet de reconstituer une chaine qui sera interprété par XL comme l'adresse d'une cellule.

Fonction INDIRECT - Support Microsoft

Comment utiliser la fonction INDIRECT dans Excel pour modifier la référence à une cellule dans une formule sans modifier la formule elle-même.

support.microsoft.com

 

[job75]

Bonsoir,

@sylvanu la colonne supplémentaire dans le 1er tableau n'est pas nécessaire, matricielle en E4 :

=SIERREUR(INDEX(Tableau1[table];PETITE.VALEUR(SI(Tableau1="Hs";LIGNE(Tableau1)-4);LIGNE(E1)));"")

A+

 

[job75]

Il vaut mieux cette formule matricielle en E4 car elle peut être tirée sur la droite :

=SIERREUR(INDEX(Feuil1!E:E;PETITE.VALEUR(SI(Tableau1="Hs";LIGNE(Tableau1));LIGNE(E1)));"")

 

[AtTheOne]

Bonsoir à toutes & à tous, bonsoir @Neo Hyuga , @sylvanu , @job75,
Bon j'y vais de mon petit apport pour éviter la validation par CTRL MAJ ENTREE et n'avoir qu'une seule formule. Avec E4 sélectionnée je crée le nom (J'aime bien les noms) :

Liste_Hs =SIERREUR(INDEX(INDIRECT("Tableau1["&Tableau2[#En-têtes] Feuil2!E:E&"]");PETITE.VALEUR(SI(Tableau1="Hs";LIGNE(Tableau1)-LIGNE(Tableau1[#En-têtes]));LIGNE(Feuil2!E1)));"")

INDIRECT("Tableau1["&Tableau2[#En-têtes] Feuil2!E:E&"]") permet de lire l'entête de la colonne en cours, le reste c'est votre solution.
Saisir =Liste_Hs en E4, puis tirer sur la droite, je ne sais pas pourquoi avec 2007, j'ai dû étendre vers le bas (double clic sur le petit carré noir en bas à droite) ...

A bientôt

 

[job75]

Bonjour AtTheOne, le forum,

Pour éviter la validation matricielle il suffit de définir le nom Matrice par :

=SI(Tableau1="Hs";LIGNE(Tableau1))

La formule en E4 devient :

=SIERREUR(INDEX(Feuil1!E:E;PETITE.VALEUR(Matrice;LIGNE(E1)));"")

A+

 

[Neo Hyuga]

hello les amis,

comme d'hab j ai fait un mix de tout vos solutions et ca a bien aidé a resoudre mon dilemne,

un grand merci a vous tous

ps : je met le post de Sylvanu pour le "resolu" mais c'est grace a votre esprit d'equipe surtout,

encore merci