XL 2013 caclul champs différent

[vidou]

Bonjour ,

je vous joins un fichier dans lequel je voudrais calculer une sommes d'estimé et de réél

Le total doit reprendre la somme des estimés si il n'y a pas de saisie de chiffre réél. Puis si on saisi sur la ligne réél, il faut prendre en compe le dernier réél saisi + la sommes de l'estimé des colonnes suivantes.

Vous remerciant par avance car la je patauge ( j'ai trouvé comment obtenir le dernier champs saisi de ligne réél )

Cordialement

 

[Lolote83]

Salut,
Somme estimée =SOMMEPROD((B3:F3)*(ESTVIDE(B2:F2)))
Vu que tu as trouvé comment obtenir le dernier champs réél), il te suffit de faire la somme
@+ Lolote83

 

[JHA]

Bonjour à tous,

Un essai en matriciel

=SOMME(DECALER($A3;;GRANDE.VALEUR(SI($B$2:$F$2<>"";$B$1:$F$1);1)+1;;MAX($B$1:$F$1)-GRANDE.VALEUR(SI($B$2:$F$2<>"";$B$1:$F$1);1)))+RECHERCHEH(9^9;$B$2:$F$2;1)

JHA

 

[JHA]

Bonjour à tous,

Une autre avec max()

=RECHERCHEH(9^9;$B$2:$F$2;1)+SOMME(DECALER(A3;;MAX(SI($B$2:$F$2<>"";$B$1:$F$1))+1;;MAX($B$1:$F$1)-MAX(SI($B$2:$F$2<>"";$B$1:$F$1))))

JHA

 

[vidou]

Bonjour,
Merci pour cette aide mais dès que je veux reproduire la formule sur un autre onglet ou dès que je valide la cellule des estimés, j'ai #valeur qui apparaît avec l'une ou l'autre

 

[Jocelyn]

Bonjour le Forum,
Bonjour vidou, Lolote83🙂,JHA🙂,

Lolote et JHA n'étant pas connecté je me permet d'intervenir

les formules de JHA doivent être validées matriciellement en appuyant simultanément sur CTRL, MAJ (au dessus de CTRL) et entrée

après si tu ne veux pas avoir a valider matriciellement tu peux faire un mixte des formule de LOlotte et JHA de cette façon

=RECHERCHEH(9^9;$B$2:$F$2;1)+SOMMEPROD(B3:F3*(B2:F2=""))

Cordialement

 

[vidou]

Bonjour,

C'est juste PARFAIT !!! Super grand merci !!!