Code VBA double clic

[kobold72210]

Bonjour à tous,
Voilà j'ai crée une feuille avec un code VBA (j'essaie de me débrouiller comme je peut), mais je bloque sur la suite. Je souhaiterai, lors d'un double clic dans une des celulles G5; G6; G7 ou G8 pouvoir afficher la date du jour dans la cellule C7.
Si vous trouvez aussi quelques erreurs dans les codes (et il y en a je pense) merci de me les signaler
En PJ, ma feuille si besoin.
Merci a vous

 

[JM27]

Bonjour
peut ètre comme cela ( en sélectionnant des zones plutôt que des colonnes)

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
     
    If Not Intersect([E13:J31], Target) Is Nothing And Target.Count = 1 Then
        If Target.Interior.Pattern <> xlNone Then
            Target.Interior.Pattern = xlNone
        Else
    End If
    Cancel = True
If ActiveCell.Value = "" Then
      ActiveCell.Value = "Oui"
      ActiveCell.Interior.ColorIndex = 43
      Else
      ActiveCell.Value = ""
      ActiveCell.Interior.ColorIndex = NONE
          End If
    End If
If Not Intersect([L13:N31], Target) Is Nothing And Target.Count = 1 Then

Cancel = True
    If ActiveCell.Value = "" Then
      ActiveCell.Value = Date:
      ActiveCell.Interior.ColorIndex = 27
      Else
      ActiveCell.Value = ""
      ActiveCell.Interior.ColorIndex = NONE
          End If
    End If
If Not Intersect([G5:G8], Target) Is Nothing And Target.Count = 1 Then
    Range("C7") = Date
  
End If
End Sub

 

[vgendron]

Hello

essaie avec ce code

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)

If Target.Column = 5 Or Target.Column = 6 Or Target.Column = 7 Or Target.Column = 8 Or Target.Column = 9 Or Target.Column = 10 Then
    If Target.Interior.Pattern <> xlNone Then
        Target.Interior.Pattern = xlNone
    End If
    Cancel = True
    If ActiveCell.Value = "" Then
        ActiveCell.Value = "Oui"
        ActiveCell.Interior.ColorIndex = 43
    Else
        ActiveCell.Value = ""
        ActiveCell.Interior.ColorIndex = NONE
    End If
End If
   
If Target.Column = 12 Or Target.Column = 13 Or Target.Column = 14 Then
    Cancel = True
    If ActiveCell.Value = "" Then
        ActiveCell.Value = Date:
        ActiveCell.Interior.ColorIndex = 27
    Else
        ActiveCell.Value = ""
        ActiveCell.Interior.ColorIndex = NONE
    End If
End If

If Target.Address = "$G$5" Or Target.Address = "$G$6" Or Target.Address = "$G$7" Or Target.Address = "$G$8" Then
    [C7] = Date
End If
End Sub

 

[Jacky67]

Bonjour à tous,
Voilà j'ai crée une feuille avec un code VBA (j'essaie de me débrouiller comme je peut), mais je bloque sur la suite. Je souhaiterai, lors d'un double clic dans une des celulles G5; G6; G7 ou G8 pouvoir afficher la date du jour dans la cellule C7.
Si vous trouvez aussi quelques erreurs dans les codes (et il y en a je pense) merci de me les signaler
En PJ, ma feuille si besoin.
Merci a vous

Bonjour à tous,
Autre proposition...

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
    Dim derlg As Long, Plage1 As Range, Plage2 As Range, Plage3 As Range
    derlg = Cells(Rows.Count, "B").End(xlUp).Row
    Set Plage1 = Range("e13:j" & derlg)
    Set Plage2 = Range("l13:n" & derlg)
    Set Plage3 = [g5:g8]

    If Not Intersect(Target, Plage1) Is Nothing Then
        Cancel = True
        Target.Value = IIf(Target.Value = "", "Oui", "")
        Target.Interior.ColorIndex = IIf(Target.Value = "", xlNone, 43)
    End If

    If Not Intersect(Target, Plage2) Is Nothing Then
        Cancel = True
        Target.Value = IIf(Target.Value = "", Date, "")
        Target.Interior.ColorIndex = IIf(Target.Value = "", xlNone, 27)
    End If

    If Not Intersect(Target, Plage3) Is Nothing Then
        Cancel = True
        Plage3 = ""
        Target.Value = "Maj par"
        [c7].Value = Date
    End If
End Sub

 

[kobold72210]

Merci a vous c'est niquel. J'ai finalement pris le code de Jacky 67
Merci bien !!!