Alerte prise de RDV

[kimcergy]

Bonjour à tous,

Voila, je voudrais créer une feuille Excel avec des flash de rappel à chaque heure indiquée.
Par ex à chaque ligne, je voudrais qu'un pop up s'affiche avec le nom du site à chaque heure
indiquée.

Je vous remercie par avance de votre aide
Cordialement

 

[kimcergy]

Re : merci de m'aider

Un rappel de 15mn avant le RDV svp

 

[kimcergy]

Re : merci de m'aider

Personne ?

 

[kimcergy]

Re : merci de m'aider

Aidez moi svp

 

[kimcergy]

Re : merci de m'aider

Pour éclaircir ma demande, je voudrais une alarme sonore ou visuelle 15mn avant l'heure du RDV.
Pensez vous que cela est possible ?

Merci par avance

 

[job75]

Re : merci de m'aider

Bonjour kimcergy,

Voyez le fichier joint et ces 3 macros dans ThisWorkbook (Alt+F11) :

Private Sub Workbook_Open()
Dim a, i&
a = [Tableau]
[Tableau].Columns(5).ClearContents 'RAZ
Application.OnTime 0, "ThisWorkbook.Minuit"
For i = 1 To UBound(a)
  Application.OnTime Date + a(i, 1) - 15 / 1440, "ThisWorkbook.Alerte"
Next
End Sub

Sub Minuit()
Workbook_Open 'pour reinitialiser les alertes
End Sub

Sub Alerte()
Dim a, i&
a = [Tableau]
For i = 1 To UBound(a)
  If Time >= a(i, 1) - 15 / 1440 And Time < a(i, 1) And a(i, 5) = "" Then
    MsgBox Format(a(i, 1), "h:mm") & " " & a(i, 2), , "Rappel RV"
    [Tableau].Cells(i, 5) = "X"
  End If
Next
End Sub

Nota 1 : la colonne auxiliaire "Alertes" en Feuil1 est indispensable.

Nota 2 : le tableau est défini dynamiquement par le nom Tableau.

A+

 

[job75]

Re : merci de m'aider

Re,

Si l'on entre de nouvelles heures en Feuil1 il faut fermer le fichier (1) et le rouvrir pour réinitialiser les alertes.

Mais on peut aussi utiliser ce fichier (2) avec cette macro dans le code de Feuil1 :

Private Sub Worksheet_Change(ByVal Target As Range)
If Not Intersect(Target, [A:A]) Is Nothing Then ThisWorkbook.Minuit
End Sub

Les alertes seront réinitialisées à chaque modification de la colonne A.

A+

 

[job75]

Re : merci de m'aider

Re,

Encore une chose kimcergy.

Allez sur votre post #1, cliquez sur "Modifier le message" et modifiez le titre de la discussion.

Appelez-la par exemple Alertes pour rendez-vous.

Cela permettra de retrouver facilement cette discussion à partir de ces mots clés.

A+

 

[kimcergy]

Re : merci de m'aider

Bonjour Job75,

Je vous remercie beaucoup de m'aider.
Je voudrais cependant pour l'alerte, agrandir et mettre une couleur bleu ou rouge avec un son. Est ce possible ?

Encore merci à vous

 

[job75]

Re : merci de m'aider

Bonjour kimcergy,

Je n'aime pas trop les questions à rallonges, et ma solution est amplement suffisante.

Maintenant si vous êtes un adepte des gadgets allez-y mais débrouillez-vous tout seul.

Edit : en plus cher ami, mon post #8 vous vous en tapez le coquillard 😡

A+

 

[kimcergy]

Re : merci de m'aider

Peut on aussi voir l'alerte même si on travaille sur une autre appli ?
Merci à vous

 

[job75]

Re : merci de m'aider

Peut on aussi voir l'alerte même si on travaille sur une autre appli ?
Merci à vous

Oui le message sera créé mais normalement il faut activer Excel pour le voir.

Vous pouvez essayer en mettant dans la macro Alerte avant la MsgBox :

AppActivate "Microsoft Excel"

A+

 

[job75]

Re : Alerte prise de RDV

Re,

J'ai testé avec Word activé : il faut bien AppActivate "Microsoft Excel" dans la macro "Alerte".

Mais le message Excel reste dans la barre des tâches, en clignotant.

Je suis sur Win 7 - Office 2010.

A+

 

[kimcergy]

Re : Alerte prise de RDV

Re,
Je suis un debutant en office. Pouvez vous m'expliquer comment mettre AppActivate "Microsoft Excel" dans la macro "Alerte
Merci de votre aide

 

[job75]

Re : Alerte prise de RDV

Re,

Sub Alerte()
Dim a, i&
a = [Tableau]
For i = 1 To UBound(a)
  If Time >= a(i, 1) - 15 / 1440 And Time < a(i, 1) And a(i, 5) = "" Then
    AppActivate "Microsoft Excel"
    MsgBox Format(a(i, 1), "h:mm") & " " & a(i, 2), , "Rappel RV"
    [Tableau].Cells(i, 5) = "X"
  End If
Next
End Sub

A+