comptage des écarts +1 et -1

[JJ1]

Bonjour à tous,
Je souhaiterais une aide pour une formule qui compterait les écart +1 et -1 sur une ligne par rapport à la ligne précédente.
Je joins un exemple simple.
merci et bon samedi

 

[Jiheme]

Re : comptage des écarts +1 et -1

Bonjour JJ1, re à tous

Je ne suis vraiment pas sûr d'avoir tout compris mais au cas où essaies la formule :

=SI(A1>B2;B2-A1;A1-B2)

Sinon essaies d'être plus clair, mon neurone est épuisé à la fin de cette période.

A+

 

[JJ1]

Re : comptage des écarts +1 et -1

Bonjour Jiheme,
merci pour ta réponse, je voudrais connaitre le total de nombres par ligne +1 et -1 par rapport à la ligne précédente
Je joins une ligne supplémentaire dans l'ex.
merci

 

[wilfried_42]

Re : comptage des écarts +1 et -1

Bonjour jj1, jiheme

je ne sais pas si j'ai tout compris, j'ai essayé avec des matricielles et je n'ai pas trouvé alors j'ai fait le gros boeuf

en d1 :

=NB.SI(A2:C2;A1-1)+NB.SI(A2:C2;B1-1)+NB.SI(A2:C2;C1-1)

en e1 :

=NB.SI(A2:C2;A1+1)+NB.SI(A2:C2;B1+1)+NB.SI(A2:C2;C1+1)

Bon weekend


Edit : Hic pas vu ton dernier message, j'ai fait par rapport à la ligne suivante (formule à adapter)

 

[wilfried_42]

Re : comptage des écarts +1 et -1

re:

à adapter, formule matricielle (à valider avec Ctrl Shift Entrée)

en D1 : =SOMME(NB.SI(A2:C2;A1:C1-1))
en E1 : =SOMME(NB.SI(A2:C2;A1:C1+1))

 

[JJ1]

Re : comptage des écarts +1 et -1

Bonjour Wilfried,
Moi aussi j'ai commencé avec ta méthode (et vite abandonné !) mais je pensais à simplifier par un sommeprod par ex?
Ici il n'y a que 3 colonnes mais avec 7 c'est pas évident car il faut comparer la 1ère colonne dessous avec les 7 au dessus , puis la 2ème dessous avec les 7 au dessus...........tu vois le nombre de comparaisons!!
Bonne journée et merci

 

[JJ1]

Re : comptage des écarts +1 et -1

Re,
On s'est croisé....
J'essaye ta formule matricielle.
Merci

 

[wilfried_42]

Re : comptage des écarts +1 et -1

re:

on a posté en meme temps : voir formule matricielle juste au dessus

 

[JJ1]

Re : comptage des écarts +1 et -1

Ta formule marche super!
Bon samedi et à bientôt

 

[JeanMarie]

Re : comptage des écarts +1 et -1

Bonsoir JJ1, Jiheme, Wilfried

Même si je trouve la solution de wilfried parfaite, voici une autre possibilité avec l'utilisation de FREQUENCE et de TRANPOSE.

=TRANSPOSE(FREQUENCE(TRANSPOSE(A2:C2)-A1:C1;{-1;1;0;-2}))

Pour la mettre en application :
1) Sélectionner la plage D2:E2
2) Saisir la formule dans la zone de la barre de formule
3) valider par les touches Ctrl+Shift+Entrer

Quelques explications :

En lisant les très succinctes explications de JJ1 dans son premier post, j'avais commencé à écrire la formule sous cette forme.

=TRANSPOSE(FREQUENCE(A2:C2-A1:C1;{-1;1;0;-2}))

A2:C2-A1:C1 retourne une matrice retournant l'écart entre la première valeur de la plage A2:C2 et la première valeur de la plage A1:C1, puis celle de la deuxième valeur des deux plages, et pour finir de la troisième valeur.
Nous aurions eu une matrice correspondant à {=A2-A1;=B2-B1;=C2-C1}.

Pour suivre l'évolution des explications de JJ1.
Pour calculer l'écart entre la première valeur de la plage A2:C2, par rapport à l'ensemble des valeurs de la plage A1:C1, il faut passer la matriceX en une matriceXY, c'est le rôle de la fonction TRANSPOSE(A2:C2)-A1:C1.

On pourrait la dessiner sous cette forme

  |     A      |     B      |     C      |     D      | 
--|------------|------------|------------|------------|-
 1|            |     3      |     6      |     8      | 
 2|          1 | =$A2-B$1   | =$A2-C$1   | =$A2-D$1   | 
 3|          2 | =$A3-B$1   | =$A3-C$1   | =$A3-D$1   | 
 4|          9 | =$A4-B$1   | =$A4-C$1   | =$A4-D$1   |

On m'avait montrer l'utilisation du TRANSPOSE sur le site de mDF ici

- FREQUENCE comptabilise le nombre de valeurs égales à -1, à 1, à 0, et inférieure à -1. Les deux valeurs 0 et -2 sont nécessaires, elles permettent de ne pas comptabiliser le 0 comme un 1 et les valeurs inférieures à -1 comme des -1. Les valeurs supérieures à 1 étant comptabilisées dans une tranche "infini". Comme le montre cet exemple il n'est nul besoin que les données de la 2ème plage soient triées.

- FREQUENCE retourne une matrice sous forme verticale, pour la basculer sous forme horizontale on utilise la fonction TRANSPOSE.

- En sélectionnant que deux cellules lors de la validation de la formule on écarte dû coup les valeurs suivantes de la matrice.

Vous pouvez aussi retrouver un autre fil utilisant cette fonction de matriceXY ici

Une petite remarque qui s'adresse à JJ1, à l'avenir adresse nous des explications plus détaillées. Une ligne, franchement c'est un peu se moquer des personnes qui te répondent, et comme moi qui te fournissent des explications.

Petit conseil en passant, essaye de mettre en application les différentes fonctions que nous te donnons, avant de soumettre ton problème sur le forum. C'est comme cela que tu vas progresser.

Si tu as des questions, n'hésite pas à demander, c'est justement le rôle d'un forum, "expliquer", et non donner une formule toute faîte.

Bonne fin de week-end.

@+Jean-Marie