XL 2019 Calculer le nombre de mois d'une année entre deux dates

FDJR_91 · 23 Mars 2021

Bonjour je souhaite savoir on peut connaitre le nombre de mois mais d'une année particulière

Je m'explique,

Date début : 01/03/2020
Date de fin : 01/08/2022

j'aimerais savoir comment je peux obtenir :

Nombre de mois en 2020 = 8
Nombre de mois en 2021 = 12
Nombre de mois en 2022 = 7

Merci à vous

sylvanu · 23 Mars 2021

Bonjour FDJR,
Un essai avec Début en C6 et Fin en C7 :

VB:

2021:   =DATEDIF(C6;"31/12/2021";"m")&" mois"
2023:   =DATEDIF("1/1/2023";C7;"m")&" mois"

Pour l'ensemble :
=DATEDIF(C6;C7;"m")&" mois"

A noter que pour 2020 la réponse est 9 et non 8.

FDJR_91 · 23 Mars 2021

FDJR_91 à dit:
Bonjour je souhaite savoir on peut connaitre le nombre de mois mais d'une année particulière

Je m'explique,

Date début : 01/03/2020
Date de fin : 01/08/2022

j'aimerais savoir comment je peux obtenir :

Nombre de mois en 2020 = 8
Nombre de mois en 2021 = 12
Nombre de mois en 2022 = 7

Merci à vous

sylvanu à dit:
Bonjour FDJR,
Un essai avec Début en C6 et Fin en C7 :

VB:

2021: =DATEDIF(C6;"31/12/2021";"m")&" mois" 2023: =DATEDIF("1/1/2023";C7;"m")&" mois" Pour l'ensemble : =DATEDIF(C6;C7;"m")&" mois"

A noter que pour 2020 la réponse est 9 et non 8.

Bonjour et merci pour votre réponse, l'idée c'est de remplir les colonnes C-D-E, pouvez-vous m'aider ?

FDJR_91 · 23 Mars 2021

j'espère que vous pourrez m'aider voici le tableau

JHA · 23 Mars 2021

Bonjour à tous,

A essayer

VB:

=SIERREUR(DATEDIF(MAX($A2;"31/12/2019");MIN($B2;"31/12/2020");"m");0)

JHA

FDJR_91 · 23 Mars 2021

Génial ! merci infiniment

sylvanu · 23 Mars 2021

Bonjour JHA,
J'y étais presque arrivé, mais en moins élégant.
Cependant nous avons tous deux la même erreur par des chemins différent. C'est en D11, on trouve 5 au lieu de 6.
Et je m'arrache les cheveux, je ne comprends pas pourquoi.
( pour avoir 6 il faudrait en B11 avoir 01/07/2021, comme s'il comptait que les mois échus )
Addon : J'ai trouvé une solution avec :

VB:

=SIERREUR(DATEDIF(MAX($A2-1;"31/12/2020");MIN($B2+1;"31/12/2021");"m");0)

Apparemment la date de fin serait exclue.

Phil69970 · 23 Mars 2021

Bonjour @FDJR_91 , @JHA , @sylvanu

Sylvain en fait excel ne considère pas le mois comme entier si du part du 1er au 31 pour excel il manque 1 jour.

sylvanu à dit:
comme s'il comptait que les mois échus

donc pour contourner :
-soit tu pars du 31 du mois N-1
-soit tu arrives le 1 du mois suivant

@Phil69970

Phil69970 · 23 Mars 2021

Re

Et pour info
Le 1 du mois sera toujours le ...... 1
Alors que le dernier jour du mois n'est pas le 31 tous les mois !!!

ok je sors

@Phil69970

R@chid · 26 Mars 2021

Bonjour @ tous,
sur le fichier joint en post # 4, en C2 :

VB:

=NB(1/FREQUENCE(SI(ANNEE(LIGNE(INDIRECT($A2&":"&$B2)))=DROITE(C$1;4)*1;EQUIV(MOIS(LIGNE(INDIRECT($A2&":"&$B2)));MOIS(LIGNE(INDIRECT($A2&":"&$B2)));0));LIGNE(INDIRECT("1:"&$B2-$A2+1))))

@ valider par Ctrl+Maj+Entrée
@ tirer vers le bas et vers la droite.

Une proposition via Power Query est dans le 2ème onglet.

Cordialement

XL 2019 Calculer le nombre de mois d'une année entre deux dates

FDJR_91

XLDnaute Nouveau

sylvanu

XLDnaute Barbatruc

FDJR_91

XLDnaute Nouveau

Pièces jointes

FDJR_91

XLDnaute Nouveau

Pièces jointes

JHA

XLDnaute Barbatruc

Pièces jointes

FDJR_91

XLDnaute Nouveau

sylvanu

XLDnaute Barbatruc

Phil69970

XLDnaute Barbatruc

Phil69970

XLDnaute Barbatruc

R@chid

XLDnaute Barbatruc

Pièces jointes

Discussions similaires