Comment interferer un formulaire et les cellules d'une feuille

[...] A l'ouverture, je souhaite que la date et la valeur de la cellule E3 s'affiche automatiquement dans les 2 premiers champs. [...]

Cliquez pour agrandir...

Private Sub UserForm_Initialize()
  TextBox3 = Date
  TextBox4 = Sheets("DONNE").Range("E3")
End Sub

[...] Après avoir renseigné les autres champs, en validant par le bouton valider, voici ce que je souhaite:
- que la valeur des champs Nom et prenom s'affiche en B5 et B6 respectivement.
- que la valeur cochée dans le frame1, s'affiche en B7
- que dans le frame2, je puisse faire plus d'un choix et que les éléments cochés apparaissent en B10 (comme par exemple : CNI, Extrait). [...]

Cliquez pour agrandir...

Private Sub CommandButton1_Click()

'Vérif des saisies
If Trim(TextBox1) = "" Then
  MsgBox "Veuillez saisir le nom."
  TextBox1.SetFocus
  Exit Sub
ElseIf Trim(TextBox2) = "" Then
  MsgBox "Veuillez saisir le prénom."
  TextBox2.SetFocus
  Exit Sub
ElseIf Not (OptionButton1 Or OptionButton2 Or OptionButton3) Then
  MsgBox "Veuillez saisir la situation."
  Frame1.SetFocus
  Exit Sub
ElseIf Not (CheckBox1 Or CheckBox2 Or CheckBox3) Then
  MsgBox "Veuillez saisir les justificatifs."
  Frame2.SetFocus
  Exit Sub
Else
  'Tous les champs sont saisis -> transfert sur Feuille "DONNE"
  With Sheets("DONNE")
    .Range("B5") = TextBox1
    .Range("B6") = TextBox2
    .Range("B7") = _
        IIf(OptionButton1, OptionButton1.Caption, _
        IIf(OptionButton2, OptionButton2.Caption, OptionButton3.Caption))
    .Range("B10") = _
        IIf(CheckBox1, CheckBox1.Caption, "") & _
        IIf(CheckBox2, ", " & CheckBox2.Caption, "") & _
        IIf(CheckBox3, ", " & CheckBox3.Caption, "")
    If Left(.Range("B10"), 2) = ", " Then .Range("B10") = Mid(.Range("B10"), 3)
  End With
  Unload Me
End If
End Sub

• le bouton "Annuler" a sa propriété "Cancel" à TRUE -> c'est le bouton d'annulation par défaut. Si on appuie sur la touche Escape, alors c'est l'action liée à ce bouton qui sera exécutée (ici on referme la fenêtre)

• Pour les justificatifs (frame2), les OptionButton (qui ne permettent qu'un choix parmi 3) ont été remplacés par des CheckBox qui permettent de choisir une ou plusieurs options.

• Pour contrôler l'action de la touche tabulation et l'ordre des contrôles parcourus, utiliser la propriété TabIndex des contrôles. La touche TAB parcourra les contrôles dans l'ordre croissant des valeurs de TabIndex (Tabindex débute à 0 puis 1 puis 2 puis...). Pour ne pas que la touche TAB sélectionne un contrôle, attribuer la valeur FALSE à la propriété "TabStop" de ce contrôle.

zombe à dit:

[...] Vous avez parlé de TABINDEX que j'ai pas bien compris.
Pouvez-vous illuster cela à travers le formulaire que j'ai essayé de remanier?
Je souhaite que les saisies commencent suivant l'ordre ci-dessous:
- RELATION BANK,
- NOM
- PRENOM
- NBRE D'ENFANT
- FRAME1
- FRAME2.
Aussi, est-il possible d'intégrer des infobulles? [...]

Cliquez pour agrandir...