Compter le nombre de lettres dans une cellule

[patrick wargnier]

Bonsoir a tous
dans la cellule C1
j'ai marqué le mot kangourou
donc je voudrai une formule dans la cellule D1
qui me marque 1 si dans la cellule C1 il me trouve au
moin une lettre
z ou y ou q ou j ou k ou w ou x ou j

merci de votre aide et a ce soir trés trés tard dans la soirée
pour vous repondre ci cela me convient ou pas !

 

[tototiti2008]

Re : Compter le nombre de lettres dans une cellule

Bonjour patrick,

peut-être :

=ESTNUM(CHERCHE("z";C1))+ESTNUM(CHERCHE("y";C1))+ESTNUM(CHERCHE("q";C1))+ESTNUM(CHERCHE("j";C1))+ESTNUM(CHERCHE("k";C1))+ESTNUM(CHERCHE("w";C1))+ESTNUM(CHERCHE("x";C1))

 

[job75]

Re : Compter le nombre de lettres dans une cellule

Bonjour Patrick, tototiti,

Comme tototiti, avec SIGNE en plus :

=SIGNE(ESTNUM(CHERCHE("j";C1))+ESTNUM(CHERCHE("k";C1))+ESTNUM(CHERCHE("q";C1))+ESTNUM(CHERCHE("w";C1))+ESTNUM(CHERCHE("x";C1))+ESTNUM(CHERCHE("y";C1))+ESTNUM(CHERCHE("z";C1)))

Et mettre D1 au format personnalisé 0;; si l'on ne veut pas afficher 0.

A+

 

[patrick wargnier]

Re : Compter le nombre de lettres dans une cellule

Rebonsoir
merci Tototiti 2008
c'etait bien ca que je voulais ca marche a merveille !
et encore merci a tous !
bonne soirée

 

[patrick wargnier]

Re : Compter le nombre de lettres dans une cellule

Rebonsoir
merci aussi a JOB 75
ca marche aussi votre formule
=SIGNE(ESTNUM(CHERCHE("j";C1))+ESTNUM(CHERCHE("k";C1))+ESTNUM(CHERCHE("q";C1))+ESTNUM(CHERCHE("w";C1))+ESTNUM(CHERCHE("x";C1))+ESTNUM(CHERCHE("y";C1))+ESTNUM(CHERCHE("z";C1)))
bonne soiée encore a vous tous !

 

[job75]

Re : Compter le nombre de lettres dans une cellule

Re,

Plus simple je pense :

=SIGNE(SOMMEPROD(1*ESTNUM(CHERCHE({"j";"k";"q";"w";"x";"y";"z"};C1))))

A+

 

[JCGL]

Re : Compter le nombre de lettres dans une cellule

Bonjour à tous,

Un essai avec :

=NB(CHERCHE({"j";"k";"q";"w";"x";"y";"z"};C1))

A+ à tous

Edition : cette formule compte le nombre de fois où les lettres données apparaissent comme le titre le demandait... Mais l'énoncé demandait "simplement" de mettre 1 ou 0 si la condition était remplie. Bravo Job et JB

 

[BOISGONTIER]

Re : Compter le nombre de lettres dans une cellule

Bonsoir,

=SI(ESTNUM(EQUIV(1;EQUIV("*"&{"z";"y";"q";"k";"w";"x";"j"}&"*";A1;0);0));1;0)

JB