Microsoft 365 Alimenter une Combo Active X inséré dans une feuille de calcul

NONO14 · Vendredi à 15:41

Bonjour le forum?

Lorsque j'active la feuille de calcul "CalculHS", je souhaite alimenter la ComboBox ActiveX "Cmb_Code" de cette même feuille de calcul avec les données de la colonne "Code agent" d'un tableau structuré "t_Noms" de la feuille "Liste_agents"

J'ai fait ce code mais j'ai un message d'erreur sur la ligne définir la ComboBox "Erreur de compilation - Membre de méthode ou de données introuvable"
Pourriez-vous m'aider à résoudre ce problème s'il vous plaît ? J'ai utilisé l'aide mais je ne comprends pas.
Merci par avance

VB:

Sub AlimenterComboBox()
Dim WsCalculHS As Worksheet
Dim WsListe As Worksheet
Dim Tbl As ListObject
Dim Cell As Range
Dim Cbx As Object

    ' Définir les feuilles de calcul
    Set WsCalculHS = Sheets("CalculHS") ' Feuille de calcul contenant la ComboBox
    Set WsListe = Sheets("Liste_agents") ' Feuille de calcul contenant le tableau structuré

    ' Définir le tableau structuré
    Set Tbl = WsListe.ListObjects("t_Noms") ' Nom du tableau structuré

    ' Définir la ComboBox
    Set Cbx = WsCalculHS.Cmb_Code

    ' Vider la ComboBox avant de la remplir
    Cbx.Clear

    ' Parcourir chaque cellule de la colonne "Code agent" du tableau structuré et ajouter les valeurs à la ComboBox
    For Each Cell In Tbl.ListColumns("Code agent").DataBodyRange
        Cbx.AddItem Cell.Text
    Next Cell
End Sub

NONO14 · Vendredi à 15:57

J'ai trouvé la réponse
Voici le code qui fonctionne :

VB:

Sub AlimenterComboBox()
    Dim WsCalculHS As Worksheet
    Dim WsListe As Worksheet
    Dim Tbl As ListObject
    Dim Cell As Range
    Dim Cb As ComboBox ' Changez la déclaration pour éviter les conflits de type d'objet

    ' Définir les feuilles de calcul
    Set WsCalculHS = ThisWorkbook.Sheets("CalculHS") ' Feuille de calcul contenant la ComboBox
    Set WsListe = ThisWorkbook.Sheets("Liste_agents") ' Feuille de calcul contenant le tableau structuré

    ' Définir le tableau structuré
    Set Tbl = WsListe.ListObjects("t_Noms") ' Nom du tableau structuré

    ' Définir la ComboBox en utilisant OLEObjects
    Set Cb = WsCalculHS.OLEObjects("Cmb_Code").Object

    ' Vider la ComboBox avant de la remplir
    Cb.Clear

    ' Parcourir chaque cellule de la colonne "Code agent" du tableau structuré et ajouter les valeurs à la ComboBox
    For Each Cell In Tbl.ListColumns("Code agent").DataBodyRange
        Cb.AddItem Cell.Value
    Next Cell
End Sub

jurassic pork · Vendredi à 15:57

Hello,
As tu essayé :

VB:

Set Cbx = CalculHS.Cmb_Code

directement le nom de la feuille.
Ami calmant, J.P

NONO14 · Vendredi à 15:58

jurassic pork à dit:
Hello,
As tu essayé :

VB:

Set Cbx = CalculHS.Cmb_Code

directement le nom de la feuille.
Ami calmant, J.P

Bonjour,
Non je n'ai pas essayé, mais j'avais trouvé une solution.
Merci beaucoup

Microsoft 365 Alimenter une Combo Active X inséré dans une feuille de calcul

NONO14

XLDnaute Impliqué

NONO14

XLDnaute Impliqué

jurassic pork

XLDnaute Occasionnel

NONO14

XLDnaute Impliqué

Discussions similaires