Compiler feuilles

[s2fruit]

Bonjour à tous 😉
Pouvez-vous me donner un début de piste pour mon fichier ?
Je souhaiterai si possible à l'aide d'une macro rapatrier toutes données de mes feuilles sur une feuille Récapitulative et trier le résultat par ordre croissant sur la 1er colonne.
Un grand MERCI pour votre aide.

 

[JCGL]

Re : Feuille Récapitulative

Bonjour à tous,

Pas de début de piste sans fichier joint...
Ta demande est trop absconse pour avoir une réponse.


A+ à tous

 

[s2fruit]

Re : Feuille Récapitulative

Pardon pour cet oubli 🙄
Merci JCGL

 

[s2fruit]

Re : Compiler feuilles

Pouvez vous me dire si je suis sur la bonne piste ?
Y'a t'il plus simple ?
MERCI

Sub RECAP()
'
' RECAP Macro
'

'
Sheets("AA").Select
Range("A3:M103").Select
Selection.Copy
Sheets("RECAPITULATIF").Select
Selection.PasteSpecial Paste:=xlPasteAll, Operation:=xlNone, SkipBlanks:= _
False, Transpose:=False

Sheets("BB").Select
Range("A3:M103").Select
Application.CutCopyMode = False
Selection.Copy
Sheets("RECAPITULATIF").Select
Range("A104").Select
Selection.PasteSpecial Paste:=xlPasteAll, Operation:=xlNone, SkipBlanks:= _
False, Transpose:=False

Sheets("CC").Select
Range("A3:M103").Select
Application.CutCopyMode = False
Selection.Copy
Sheets("RECAPITULATIF").Select
Range("A205").Select
Selection.PasteSpecial Paste:=xlPasteAll, Operation:=xlNone, SkipBlanks:= _
False, Transpose:=False

Sheets("DD").Select
Range("A3:M103").Select
Application.CutCopyMode = False
Selection.Copy
Sheets("RECAPITULATIF").Select
Range("A306").Select
Selection.PasteSpecial Paste:=xlPasteAll, Operation:=xlNone, SkipBlanks:= _
False, Transpose:=False

Sheets("EE").Select
Range("A3:M103").Select
Application.CutCopyMode = False
Selection.Copy
Sheets("RECAPITULATIF").Select
Range("A407").Select
Selection.PasteSpecial Paste:=xlPasteAll, Operation:=xlNone, SkipBlanks:= _
False, Transpose:=False
Range("A2:M507").Select
Application.CutCopyMode = False
ActiveWorkbook.Worksheets("RECAPITULATIF").Sort.SortFields.Clear
ActiveWorkbook.Worksheets("RECAPITULATIF").Sort.SortFields.Add Key:=Range( _
"A2"), SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:= _
xlSortNormal
With ActiveWorkbook.Worksheets("RECAPITULATIF").Sort
.SetRange Range("A3:M507")
.Header = xlNo
.MatchCase = False
.Orientation = xlTopToBottom
.SortMethod = xlPinYin
.Apply
End With
End Sub

 

[camarchepas]

Re : Compiler feuilles

Bonjour S2Fruit,

Salutations JC,

un code sans pépin ....

Sub synthese()
 Dim Onglet As Worksheet
 Dim LigneFin As Long, LigneCible As Long
'Assemblage des onglets
 For Each Onglet In ThisWorkbook.Worksheets

   If Len(Onglet.Name) = 2 Then
 
     LigneFin = Onglet.Range("A" & Rows.Count).End(xlUp).Row
     LigneCible = Worksheets("RECAPITULATIF").Range("A" & Rows.Count).End(xlUp).Row + 1
     Onglet.Range("A3:M" & LigneFin).Copy Worksheets("RECAPITULATIF").Range("A" & LigneCible)
   
   End If

 Next Onglet

 'Tri du récap
 LigneFin = Worksheets("RECAPITULATIF").Range("A" & Rows.Count).End(xlUp).Row

 With ActiveWorkbook.Worksheets("RECAPITULATIF").Sort
  .SortFields.Clear
  .SortFields.Add Key:=Range("A3"), SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal
  .SetRange Range("A3:M" & LigneFin)
  .Header = xlNo
  .MatchCase = False
  .Orientation = xlTopToBottom
  .SortMethod = xlPinYin
  .Apply
 End With

 Application.ScreenUpdating = True
End Sub

 

[JCGL]

Re : Compiler feuilles

Bonjour à tous,
Salut Nono,

Nono : Notre ami est en XL 2003 : le .Sort ne va pas convenir. A++

A+ à tous

 

[s2fruit]

Re : Compiler feuilles

🙄 MERCI BEAUCOUP ! Vous êtes un vrai magicien 😉
Vous avez fais ça d'une façon très très Décontrasté !!!!!
Décontrasté ! (par Garcimore) - fiche chanson - B&M
Allez JCGL en refrain...

 

[camarchepas]

Re : Compiler feuilles

Bonjour Jc, s2Fruit,

@ Jc : Merci pour cette remarque sur le tri, effectivement ma solution ne convient pas à xl2003

Je pense que c'est un problème de renseignement et d'extension fichier , car dans le code proposé post 4 , c'est le demandeur lui même qui apporte cette solution.

et au vue de sa grande joie , cela parait tourner .