calcul jours d’absence consécutif

[titooooo]

Bonjour,

j'ai une liste de certificat ,j'aimerais savoir la durée d’absence successive comme modèle explique déjà dans le fichier excel

 

[titooooo]

Re : calcul jours d’absence consécutif

bonjour ,

si ma question n'est pas claire je suis disponible a toute questions et 1000 merci d'avance

 

[mapomme]

Re : calcul jours d’absence consécutif

Bonsoir titooooo,

Un essai avec ce que j'en ai compris.

Concernant la feuille "Test":

Il faut en tout premier lieu trier le tableau (colonnes B à H) de la feuille "Test" selon le premier champ "MAT" en ordre croissant et selon le second champ "A partir de " en ordre croissant.

La colonne G contiendra (si le tableau est trié) le nombre de jours consécutifs d'arrêt de travail pour des arrêts consécutifs (se suivant au jour près ou bien si la fin d'un arrêt et le début de l'arrêt suivant est inférieur ou égal en jour à une valeur nommée "valeurX")

ValeurX est le nom faisant référence au contenu de la cellule K5.

Formule en colonne G:

=SI(C2<>C1;F2-E2;SI(E2<=F1+ValeurX;G1+F2-F1;F2-E2))

la colonne H indique si c'est une nouvelle série d'arrêts de travail consécutifs (à la valeurX près)

Formule en colonne G:

=SI(ESTERREUR(E2-F1); "Début période";    SI(OU(C2<>C1;ET(C2=C1;E2>F1+ValeurX));"Début période";""))

Concernant la feuille "recap":

La colonne C indique si le salarié est présent ou non à la date en C2:

Formule en colonne C:

=SI(SOMMEPROD( (B3=TEST!$C$1:$C$5000)  *  (TEST!$E$1:$E$5000<=$C$2)  *  (recap!$C$2<=TEST!$F$1:$F$5000) )>0; "En congé maladie";"Présent")

La colonne D indique le nombre de jours consécutifs d'arrêt ( à la valeurX près ) pour la dernière série d'arrêts dont la fin est antérieure à la date en D2. C'est une formule matricielle.

Formule matricielle en colonne D:

=SI(MAX(SI((B3=TEST!$C$1:$C$5000)*(TEST!$F$1:$F$5000<=$D$2)>0;LIGNE(TEST!$F$1:$F$5000);""))=0;" ";  INDEX(TEST!$G$1:$G$5000;MAX(SI((B3=TEST!$C$1:$C$5000)*(TEST!$F$1:$F$5000<=$D$2)>0;LIGNE(TEST!$F$1:$F$5000);""))))

Formule matricielle: Elle doit être validée par la combinaison des touches Ctrl+Maj+Entrée au lieu de la seule touche Entrée comme une formule classique.
Si la validation matricielle est correcte, alors Excel entoure la formule d'accolades {=.......}.
Chaque fois que cette formule sera modifiée, la validation devra se faire par Ctrl+Maj+Entrée. Les accolades apparaissent à la validation et ne doivent pas être saisies au clavier.

nb: il y a dans le fichier des arrêts de travail dont les dates se chevauchent. Il me semble qu'un arrêt de travail est soit un nouvel arrêt soit une prolongation et dans ce dernier cas le chevauchement de dates n'est pas toléré (du moins dans ma boîte, c'est refusé)

 

[titooooo]

Re : calcul jours d’absence consécutif

vraiment je suis épaté mon ami

bravo

juste sur le dernier point y'as il une méthode pour détecter dans le suivi de certificat les dates qui se chevauchent et pouvoir agir en conséquent

encore merci pour ce travail PRO

 

[mapomme]

Re : calcul jours d’absence consécutif

Bonjour titooooo

juste sur le dernier point y'as il une méthode pour détecter dans le suivi de certificat les dates qui se chevauchent et pouvoir agir en conséquent

Pour ce point voir colonne I de la feuille "Test" du fichier joint.
Après des corrections, il faut absolument re-trier le tableau -> j'ai rajouté un bouton "Trier"

nb: j'ai mal lu et confondu date de fin d'arrêt et date de reprise. A priori, cela ne change pas les formules sauf pour celles de la colonne C de la feuille "Récap" qui devient:

=SI(SOMMEPROD( (B3=TEST!$C$1:$C$5000)  *  (TEST!$E$1:$E$5000<=$C$2)  *  ($C$2<TEST!$F$1:$F$5000) )>0; "En congé maladie";"Présent")

Je te conseille vivement de faire des vérifications sur les résultats du fichier; j'ai pu me planter peut-être sur certaines inégalités (entre > et >= par exemple) - je quitte XLD, Morphée m'attend...