Comparaison 'spéciale' entre 2 colonnes

[o06]

Bonjour le Forum,

Je suis vraiment 'novice' dans le maniement d'Excel, et je me retrouve bien embêté, et un peu comme la Princesse Leïa le dit à Obi Wan Kenobi dans ce désormais fameux message vidéo "... vous êtes mon dernier espoir ..."

J'ai besoin de vérifier si les valeurs contenues dans la colonne B se retrouvent dans la colonne A, et le cas échéant le signaler dans la colonne C.
Cela donnerait :
est ce que la valeur B2 est contenue dans A2:A111;si oui "1"; si non "0"
est ce que la valeur B3 est contenue dans A2:A111;si oui "1"; si non "0"
est ce que la valeur B4 est contenue dans A2:A111;si oui "1"; si non "0"
ETC.

Petites précisions :
- Les valeurs contenues dans les celulles des 2 colonnes sont de types alphanumériques

- Dans la colonne B, les valeurs à rechercher comportent 11 carractères, et ceux de la colonne A 16. Il faut que la valeur B soit contenue dans la valeur A et non pas strictement égale.

Voilà, ça doit être de la rigolade pour vous, mais moi j'ai des larmes qui coulent sur mes jouent là ...

Merci d'avance pour votre aide.

PS : j'ai bien sûr recherché dans le forum des posts équivalents mais sans succès. Les plus approchants abordent la fonction RECHERCHEV, mais je n'arrive pas à l'adapter à mon pb.

 

[Spitnolan08]

Re : Comparaison 'spéciale' entre 2 colonnes

Bonjour,
La fonction RechercheV fonctionne mais il faut l'édulcorer un peu..
Essaie :
=SI(ESTERREUR(RECHERCHEV(B2;A2:A111;1;FAUX));"Non";"Oui")
Cordialement

 

[wilfried_42]

Re : Comparaison 'spéciale' entre 2 colonnes

bonjour o06

en c2 tu mets : si(nb.si($A$2:$A$111;"=" & B2)>0;1;0)

ensuite tu etires la fonction vers le bas

Edit : Bonjour Spitnolan, Désolé pas vu

Bonjour jocelyn

 

[Jocelyn]

Re : Comparaison 'spéciale' entre 2 colonnes

Bonjour le Forum,
Bonjour o06, Spitnolan08, wilfried_42,

Comme tu as 11 caractere d'un coté et 16 de l'autre il n'est pas facile de comparer les cellules entieres alors une solution SOMMEPROD / estnum/trouve voir en fichier joint.

Jocelyn

 

[o06]

Re : Comparaison 'spéciale' entre 2 colonnes

Bonjour Spitnolan08, wilfried_42, Jocelyn,

Merci à vous pour vos réponses.
La méthode de Jocelyn fonctionne à merveille pour moi. Nickel. Merci.

En tous les cas super la réactivité de ce forum. Le top !

A bientôt.

o06.

 

[o06]

Re : Comparaison 'spéciale' entre 2 colonnes

Bonjour le Forum,

Je refais monter ce post pour une précision.

En bref : colonne A contenant des références alpha numériques de 16 caractères et colonne B contenant le même type de données mais sur 11 caratères. Je veux tester pour chaque valeur contenue dans la colonne B si elle se retrouve dans la colonne A. Le cas échéant le signaler.

Donc Joc. m'a donné la fonction suivante :
=SI(SOMMEPROD(ESTNUM(TROUVE(B1;A1:A111))*1)>=1;1;0)
Le souci c'est qu'en passant à la cellule suivante la plage s'incrémente ...
=SI(SOMMEPROD(ESTNUM(TROUVE(B2;A2:A112))*1)>=1;1;0)
=SI(SOMMEPROD(ESTNUM(TROUVE(B3;A3:A113))*1)>=1;1;0) etc ...

Le 1er pb : si par ex. B3 est contenu dans A1, je ne le saurai pas.
Le 2eme, moins grave, la fonction va tester des cellules vides (à partir de A112 dans cet ex.)

Je voudrais :
=SI(SOMMEPROD(ESTNUM(TROUVE(B1;A1:A111))*1)>=1;1;0)
=SI(SOMMEPROD(ESTNUM(TROUVE(B2;A1:A111))*1)>=1;1;0)
=SI(SOMMEPROD(ESTNUM(TROUVE(B3;A1:A111))*1)>=1;1;0) etc..

Pouvez m'aider ? Même en étirant la fonction et en disant "copier les cellules" cela s'incrémente quand même.

Merci pour votre aide et votre patience ...

A+

 

[Jocelyn]

Re : Comparaison 'spéciale' entre 2 colonnes

bonjour,

pour obtenir ce que tu souhaite il suffit de fixer ta plage A1:A111 de cette façon :

tu ecris la formule comme ca :

=SI(SOMMEPROD(ESTNUM(TROUVE(B1;$A$1:$A$111))*1)>=1;1;0 )

les $ pêrmette de passer d'une référence relative a absolue

exemple

A1 etiré a droite devient B1
A1 etiré vers le bas devient A2

maintenant

$A$1 retse A1 etiré vers la droite ou vers le bas
$A1 devient A2 étiré vers le bas mais reste A1 etirée vers la droite
A$1 reste A1 etiré vers le bas mais devient B1 etiré a droite

Jocelyn

 

[o06]

Re : Comparaison 'spéciale' entre 2 colonnes

Salut Jocelyn,

Merci beaucoup.

A+