Comment faire une boucle pour vider 10 textbox SVP

'en exemple
Public Sub EffaceTxtBox(ByRef UForm As UserForm)
    Dim Ctrl As Control
    'Boucle sur tous les contrôles de UForm
    For Each Ctrl In UForm.Controls
        If TypeOf Ctrl Is MSForms.TextBox Then Ctrl.Value = vbNullString
    Next

    Set Ctrl = Nothing

End Sub

'en exemple
'Dans n'importe quel UserForm, les TextBox en paramètre ne seront pas affectées
'exemple d'appel: Call EffaceTextBox(Me, "TextBox2", "TextBox4")
Public Sub EffaceTextBox(ByRef UForm As UserForm, ParamArray ExceptTextBoxes())
    Dim Ctrl As Control, i As Long, bModif As Boolean
    'Boucle sur tous les contrôles de UForm
    For Each Ctrl In UForm.Controls
        bModif = True
        If TypeOf Ctrl Is MSForms.TextBox Or TypeOf Ctrl Is MSForms.ComboBox Then
            For i = LBound(ExceptTextBoxes) To UBound(ExceptTextBoxes)
                If Ctrl.Name = ExceptTextBoxes(i) Then
                    bModif = False
                    Exit For
                End If
            Next i
            If bModif Then Ctrl.Value = vbNullString    'évite " "
        End If
    Next

    Set Ctrl = Nothing

End Sub
'utilisé
'appel à partir de l'userform : Me,EffaceComboboxTextBox
Public Sub EffaceComboboxTextBox(ByRef UForm As UserForm)
 Dim Ctrl As Control

 For Each Ctrl In UForm.Controls
 If TypeOf Ctrl Is MSForms.TextBox Then Ctrl.Value = vbNullString
 If TypeOf Ctrl Is MSForms.ComboBox Then Ctrl.Value = vbNullString
 Next Ctrl

 Set Ctrl = Nothing

End Sub

For Each CtrlArray In Array(TextBox1, TextBox2,TextBox3, _TextBox4,TextBox5,TextBox6,TextBox7,TextBox8,TextBox9,TextBox10)
        CtrlArray.Value = ""