Calcul textbox

[nicos3390]

Bonjour à tous,

dans mon userform, je souhaite multiplier 2 Textbox et obtenir un résultats en €.

TextBox7 = Format(TextBox7, "0.00%")
et
Textbox20 est un montant saisi

Je souhaite que ma textbox 6 multiplie ces 2 valeurs:

Me.TextBox6.Value = (Val(TextBox7.Value) / 100) * Val(TextBox20.Value)

Cependant en utilisant cette formule, si la valeur de la textbox 7 est de 0.15% alors le résultat donnera 0 car cette formule ne tient pas compte des chiffres après la virgule ...

pouvez-vous m'éclairer?

 

[laetitia90]

Re : Calcul textbox

bonjour nico il faut utiliser cdbl

TextBox6 = CDbl(TextBox7) / 100 * CDbl(TextBox20)

val accepte que le point

 

[Dranreb]

Re : Calcul textbox

Bonjour
Essayez CDbl à la place de Val
Mais c'est plus compliqué à cause du "%".
Mettez une fonction ValFrm qui recalcule du numérique à partir de vos textes formatés.

Sub test()
Const V1 = 123, V2 = 0.1
Dim Z1 As String, Z2 As String
Z1 = Format(V1, "0.00")
Z2 = Format(V2, "0.00%")
MsgBox """" & Z1 & """ * """ & Z2 & """ = " & ValFrm(Z1) * ValFrm(Z2)
End Sub


Function ValFrm(ByVal Txt As String) As Double
If Txt Like "*%" Then
   ValFrm = CDbl(Replace(Txt, "%", "")) / 100
Else
   ValFrm = CDbl(Txt)
   End If
End Function

À +

 

[job75]

Re : Calcul textbox

Bonjour à tous,

Une solution avec ce code dans l'USF :

Private Sub TextBox7_Change()
Dim t$
t = Replace(Replace(TextBox7, "%", ""), ",", ".")
TextBox7 = Val(t) & IIf(Right(t, 1) = ".", Mid(0.1, 2, 1), "") & "%"
TextBox7.SelStart = Len(TextBox7) - 1
TextBox6 = Format(Val(Replace(Replace(TextBox7, "%", ""), ",", ".")) * Val(Replace(TextBox20, ",", ".")) / 100, "0.00 €")
End Sub

Private Sub TextBox20_Change()
Dim t$
t = Replace(Replace(TextBox20, "%", ""), ",", ".")
TextBox20 = Val(t) & IIf(Right(t, 1) = ".", Mid(0.1, 2, 1), "")
TextBox6 = Format(Val(Replace(Replace(TextBox7, "%", ""), ",", ".")) * Val(Replace(TextBox20, ",", ".")) / 100, "0.00 €")
End Sub

On peut utiliser la virgule ou le point comme séparateur décimal.

Fichier joint.

A+

 

[job75]

Re : Calcul textbox

Re,

Avec 2 variables mémorisées c'est plus simple :

Dim t1$, t2$ 'mémorise les variables

Private Sub TextBox7_Change()
t1 = Replace(Replace(TextBox7, "%", ""), ",", ".")
TextBox7 = Val(t1) & IIf(Right(t1, 1) = ".", Mid(0.1, 2, 1), "") & "%"
TextBox7.SelStart = Len(TextBox7) - 1
TextBox6 = Format(Val(t1) * Val(t2) / 100, "0.00 €")
End Sub

Private Sub TextBox20_Change()
t2 = Replace(Replace(TextBox20, "%", ""), ",", ".")
TextBox20 = Val(t2) & IIf(Right(t2, 1) = ".", Mid(0.1, 2, 1), "")
TextBox6 = Format(Val(t1) * Val(t2) / 100, "0.00 €")
End Sub

Fichier (2)

A+

 

[Dranreb]

Re : Calcul textbox

Oui, mais avec ma fonction dans un coin on ne se pose plus tellement de questions:

Me.TextBox6.Text = Format(ValFrm(TextBox7.Text) * ValFrm(TextBox20.Text), "0.00 €")

Si la TextBox20 peut aussi contenir le symbole "€":

Function ValFrm(ByVal Txt As String) As Double
If Txt Like "*%" Then
   ValFrm = CDbl(Replace(Txt, "%", "")) / 100
Else
   ValFrm = CDbl(Replace(Txt, "€", ""))
   End If
End Function

À +

 

[job75]

Re : Calcul textbox

Re,

Au lieu de contrôler les entrées dans les TextBox on peut utiliser un bouton :

Private Sub CommandButton1_Click()
Dim t1$, t2$
t1 = Replace(Replace(TextBox7, "%", ""), ",", ".")
TextBox7 = Format(Val(t1), "0.00\%")
t2 = Replace(Replace(TextBox20, "%", ""), ",", ".")
TextBox6 = Format(Val(t1) * Val(t2) / 100, "0.00 €")
End Sub

Fichier (3).

A+

 

[laetitia90]

Re : Calcul textbox

bonjour tous 🙂🙂🙂🙂🙂
dans son cas

Textbox20 est un montant saisi

on renseigne la textbox 20

Private Sub TextBox20_Change()
TextBox6 = Format(Val(TextBox7.Text) / 100 * TextBox20.Text, "0.00 €")
End Sub

eventuellement si il efface textbox20

Private Sub TextBox20_Change()
On Error Resume Next
TextBox6 = Format(Val(TextBox7.Text) / 100 * TextBox20.Text, "0.00 €")
End Sub

peut être suffisant???

 

[nicos3390]

Re : Calcul textbox

Bonjour à tous,

merci de vos retours, je ne trouve cependant pas mon bonheur, je vous joins le fichier.

 

[job75]

Re : Calcul textbox

Bonjour,

Pas de TextBox6 ,TextBox7, TextBox20 dans l'USF.

Sans explications par ailleurs, j'ai refermé le fichier.

A+

 

[nicos3390]

Re : Calcul textbox

Lorsque l'on clique sur l'userform, et que l'on choisit dans la première Combobox"SECTEUR", on passe à la seconde Combobox et l'on choisit "chaussure".
On renseigne dans montant annuel "15000", par ex.

Automatiquement l'USF va récupérer des données, en l'occurrence des pourcentages.
et Automatiquement aussi, il calcul une valeur de la manière suivante: montant annuel * le pourcentage de la ligne.

cependant je ne parviens pas à faire en sorte que ma valeur en bout de ligne tienne compte des décimales du pourcentage dans son calcul.

j'espère avoir votre aide

merci

 

[job75]

Re : Calcul textbox

Re,

Private Sub Calcul()
TextBox4 = Val(Replace(Replace(ComboBox3, "%", ""), ",", ".")) * Val(Montantannuel) / 100
TextBox6 = Val(Replace(Replace(TextBox5, "%", ""), ",", ".")) * Val(Montantannuel) / 100
TextBox13 = Val(Replace(Replace(TextBox12, "%", ""), ",", ".")) * Val(Montantannuel) / 100
TextBox14 = Val(Replace(Replace(ComboBox4, "%", ""), ",", ".")) * Val(Montantannuel) / 100
'mise en euros des résultats
TextBox4 = Format(TextBox4, "# ##0.00 €")
TextBox6 = Format(TextBox6, "# ##0.00 €")
TextBox13 = Format(TextBox13, "# ##0.00 €")
TextBox14 = Format(TextBox14, "# ##0.00 €")
End Sub

Vous n'avez même pas essayé de comprendre les codes que j'ai donnés dans mes posts précédents.

A+

 

[nicos3390]

Re : Calcul textbox

Merci pour votre solution, un peu moins pour votre analyse pédagogique.