comment calculer et afficher en année et mois, le temps depuis son anniversaire?

[Nicko]

bonsoir ,

Je suis pas un pri d'excel; j'essaie de comment calculer et afficher en année et mois , le temps écoulé depuis mon anniversaire.

j'ai réussi à faire ; =ANNEE(AUJOURDHUI())-ANNEE(C4),c4 est la cellule avec la date de naissance.
Mais le résultat est en année bien sur, comment faut-il s'y prendre pour afficher la période en annee et mois ?

Et ca oui à l'air simple pour vous ! encore dur pour moi !

merci de votre aide

nicko

 

[Lord Nelson]

Salut,

Les dates dans Excel sont des jours, donc la soustraction de deux dates donne un nombre de jours. A supposer que la date de naissance soit en A4 et la date d'aujourd'hui en B4, voici une formule possible :

=ENT((B4-A4)/365,25)&" ans "&ENT((MOD(B4-A4;365,25))/(365,25/12))&" mois"

(la fonction MOD donne le reste d'une division)

Une autre possibilité est d'utiliser la fonction DATEDIF pour obtenir directement le nombre de mois entre deux dates, comme ceci :

=ENT(DATEDIF(A4;B4;"m")/12) & " ans " & MOD(DATEDIF(A4;B4;"m");12) & " mois"

(le paramètre "m" donne des mois, "y" des années et "d" des jours)


A+
Horatio

 

[Nicko]

salut !


Merci beaucoup pour ca la première formule correspond tout à fait à ce que je m'efforçait de trouver.

merci Beaucoup

Par contre comment faut-il faire quand on applique cette formule a toute une colonne ?

il faut que le numéro de la cellule ou se trouve la date d'aujourd'hui en B4 reste fixe dans la formule et j'ai oublié comment on le fait!

Pourriez vous me le rappellez merci

a+

Nicko

 

[Nicko]

salut !

En fait la mémoire m'est revenu merci encore !!

A +

Nicko

 

[Jean-Marie]

Bonjour Nicko

Utilise les $, ce qui donne :
$B$4, fixe en colonne et en ligne la référence de la cellule
B$4, fixe en ligne la référence de la cellule

@+Jean-Marie

 

[Nicko]

salut


merci Jean Marie !

c'est Tip Top comme ca !!


ciao

 

[vbaleveltwoandhalf]

Bonjour


Il existe une fonction non documentée dans Xl:
DATEDIF

ex:
en A1 un date -> en B1 entrez la formule suivante

=DATEDIF(A1;AUJOURDHUI();"y")

 

[coyote]

N'y a t'il pas plus simple ?

Date d'anniversaire en A1

Date d'aujourd'hui en B1

C1 = B1 - A1 et formaté la cellule, nombre personnalisée : aa" ans et "mm" mois"

 

[Lord Nelson]

Salut tout le monde,

L'idée de Coyote est séduisante mais... sans que je sache pourquoi, ça rajoute un mois.

A+
Horatio

 

[coyote]

Ah oui, je n'avais pas remarqué.... désolé

En fait il affiche si date = jour anniversaire : x-1 ans et 12 mois

et JAMAIS x ans et 0 mois

si anniversaire+1 jour : x ans et 1 mois


Je ne l'explique pas également. sinon pour neutraliser le problème mets en C1 (selon mon exemple ci-dessus)
=SI(MOIS(B1-A1+1)=1;ANNEE(B1-A1+1)+1-1900&" ans et 0 mois";ANNEE(B1-A1+1)-1900&" ans et "&MOIS(B1-A1+1)-1&" mois")

J'ai testé vite fait, çà a l'air de fonctionner. Le format personnalisé n'est plus nécessaire en C1

 

[Monique]

Bonjour,

Le format nombre aa" ans et "mm" mois" est un format de date, il donne automatiquement au moins 1 mois.
A un âge de 4 ans, 0 mois et 11 jours correspond la date du 11-01-1904
Le 11-12-1904 pour un âge de 4 ans, 11 mois et 11 jours

Datedif sans s'embêter avec les pluriels :
=DATEDIF(A1;B1;"y")&" a "&DATEDIF(A1;B1;"ym")&" m "&DATEDIF(A1;B1;"md")&" j"

Datedif plus complet dans le classeur "Dates et Heures", ici :
<http://www.excel-downloads.com/html/French/fichiers/vba-date_maj-1.htm>