Code conditions multiples

[Centrino]

Bonjour à toutes et à tous,

Je suis en train de concevoir une macro dont l'une de ces parties est constituées de conditions. Voici ce que j'ai rédiger:

    For I = 1 To nbre_pt_contrôle
        For J = 1 To nbre_répliques
        
            If Worksheets("Quantification").Cells(I, J).Value > 400 Then Worksheets("Cluster").Cells(I + 7, J + 4).Value = "+++"
            Next J
            
            If 200 < Worksheets("Quantification").Cells(I, J).Value < 400 Then Worksheets("Cluster").Cells(I + 7, J + 4).Value = "++"
            Next J
            
            If 100 < Worksheets("Quantification").Cells(I, J).Value < 200 Then Worksheets("Cluster").Cells(I + 7, J + 4).Value = "+"
            Next J
            
            If 50 < Worksheets("Quantification").Cells(I, J).Value < 100 Then Worksheets("Cluster").Cells(I + 7, J + 4).Value = "-"
            Next J
            
            If 20 < Worksheets("Quantification").Cells(I, J).Value < 50 Then Worksheets("Cluster").Cells(I + 7, J + 4).Value = "--"
            Next J
            
            If Worksheets("Quantification").Cells(I, J).Value < 25 Then Worksheets("Cluster").Cells(I + 7, J + 4).Value = "---"
            Next J
               
        Next J
    Next I

Pouvez-vous m'aider sur ce point car cette macro ne fonctionne pas.

Merci

 

[kjin]

Re : Code conditions multiples

Bonjour,
Tu pourrais écrire...

With Worksheets("Quantification")
    For i = 1 To nbre_pt_contrôle
        For j = 1 To nbre_répliques
            If .Cells(i, j).Value > 400 Then Worksheets("Cluster").Cells(i + 7, j + 4).Value = "+++"
            If .Cells(i, j).Value > 200 And .Cells(i, j).Value <= 400 Then Worksheets("Cluster").Cells(i + 7, j + 4).Value = "++"
            '...
        Next j
    Next i
End With

...ou plus simplement

With Worksheets("Quantification")
    For i = 1 To nbre_pt_contrôle
        For j = 1 To nbre_répliques
            Select Case .Cells(i, j)
            Case Is > 400
                Worksheets("Cluster").Cells(i + 7, j + 4).Value = "+++"
            Case 201 To 400
                Worksheets("Cluster").Cells(i + 7, j + 4).Value = "++"
            Case 101 To 200
                Worksheets("Cluster").Cells(i + 7, j + 4).Value = "+"
            Case 51 To 100
                Worksheets("Cluster").Cells(i + 7, j + 4).Value = "-"
            Case 21 To 50
                Worksheets("Cluster").Cells(i + 7, j + 4).Value = "--"
            Case Else
                Worksheets("Cluster").Cells(i + 7, j + 4).Value = "---"
            End Select
        Next j
    Next i
End With

Note qu'il y a des incohérences dans tes critères donc je te laisse adapter
A+
kjin

 

[Modeste]

Re : Code conditions multiples

Bonjour Centrino,

J'ai bien peur que cette syntaxe

If 200 < Worksheets("Quantification").Cells(I, J).Value < 400

ne soit guère compréhensible

Par contre, tu pourrais chercher dans l'aide, des infos sur l'utilisation de l'instruction "Select Case" ... ton code ressemblerait (si j'ai bien compris!) à quelquechose comme:

Select Case Worksheets("Feuil1").Cells(I, J).Value
Case 1 To 9
    MsgBox "entre 1 et 9"
Case 10 To 50
    MsgBox "entre 10 et 50"
End Select

Edit: Salut kjin 🙂 ... serais-je un peu lent?

 

[Centrino]

Re : Code conditions multiples

Je vous remercie de vos informations, je ne connaissais pas cette fonction (voilà qui est fait 😉 )

Cependant, le deuxième code de Kjin affiche une erreur pour le "Next J" disant qu'il manque le For. Avez-vous une solution ?

Encore merci pour votre aide !

 

[kjin]

Re : Code conditions multiples

Re, Hello Modeste 🙂,

Cependant, le deuxième code de Kjin affiche une erreur pour le "Next J" disant qu'il manque le For.

Oui j'ai rectifié (il manquait le End Select et je n'avais pas testé)
A+
kjin

 

[Centrino]

Re : Code conditions multiples

Ah excellent ! Merci Kjin !

 

[Gorfael]

Re : Code conditions multiples

Salut Centrino et le forum
Comme dit Modeste :

If 200 < Worksheets("Quantification").Cells(I, J).Value < 400 Then Worksheets("Cluster").Cells(I + 7, J + 4).Value = "++"

Excel ne comprend pas, il a ses limites : Si tu ne rédige pas dans la bonne syntaxe, il boude !
si 100<A<400 alors... Ça c'est du français. En VBA, il faudra traduire par :
si 100<A et A<400 alors... en considérant que le "et" est la fonction logique. Ce qui nous donne :

If (200 < Worksheets("Quantification").Cells(I, J)) and (Worksheets("Quantification").Cells(I, J) <  400) Then Worksheets("Cluster").Cells(I + 7, J + 4).Value = "++"

C'est la même chose sur une feuille de calcul.
A+