Combiner INDEX et une recherche matricielle

tototiti2008

XLDnaute Barbatruc

• 13 Octobre 2010

• #2

Re : Combiner INDEX et une recherche matricielle

Bonjour caritijak,

Je suis presque sûr qu'il y a plus simple mais je n'ai pas trouvé
en B2 :

Code:

=INDEX($E$2:$G$2;1;SI(ESTNUM(EQUIV(A2;$E$3:$G$3;0));EQUIV(A2;$E$3:$G$3;0);0)+SI(ESTNUM(EQUIV(A2;$E$4:$G$4;0));EQUIV(A2;$E$4:$G$4;0);0)+SI(ESTNUM(EQUIV(A2;$E$5:$G$5;0));EQUIV(A2;$E$5:$G$5;0);0)+SI(ESTNUM(EQUIV(A2;$E$6:$G$6;0));EQUIV(A2;$E$6:$G$6;0);0))

 

Vote positif 0 Vote négatif

mromain

XLDnaute Barbatruc

• 13 Octobre 2010

• #3

Re : Combiner INDEX et une recherche matricielle

Bonjour caritijak, tototiti,

une autre proposition (à saisir en B2 et à tirer vers le bas) :

Code:

=DECALER($E$2;;SOMMEPROD(COLONNE($E$2:$G$6)*($E$2:$G$6=$A2))-5)

a+

 

Vote positif 0 Vote négatif

tototiti2008

XLDnaute Barbatruc

• 13 Octobre 2010

• #4

Re : Combiner INDEX et une recherche matricielle

Re,

Bonjour mromain 😉

Bon, j'avais fini par trouver quelque chose qui ressemble pas mal à ta solution :

Code:

=INDEX($E$2:$G$2;1;SOMMEPROD(($E$3:$G$6=A2)*COLONNE($A$3:$C$6)))

 

Vote positif 0 Vote négatif

CBernardT

XLDnaute Barbatruc

• 13 Octobre 2010

• #5

Re : Combiner INDEX et une recherche matricielle

Bonjour,

Une variante :

=SI(NON(ESTNA(EQUIV(A2;$E$3:$E$6;0)));$E$2;SI(NON(ESTNA(EQUIV(A2;$F$3:$F$6;0)));$F$2;SI(NON(ESTNA(EQUIV(A2;$G$3:$G$6;0)));$G$2;"")))

Cliquez pour agrandir...

 

Vote positif 0 Vote négatif

H

hoerwind

XLDnaute Barbatruc

• 13 Octobre 2010

• #6

Re : Combiner INDEX et une recherche matricielle

Bonjour, salut tototiti,

Il y a aussi moyen de le faire par formule matricielle, mais pour l'exemple celle-ci devrait suffire :

B2 : ="CS"&NB.SI(E$2:E$6;A2)+NB.SI(F$2:F$6;A2)*2+NB.SI(G$2:G$6;A2)*3
formule à copier vers le bas.

Édition : pas vu mromain et CBernardT, à vous aussi le bonjour !

 

Vote positif 0 Vote négatif

D

david84

XLDnaute Barbatruc

• 13 Octobre 2010

• #7

Re : Combiner INDEX et une recherche matricielle

Bonjour tototiti,mromain,CBernardT, hoerwind,
une autre possibilité avec validation matricielle :

Code:

=SI(A2="";"";INDIRECT(ADRESSE(2;MIN(SI(E$3:G$6=A2;COLONNE(E$3:G$6))))))

A+

 

Vote positif 0 Vote négatif

C

caritijak

Guest

• 13 Octobre 2010

• #8

Re : Combiner INDEX et une recherche matricielle

Merci à tous pour vos réponses,

Le gagnant est tototiti, mais j'ai besoin d'un peu d'explication sur ce qui suit le SOMMEPROD, pour pouvoir l'adapter sur ma "vraie" feuille. Je crois comprendre que E3:G6 est la matrice dans laquelle on cherche A2 (?), mais COLONNE(A3:C6) me laisse sans voix.

=INDEX($E$2:$G$2;1;SOMMEPROD(($E$3:$G$6=A2)*COLONNE($A$3:$C$6)))

 

Vote positif 0 Vote négatif

tototiti2008

XLDnaute Barbatruc

• 13 Octobre 2010

• #9

Re : Combiner INDEX et une recherche matricielle

Bonjour à tous,
Re,

6 formules différentes qui fonctionnent, impressionnant 😉

Tu peux remplacer

Code:

COLONNE($A$3:$C$6)

par

Code:

COLONNE($E$3:$G$6)-4

en fait le but est de renvoyer un nombre 1, 2 ou 3 pour connaître le numéro de colonne où se trouve le prénom

Comme la colonne E est la 5ème colonne, on peut faire -4 ou tout décaler en colonne A

 

Vote positif 0 Vote négatif

C

caritijak

Guest

• 13 Octobre 2010

• #10

Re : Combiner INDEX et une recherche matricielle

Merci à tous,

Encore une fois merci à tous.

J'ai pas tout compris sur la fonction sommeprod même avec l'aide Excel, mais ça marche, alors ...

Cordialement

 

Vote positif 0 Vote négatif