Compter le nombre de "X" qui se suivent...

Option Explicit 'pour forcer la déclaration de variable
Option Base 1 ' pour dire que les tableaux commence à 1 et pas à zero

Function nb_maxi(valeur As String, tableau_recherche) As Integer
'déclaration des variables
Dim i As Integer, j As Integer, nb As Integer, maxi As Integer
'i : un pointeur pour parcourir le tableau "tableau_recherche"
'j : variable intermédiaire elle représente le nombre maximum trouvé jusqu'à i
'nb : représente le nombre de ligne du tableau "tableau_recherche"
'maxi : nombre de rencontre maximale

  ' repérage du nombre de ligne
  nb = UBound(tableau_recherche.Value, 1)
  'mise à zéro des maximetres
  j = 0
  maxi=0  ' un oubli dans le fichier mais pas grave car la variable est automatiquement mis à 0 quand elle est déclarer en integer

  'boucle de parcour du tableau
  For i = 1 To nb
    ' test : c'est sur cette ligne que l'on fait ce que l'on veut
    ' dans cette fonction je recherche le nombre maxi de fois où "valeur" est à la suite
    If tableau_recherche(i, 1).Value = valeur Then
      ' quand le test si dessus est bon on incrémente la valeur intermédiaire "j"
      j = j + 1
      If j > maxi Then maxi = j ' on test si la valeur intermédiaire "j" est supérieur à la "maxi" si c'est le cas alors on met la valeur de "j" dans "maxi"
    Else
      ' si le test n'est pas bon alors on remet la valeur "j" à 0
      j = 0
    End If
  Next i
  ' on renvoi la variable "maxi"
  nb_maxi = maxi
End Function

Sub CompteZonesA()Sub CompteZonesA()
Call Calcul("A", "avec A")
End Sub

Sub CompteZonesSansA()
Call Calcul("<>A", "sans A")
End Sub

Sub Calcul(crit$, txt$)
Dim reference$, n As Long, mini As Long, maxi As Long

ActiveSheet.AutoFilterMode = False
Range("B1").AutoFilter Field:=2, Criteria1:=crit
reference = Range("B2:B" & Range("B65536").End(xlUp).Row).SpecialCells(xlVisible).Address
Range("B1").AutoFilter

n = UBound(Split(reference, ","))
mini = 9 ^ 9
maxi = 0

For i = 0 To n
mini = Application.Min(mini, Range(Split(reference, ",")(i)).Cells.Count)
maxi = Application.Max(maxi, Range(Split(reference, ",")(i)).Cells.Count)
Next

MsgBox Chr(10) & "Nombre de zones  " & txt & " : " & n + 1 & Chr(10) & _
Chr(10) & "Nombre minimum par zone : " & mini & Chr(10) & _
Chr(10) & "Nombre maximum par zone : " & maxi & "   " & Chr(10)


End Sub

Public Function Gw_Freq(MaPlage As Range, ByVal Mavaleur As Variant, Optional signe As String = "=") As Variant
    Dim tablo1() As Boolean ' définir un tableau qui pred Vrai ou Faux selon le resultat du test
    Dim tablo2() As Long ' Récupère pour chacune des fréquences le nombre de valeurs qui se suivent
    Dim i As Long, j As Long, k As Long, total As Long ' diférents pointeur pour boucles
    Dim lig As Long, col As Long ' le suivi des lignes et colonnes
    Application.Volatile
    Dim cel As Range
    i = -1
    For col = 1 To MaPlage.Columns.Count ' Boucle sur les colonnes
        For lig = 1 To MaPlage.Rows.Count ' Boucle sur les lignes
            Set cel = MaPlage(1, 1).Offset(lig - 1, col - 1) ' recupération de la cellule
            i = i + 1 ' evolution de la table
            ReDim Preserve tablo1(i) ' Agrandissement de la table
            tablo1(i) = False ' initialiser à faux
            Select Case signe ' Gestion du signe, la valeur de la table passe à Vrai si condition ok
                Case "="
                    If cel.Value = Mavaleur Then tablo1(i) = True
                Case ">"
                    If cel.Value > Mavaleur Then tablo1(i) = True
                Case "<"
                    If cel.Value < Mavaleur Then tablo1(i) = True
                Case "<>", "><"
                    If cel.Value <> Mavaleur Then tablo1(i) = True
                Case ">=", "=>"
                    If cel.Value >= Mavaleur Then tablo1(i) = True
                Case "<=", "=<"
                    If cel.Value <= Mavaleur Then tablo1(i) = True
            End Select
        Next lig ' Prochaine ligne
    Next col ' Prochaine colonne
    total = 0: k = -1 ' Initialisation des pointeurs
    For j = 0 To i ' On relis la table en mémoire (les vrais et les faux)
        If tablo1(j) = False Then ' Si c'est faux, on va charger la table de resultat
            If total > 0 Then ' Mais seulement s'il y a une valeur dans le total
                k = k + 1 ' pointeur table
                ReDim Preserve tablo2(k) ' redimensionnement de la table
                tablo2(k) = total ' mise en place de la valeur
                total = 0 ' remise à zero
            End If
        Else ' la valeur est vrai, j'incrémente le total de 1
            total = total + 1
        End If
    Next
    If total > 0 Then ' je teste si le total est > 1 dans le cas ou la colonne se termine par une valeur cherchée
        k = k + 1 ' incremente la table
        ReDim Preserve tablo2(k) ' agrandissement de la table
        tablo2(k) = total ' mise en place de la valeur
        total = 0 ' remise à zéro, pas vraiment utile ici, mais c'est un tic de ma part
    End If
    Gw_Freq = tablo2 ' transfert de la table dans la fonction pour utilisation
End Function

=gw_freq(Maplage;MaValeur;[Signe])