concaténer un nombre entier sur plusieurs cellules

diouri lahsen · 1 Janvier 2011

Bonsoir tous le monde

Je cherche une formule pour concaténer un nombre entier sur plusieurs cellules c'est à dire un chiffe par cellule, et une autre pour écrire une date en toute lettre.

Merci pour votre aide

Tibo · 1 Janvier 2011

Re : concaténer un nombre entier sur plusieurs cellules

Bonsoir,

Pour décomposer le montant, une solution parmi d'autres :

en F4 :

Code:

=STXT(TEXTE($F$6;"000000");COLONNES($A:A);1)

Pour écrire la date en toutes lettres, une formule "un peu" longue :

en E12 :

Code:

=TEXTE(date;"jj mmmm")&" "&CHOISIR(ANNEE(D12)/1000;"";"deux ";"trois ";"quatre ";"cinq ";"six ";"sept ";"huit ";"neuf ")&"mille"&" "&SI(DROITE(ANNEE(D12);3)*1>99;CHOISIR(DROITE(ANNEE(D12);3)/100;"";"deux ";"trois ";"quatre ";"cinq ";"six ";"sept ";"huit ";"neuf ")&"cent"&SI(DROITE(ANNEE(D12);3)*1>100;SI(DROITE(ANNEE(D12);2)*1=0;"s";" "););)&CHOISIR(DROITE(ANNEE(D12);2)/10+1;"";"";"vingt";"trente";"quarante";"cinquante";"soixante";"soixante";"quatre-vingt"&SI(DROITE(ANNEE(D12))*1=0;"s";);"quatre-vingt")&SI(DROITE(ANNEE(D12);2)*1<20;"";SI(ET(OU(DROITE(ANNEE(D12))*1<>0;DROITE(ANNEE(D12);2)*1=70;DROITE(ANNEE(D12);2)*1=90));SI(ET(DROITE(ANNEE(D12))*1=1;DROITE(ANNEE(D12);2)*1<80);" et ";"-");""))&CHOISIR(DROITE(ANNEE(D12);2)*1-CHOISIR(DROITE(ANNEE(D12);2)/10+1;0;0;2;3;4;5;6;6;8;8)*10+1;"";"un";"deux";"trois";"quatre";"cinq";"six";"sept";"huit";"neuf";"dix";"onze";"douze";"treize";"quatorze";"quinze";"seize";"dix-sept";"dix-huit";"dix-neuf")

Je joins le fichier avec les formules proposées.

@+

Edit : En ce qui concerne la date, pour avoir l'affichage 1er pour le premier jour de chaque mois, on peut modifier le début de la formule ainsi :

Code:

=JOUR(D12)&SI(JOUR(D12)=1;"er ";" ")&TEXTE(date;"mmmm")&" "&CHOISIR(.....

@+

Softmama · 1 Janvier 2011

Re : concaténer un nombre entier sur plusieurs cellules

Bonjour,

Pour la première partie, tu peux taper dans une cellule pour avoir le nbre:

Code:

=CNUM(F4&G4&H4&I4&J4&K4)

hoerwind · 2 Janvier 2011

Re : concaténer un nombre entier sur plusieurs cellules

Bonjour, salut Tibo et Softmama, bonne année à tous,

Pour écrire la date en toutes lettres, en faisant appel pour l'année à une fonction de Morefunc (à télécharger gratuitement sur le Net) :

Code:

="le "&JOUR(D12)&SI(JOUR(D12)=1;"er ";" ")&TEXTE(MOIS(D12);"mmmm")&" "&MINUSCULE(NBTEXTE(ANNEE(D12)))

concaténer un nombre entier sur plusieurs cellules

diouri lahsen

XLDnaute Nouveau

Pièces jointes

Tibo

XLDnaute Barbatruc

Pièces jointes

Softmama

XLDnaute Accro

hoerwind

XLDnaute Barbatruc

Discussions similaires