Cellules vides avec SOMMEPROD

[Archi]

Bonjour,

Voici mon prob,

J'ai
=SOMMEPROD((Q4=S4)+(T4=V4)+(W4=Y4)*1) en O4
89 en Q4
78 en S4
50 en T4
12 en V4
rien en W4
rien en Y4

le résultat me donne 1 ???

Comment ne pas prendre en compte les cellules vides ????

Merci d'avance

 

[Monique]

Bonjour,

=((Q4=S4)*(Q4<>0)*(S4<>0))+((T4=V4)*(T4<>0)*(V4<>0))+((W4=Y4)*(W4<>0)*(Y4<>0))

Si tes données étaient disposées de façon différente, tu pourrais utiliser SommeProd
89 en Q12
78 en Q13
50 en R12
12 en R13
rien en S12
rien en S13
=SOMMEPROD((Q12:S12=Q13:S13)*(NON(ESTVIDE(Q12:S12))))

 

[Archi]

Merci Monique

Question:
Sommeprod ne peut pas additionner en horizontale ???

 

[Archi]

je viens d'essayer
=SOMMEPROD((Q4:T4:W4=S4:V4:Y4)*NON(ESTVIDE(Q4:T4:W4))*1)

quand penses tu ???

 

[Monique]

Re,

Eh bien tu viens d'en inventer une bonne.
Je n'avais jamais vu ce genre de formule, avec plusieurs : :
J'ai l'impression qu'elle fonctionne.

Celle-ci (validée en matriciel) semble avoir toujours 1 pour résultat :
=(Q2:T2:W2=S2:V2:Y2)*1

 

[Monique]

Re,

Pour ton message précédent (j'ai oublié, du coup)
SommeProd compare, additionne, compte des cellules situées sur la même ligne de colonnes différentes,
ou sur la même colonne de 2 lignes différentes.
ou situées "au même niveau" de 2 plages perpendiculaires
2 plages horizontales, compte le nb de valeurs identiques situées sur la même colonne verticale
=SOMMEPROD((A1:C1=A2:C2)*(NON(ESTVIDE(A1:C1))))
2 plages verticales, compte le nb de valeurs identiques situées sur la même ligne horizontale :
=SOMMEPROD((E1:E3=F1:F3)*(NON(ESTVIDE(E1:E3))))
Idem, mais les plages sont perpendiculaires :
=SOMMEPROD((H1:J1=TRANSPOSE(I2:I4))*1)
(formule matricielle, à valider par ctrl, maj et entrée.
Tu as un classeur à télécharger, SommeProd_SumProduct II
<http://www.excel-downloads.com/html/French/fichiers/programmation-date_maj-1.htm>

 

[Archi]

est le (*1) sert à quoi exactement ??

 

[Monique]

Re,
Il rend numérique un résultat
=10=10 dit VRAI
=(10=10)*1 dit 1
=(10=22)*1 dit 0
Tu as la même chose avec
=(10=10)+0
=(10=10)-0
=(10=10)/1

 

[Archi]

Merci
@+

 

[Jean-Marie]

Bonjour

Archi ta formule =SOMMEPROD((Q4:T4:W4=S4:V4:Y4)*NON(ESTVIDE(Q4:T4:W4))*1) équivaut à faire ceci =SOMMEPROD((Q4:W4=S4:Y4)*NON(ESTVIDE(Q4:W4))*1)

La matricielle de (Q4:T4:W4=S4:V4:Y4) est constituée de 7 éléments et non 3 ce qui aurait été génial. Pour le vérifier, c'est simple, il suffit de sélectionner une plage de cellule horizontale (elle doit-être dans le même sens que la plage de cellule) disons 10 cellules, cliquer sur la "zone formule" de la barre d'outils formule (tu me suis, lol) et de coller la partie de la formule et de la valider par Crtl+Shift+entrer et tu verras à la fin de la plage 3 #NA, ce qui indique que 3 éléments sont inconnus. Ce que tu vois dans la plage est la représentation de la matrice (il n'y a pas de lien avec le film Matrix, lol)

Archi, comme la dit Monique Eh bien tu viens d'en inventer une bonne. dans la détermination d'une plage Q4:T4:W4

Bonne journée

@+Jean-Marie