Coloriage de lignes avec conditions

For x = 21 To 24 Step 2
    Rows(x).Interior.ColorIndex = 6
Next x

Sub Macro1()
Dim cel As Range 'déclare la variable cel (CELlule)
Dim lv() As Integer 'déclare le tableau de variables lv (Ligne des Valeurs)
 
ReDim lv(0) 'redimensionne le tableau de variables lv
lv(0) = 4 'définit la première valeur indexée
 
'********************************************************************
'tableau contenant le numéro des lignes à chaque changement de valeur
'********************************************************************
 
For Each cel In Range("B5:B" & Range("B65536").End(xlUp).Row) 'boucle sur toutes les cellules éditées de la colonne B (en partant de B5)
    If cel.Value <> cel.Offset(-1, 0) Then 'condition : si la valeur de la cellule est différente de la valeur de la cellule au dessus
        ReDim Preserve lv(UBound(lv) + 1) 'redimensionne le tableau de variables lv
        lv(UBound(lv)) = cel.Row 'définit la nouvelle valeur indexée
    End If 'fin de la condition
Next cel 'prochaine cellule de la boucle
 
ReDim Preserve lv(UBound(lv) + 1) 'redimensionne le tableau de variables lv
lv(UBound(lv)) = Range("B65536").End(xlUp).Row + 1 'définit la dernière ligne du tableau
 
'*********************
'coloration des lignes
'*********************
 
For x = 0 To UBound(lv) Step 2 'boucle sur toutes le valeurs du tableau de variables par pas de deux
    On Error Resume Next 'permet d'ignorer le bug si le nombre de changement est impair
    Rows(lv(x) & ":" & lv(x + 1) - 1).Interior.ColorIndex = 6 'colore les lignes
Next x 'prochaine valeur du tableau de variable (en en sautant une)
End Sub