combobox alpha

[Evelynetfrancois]

Bonjour a tous !
Pour initialiser ma combobox2 j utilise ces lignes

With Sheets("helpsheet")
line = .Range("C500").End(xlUp).Row
For Each cel In .Range("C1:C" & line)
ComboBox2.AddItem cel.Value
Next cel
End With
Y a t il une solution pour avoir cette liste par ordre Alpha ( A ,Z) , sachant que ma liste en colonne "C" n’ est bien sur pas rangée Alpha ?( et ne doit pas l être )

je vous remercie d avance pour toutes vos idées

E et F

 

[PascalXLD]

Re : combobox alpha

Bonjour

il faut que tu mettes tes données dans un tableau de variable tu les trie dans ce tableau puis tu les mets dans ta combo

Tu trouveras des exemples sur le forum

 

[MichelXld]

Re : combobox alpha

Bonsoir chers E&F et Pascal


voici l'adaptation d'une procédure de notre ami Hervé

Private Sub UserForm_Initialize()
Dim x As Integer, i As Integer, j As Integer
Dim Temp As String
 
x = Sheets("helpsheet").Range("C65536").End(xlUp).Row
ComboBox1.List() = Sheets("helpsheet").Range("C1:C" & x).Value
With ComboBox1
    For i = 0 To .ListCount - 1
        For j = 0 To .ListCount - 1
            If .List(i) < .List(j) Then
                Temp = .List(i)
                .List(i) = .List(j)
                .List(j) = Temp
            End If
        Next j
    Next i
End With
End Sub

Bonne soirée
MichelXld

 

[CBernardT]

Re : combobox alpha

Bonjour Evelynetfrancois, Pascal, MichelXld et le forum,

Une approche identique à celle de Michel avec cependant l'emploi d'un tableau dynamique pour la mise en ordre alpha.
L'affichage dans la combobox est classique depuis le tableau ordonné :


Dim tablo As Variant, Val As Variant
Dim i As Integer, j As Integer, n As Integer, Line As Integer

With Sheets("helpsheet")
Line = .Range("C500").End(xlUp).Row
tablo = .Range("C1:C" & Line)
' Mise en ordre alpha
For i = 1 To Line
For j = 1 To Line
If tablo(j, 1) > tablo(i, 1) Then
Val = tablo(i, 1)
tablo(i, 1) = tablo(j, 1)
tablo(j, 1) = Val
End If
Next j
Next i
' Mise en combobox
For i = 1 To Line
ComboBox2.AddItem tablo(i, 1)
Next i
End With

Cordialement

Bernard

 

[Evelynetfrancois]

Re : combobox alpha

MERCI pour tout !!
(excusez ce temps de reponse, mais j etais absent toute l aprem)
je vais tester ces deux procedures
je vous remercie vraiment pour ce super coup de main .

a bientot vous lire

E et F