Bordure d'un tableau

[pierrof]

Re-bonjour

Voila je voudrai réaliser à partir d'une macro, les bordures d'un tableau.
Le nombre de lignes du tableau peut variée.
Et de plus je souhaite que la bordure externe du tableau soit du type gras.

Je joins un fichier pour plus d'information avec le résultat attendu

Merci

 

[tototiti2008]

Re : Bordure d'un tableau

Bonjour à tous,

un truc du genre (je l'ai fait alors je le poste 😉)

Private Sub CommandButton1_Click()
    With Range("A10").CurrentRegion
        With .Borders(xlInsideVertical)
            .LineStyle = xlContinuous
            .Weight = xlThin
            .ColorIndex = xlAutomatic
        End With
        With .Borders(xlInsideHorizontal)
            .LineStyle = xlContinuous
            .Weight = xlThin
            .ColorIndex = xlAutomatic
        End With
        With .Borders(xlEdgeLeft)
            .LineStyle = xlContinuous
            .Weight = xlMedium
            .ColorIndex = xlAutomatic
        End With
        With .Borders(xlEdgeTop)
            .LineStyle = xlContinuous
            .Weight = xlMedium
            .ColorIndex = xlAutomatic
        End With
        With .Borders(xlEdgeBottom)
            .LineStyle = xlContinuous
            .Weight = xlMedium
            .ColorIndex = xlAutomatic
        End With
        With .Borders(xlEdgeRight)
            .LineStyle = xlContinuous
            .Weight = xlMedium
            .ColorIndex = xlAutomatic
        End With
    End With
End Sub

 

[pierrof]

Re : Bordure d'un tableau

Parfait

Merci beaucoup

 

[Staple1600]

Re : Bordure d'un tableau

Bonsoir


En version allégée 😉

Sub a()
ActiveCell.CurrentRegion.Borders.LineStyle = 1
ActiveCell.CurrentRegion.BorderAround 1, -4138
End Sub

Sub a_version_extra_light()
With ActiveCell.CurrentRegion: .Borders.LineStyle = 1: .BorderAround 1, -4138: End With
End Sub

EDITION: en version avec paramètres

Private Sub appliquer_bordure(f1$, source$, _
                              f2$, desti$, _
                              vWeight As XlBorderWeight)
Sheets(f1).Range(source).CurrentRegion.Copy Sheets(f2).Range(desti)
With Sheets(f2).Range(desti).CurrentRegion
    .Borders.LineStyle = 1
    .BorderAround 1, vWeight
End With
End Sub

Sub test()
appliquer_bordure "Feuil1", "A10", "Feuil2", "A10", xlMedium
End Sub