Alimenter une listbox multi colonne

[Lu K]

Bonjour à toutes et à tous,

Je reviens vers vous car j'ai découvert qu'une listbox pouvais être multi colonne !!

Mais mon souci est que je n'arrive pas à l'alimenter comme sur plusieurs listbox

Pouvez vous m'aider SVP.

Merci d'avance.

Dim cel As Range 'déclare la variable cel (CELlule)
Me.Listebox1.Clear
Me. Listebox2.Clear
Me. Listebox3.Clear

With Sheets("Feuil1")
    For Each cel In .Range("d3:d" & .Range("d65536").End(xlUp).Row)
        If cel.Value = Me.Textbox1.Value Then
Me. Listebox1.AddItem cel.Offset(0, -3).Value
Me. Listebox2.AddItem cel.Offset(0, -2).Value
Me. Listebox3.AddItem cel.Offset(0, -1).Value
    Next cel
End With

 

[Pierrot93]

Re : Alimenter une listbox multi colonne

Bonjour,

regarde ceci, si ca peut t'aider, concerne l'initialisation d'une seule listbox :

Option Explicit
Private Sub UserForm_Initialize()
Dim cel As Range
With ListBox1
    .ColumnCount = 4
    For Each cel In Range("d3:d" & Range("d65536").End(xlUp).Row)
        .AddItem cel.Value
        .List(.ListCount - 1, 1) = cel.Offset(0, -3).Value
        .List(.ListCount - 1, 2) = cel.Offset(0, -2).Value
        .List(.ListCount - 1, 3) = cel.Offset(0, -1).Value
    Next cel
End With
End Sub

bonne soirée
@+

 

[tototiti2008]

Re : Alimenter une listbox multi colonne

Bonjour Lu K, Bonjour Pierrot,

Ou alors, pour exclure ce qui est différent de Textbox1

Private Sub CommandButton1_Click()
Dim i As Long
    With ListBox1
        .ColumnCount = 4
        .List = Range("A3:D" & Range("D65536").End(xlUp).Row).Value
        For i = .ListCount - 1 To 0 Step -1
            If .List(i, 3) <> TextBox1.Text Then
                .RemoveItem i
            End If
        Next i
    End With
End Sub

Edit : C'est la bouteille à moitié pleine contre la bouteille à moitié vide 😉

 

[Lu K]

Re : Alimenter une listbox multi colonne

Bonjour Pierrot93 et Tototiti2008

Merci pour vos réponse qui vont beaucoup m'aider.

Un grand merci