Microsoft 365 Besoin d'aide avec la formule rechercheV

Anto42 · 28 Novembre 2023

Bonjour à tous,
Je suis nouveau sur le forum et j'essaie d'apprendre à me servir d'excel.
J'ai besoin d'utiliser la formule rechercheV pour retourner le resultat de plusieurs champs correspondant à un ID dans plusieurs lignes d'une autre feuille de calcul.
Je tourne en rond sans parvenir au résultat pourtant cela me parait simple.
Je vous met un exemple de ce que je souhaiterai avoir
Merci d'avance pour votre aide
Anto

sylvanu · 28 Novembre 2023

Bonsoir Anto, et bienvenu sur XLD,
Une approche simple en PJ mais avec lignes colonnes inversées, en attendant une réponse plus pertinente :

VB:

=SIERREUR(INDEX(donnees!$B$2:$B$8;PETITE.VALEUR(SI(donnees!$A$2:$A$8=B$1;LIGNE(INDIRECT("1:"&LIGNES(donnees!$B$2:$B$8))));LIGNES($1:1)));"")

Sur les anciennes versions XL à valider par Maj+Ctrl+Entrée, sur 365 on peut s'en passer.

job75 · 28 Novembre 2023

Bonsoir Anto42, sylvanu,

Formule matricielle en A2, à tirer vers le bas :

Code:

=SIERREUR(PETITE.VALEUR(SI(NON(NB.SI(A$1:A1;donnees!A$2:A$8));donnees!A$2:A$8);1);"")

Formule matricielle en B2, à tirer à droite et vers le bas :

Code:

=SIERREUR(INDEX(donnees!$B:$B;PETITE.VALEUR(SI(donnees!$A$2:$A$8=$A2;LIGNE(donnees!$B$2:$B$8));COLONNE(A2)));"")

A+

Anto42 · 28 Novembre 2023

Merci pour votre aide @sylvanu et @job75 !
Je vais essayer de comprendre vos formules à tête reposée…

Anto42 · 29 Novembre 2023

Petite question pour ma culture, si je connaissais les attributs possibles est ce que cela simplifierait les formules? Comme dans ce fichier par exemple. Merci d’avance

R@chid · 29 Novembre 2023

Bonsoir @ tous,

Anto42 à dit:
Bonjour à tous,
Je suis nouveau sur le forum et j'essaie d'apprendre à me servir d'excel.
J'ai besoin d'utiliser la formule rechercheV pour retourner le resultat de plusieurs champs correspondant à un ID dans plusieurs lignes d'une autre feuille de calcul.
Je tourne en rond sans parvenir au résultat pourtant cela me parait simple.
Je vous met un exemple de ce que je souhaiterai avoir
Merci d'avance pour votre aide
Anto

Sous Excel pour Microsoft 365 :
en A2 :

VB:

=TRIER(UNIQUE(donnees!A2:A8))

En B2 :

Code:

=TRANSPOSE(FILTRE(donnees!B$2:B$8;donnees!A$2:A$8=A2))

@ tirer vers le bas

Cordialement,

job75 · 29 Novembre 2023

Bonjour Anto42, R@chid, le forum,

Anto42 à dit:
Petite question pour ma culture, si je connaissais les attributs possibles est ce que cela simplifierait les formules?

Bien sûr avec cette formule (normale) unique en B2 à tirer sur B24, fichier 5 :

Code:

=REPT(B$1;SOMMEPROD((donnees!$A$2:$A$8=$A2)*(donnees!$B$2:$B$8=B$1))>0)

De plus on peut mettre le tableau source sous forme de tableau structuré pour éviter de modifier les références, fichier 6 :

Code:

=REPT(B$1;SOMMEPROD((INDEX(Tableau1;;1)=$A2)*(INDEX(Tableau1;;2)=B$1))>0)

Avec INDEX on évite l'incrémentation des colonnes.

A+

Anto42 · 29 Novembre 2023

Top merci pour toutes ces réponses!

Microsoft 365 Besoin d'aide avec la formule rechercheV

Anto42

XLDnaute Nouveau

Pièces jointes

sylvanu

XLDnaute Barbatruc

Pièces jointes

job75

XLDnaute Barbatruc

Pièces jointes

Anto42

XLDnaute Nouveau

Anto42

XLDnaute Nouveau

Pièces jointes

R@chid

XLDnaute Barbatruc

job75

XLDnaute Barbatruc

Pièces jointes

Anto42

XLDnaute Nouveau

Discussions similaires