Cellule fusionnée vides sous conditions

[Ilino]

FORUM BONJOUR
JE CHERCHE UN CODE SUIVANT :
si la cellule E40(fusionnéeE-F) contient "Non" alors H40( fusionnée H-K) et la cellule M40(fusionnée M-P) vide ??
Grazie

 

[CISCO]

Re : Cellule fusionnée vides sous conditions

Bonsoir

En H40
=SI(E40="Non";"")

Je suis sûr que tu trouveras la formule pour M40.

@ plus

 

[Ilino]

Re : Cellule fusionnée vides sous conditions

Bonsoir CISCO
GRAZIE POUR LA REPONSE😕
MON SOUCI RESIDE A CE NOUVEAU LA

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
If [E40] = "Non" Then [H40] = ""         'Vider Contractuelle et réelle
If [E40] = "Non" Then [M40] = ""



If [E42] = "Non" Then [H42] = ""         'Vider Contractuelle et réelle
If [E42] = "Non" Then [M42] = ""



If [E44] = "Non" Then [H44] = ""         'Vider Contractuelle et réelle
If [E44] = "Non" Then [M44] = ""


End Sub

COMMENT RÉDUIRE CE CODE 😕

ET POUR LA cellule M40 ,I do my best.😀
A+

 

[Ilino]

Re : Cellule fusionnée vides sous conditions

Bonsoir

En H40
=SI(E40="Non";"")

Je suis sûr que tu trouveras la formule pour M40.

@ plus

Tu as raison j'ai oublié de vous informer que les cellules H40 et M40 ces des cellules de saisiés
A+

 

[job75]

Re : Cellule fusionnée vides sous conditions

Bonjour Ilino, CISCO,

Code à choisir suivant la dimension du tableau à traiter :

Dim c As Range
For Each c In [E40,E42,E44]
  If c = "Non" Then c(1, 4) = "": c(1, 9) = ""
Next

Dim c As Range, n&
For Each c In [E40:E44]
  n = n + 1
  If n Mod 2 Then If c = "Non" Then c(1, 4) = "": c(1, 9) = ""
Next

Dim t1, t2, t3, n&
t1 = [E40:E10000].Formula
t2 = [H40:H10000].Formula
t3 = [M40:M10000].Formula
For n = 1 To UBound(t1) Step 2
  If t1(n, 1) = "Non" Then t2(n, 1) = "": t3(n, 1) = ""
Next
[H40:H10000] = t2
[M40:M10000] = t3

A+

 

[Ilino]

Re : Cellule fusionnée vides sous conditions

Bonjour JOB
Grazie, maintenant j'ai le choix
A+

 

[job75]

Re : Cellule fusionnée vides sous conditions

Re Ilino,

Une variante un peu plus élaborée pour le 3ème code :

Dim t1, t2, t3, n&
With Range("E40:M" & Range("E" & Rows.Count).End(xlUp).Row)
  t1 = .Columns(1).Formula
  t2 = .Columns(4).Formula
  t3 = .Columns(9).Formula
  For n = 1 To UBound(t1) Step 2
    If t1(n, 1) = "Non" Then t2(n, 1) = "": t3(n, 1) = ""
  Next
  .Columns(4) = t2
  .Columns(9) = t3
End With

A+

 

[job75]

Re : Cellule fusionnée vides sous conditions

Re,

Ceci est mieux et fonctionne même s'il n'y a qu'une seule ligne :

Dim t, n&
With Range("E40:M" & Range("E" & Rows.Count).End(xlUp).Row)
  t = .Formula
  For n = 1 To UBound(t) Step 2
    If t(n, 1) = "Non" Then t(n, 4) = "": t(n, 9) = ""
  Next
  .Columns(4) = Application.Index(t, , 4)
  .Columns(9) = Application.Index(t, , 9)
End With

A+