Microsoft 365 cherche mot colonne et copier coller

[nonobat]

bonjour
je souhaite créer une macro qui recherche le mot(additif) dans la colonne "b"
et copier du mot additif jusqu’à la fin de la colonne
pour la coller dans un autre classeur (dont je ferai appel a une fenêtre pour allez chercher manuellement le classeur)

j 'ai cherché sur le forum il y a des choses qui s'approche mais grrr je ne suis pas assez doué
et donc une fois de plus j 'ai besoin de vos aides

merci

 

[Staple1600]

Bonjour le fil, nonobat

nonobat
Tu n'as pas un fichier exemple sous le coude ?
Histoire d'y voir plus clair

 

[nonobat]

bonjour staple1600
tu as raison ça va être plus clair je joint le fichier
le but pour l 'instant est surtout de copier les cellules en dessous additif
et trouver le code qui me permet d'ouvrir une fenetre qui me permettra d 'allez chercher mon autre fichier excel (car se dernier fichier et refait tout les jours et nommer a la date du jour) et les coller dedans

 

[Staple1600]

Re

Alors, pour commencer la chose

Sub Recopiage()
Dim lDeb&, lFin&
lDeb = Application.Match("additif", Columns(2), 0) + 1
lFin = Cells(Rows.Count, 2).End(3).Row
MsgBox Range(Cells(lDeb, 2), Cells(lFin, 2)).Address 'pour test
Range(Cells(lDeb, 2), Cells(lFin, 2)).Copy [J4] 'pour test
End Sub

 

[nonobat]

impeccable c 'est exactement ça
merci staple 1600
a la suite je voulais ouvrir une fenêtre pour allez chercher un autre classeur et le copier dedans
tel que :

Sub Recopiage()
Dim lDeb&, lFin&
lDeb = Application.Match("additif", Columns(2), 0) + 1
lFin = Cells(Rows.Count, 2).End(3).Row
'MsgBox Range(Cells(lDeb, 2), Cells(lFin, 2)).Address 'pour test

'ici j"ouvre une fenetre pour allez chercher mon fichier et coller dans ce fichier
Fichier = Application.GetOpenFilename("Tous les fichiers (*.*),*.*")


Range(Cells(lDeb, 2), Cells(lFin, 2)).Copy [J4] 'pour test
End Sub

mais ça ne marche pas !!!

 

[Staple1600]

Bonjour le fil, nonobat

nonobat
Qu'est-ce tu lis au bout de ligne aprés le ' ?
(c'est en vert dans le message#4)

 

[nonobat]

oui tout a fait j 'ai bien compris que c 'est un test qui recopie dans la même feuille en "j4"
mais je pensais qu'en mettent

Fichier = Application.GetOpenFilename("Tous les fichiers (*.*),*.*")
Range(Cells(lDeb, 2), Cells(lFin, 2)).Copy [J4] 'pour test

cela m'aurai permis d'ouvrir un autre classeur coller dedans
j 'arrive parfois a modifier quelques code pour les arrangers à ma manière
mais je reconnais que sans aide je suis vraiment très mauvais

 

[Staple1600]

Re

Donc si c'est pour test, pourquoi réutiliser la ligne telle quelle ??
(Tu n'as jamais indiqué vouloir copier en J4, non ?)

 

[Staple1600]

Re

Essaies comme ceci

Sub Recopiage_II()
Dim lDeb&, lFin&, WBK As Workbook, Plg As Range
lDeb = Application.Match("additif", Columns(2), 0) + 1
lFin = Cells(Rows.Count, 2).End(3).Row
Set Plg = Range(Cells(lDeb, 2), Cells(lFin, 2))
'ici j"ouvre une fenetre pour allez chercher mon fichier et coller dans ce fichier
Fichier = Application.GetOpenFilename("Classeur (*.xls),*.xls,Classeur (*.xlsx),*.xlsx,Classeur (*.xlsm),*.xlsm")
If Fichier <> False Then
Set WBK = Workbooks.Open(Fichier)
End If
'ici on recopie dans sur la feuille 1 du classeur ouvert GetOpenFilename
Plg.Copy WBK.Sheets(1).[A1]
End Sub

 

[nonobat]

hou la la en effet j 'en étais en cent mille lieus
c 'est exactement ça !!!
total respect M staple1600
je pense que j 'ai encore beaucoup beaucoup... de boulot pour arriver à un niveau pareil

merci

 

[Staple1600]

Re

Ce n'est point du boulot (c'est du plaisir )
Une petite variante (pour le fun)

Sub Recopiage_III()
Dim x&, WBK As Workbook, Plg As Range
x = quaero("additif")
Set Plg = Range(Cells(x, 2), Cells(x, 2).End(xlDown))
Fichier = Application.GetOpenFilename("Classeur (*.xls),*.xls,Classeur (*.xlsx),*.xlsx,Classeur (*.xlsm),*.xlsm")
If Fichier <> False Then
Set WBK = Workbooks.Open(Fichier)
End If
WBK.Sheets(1).Cells(1).Resize(Plg.Rows.Count) = Plg.Value
End Sub
Function quaero(verbum As String, Optional columna As Long = 2) As Long
quaero = Application.Match(verbum, Columns(columna), 0) + 1
End Function

NB: Par contre ceci n'est pas forcément du bon boulot.
Je te laisse découvrir pourquoi

 

[nonobat]

ça marche tout autant trop cool
mais déjà que je suis perdu en temps normal
mais là ....
Function quaero(verbum) ??? jamais vu
c 'est du latin ? (en tout cas pour moi oui )

 

[Staple1600]

Re

Function quaero(verbum) ??? jamais vu

Normal, c'est moi qui vient de la pondre
(Faut bien s'occuper quand rôde le CoVid-19 et que la pluie tombe au dehors)
Est-ce que tu vois le petit bonus que cela apporte ?

 

[nonobat]

nous ici (Normandie) aujourd'hui un peu de soleil ça fait du bien
alors je vois que la fonction est séparée de la macro
peut être que cela permet de faire différente recherche
en gardant la même macro en ajoutant seulement la fonction

 

[Staple1600]

Re

Par exemple, je veux chercher le mot UmmaGumma dans la colonne C
alors il suffit de simplement modifier cette ligne
x = quaero("UmmaGumma",3)
Voila où résidait le petit bonus