Ajouté des séries sur un graph avec une maccro

[MrBMCi]

Bonjour ,

J'aimerais ajouté une série sur un graph avec une maccro , j'ai ça pour l'instant :

ActiveChart.ChartObjects("Chart").Activate
ActiveChart.ChartArea.Select
ActiveChart.SeriesCollection.NewSeries
ActiveChart.SeriesCollection(1).Name = "='Sheet2'!A1"
ActiveChart.SeriesCollection(1).XValues = "='sheet2'!A3:A83"
ActiveChart.SeriesCollection().Values = "='Sheet2'!B3:B83"

mais j'ai une erreur a la premiére ligne du programme 🙁

Je suis vraiment pas sur de cette macro , c'est la premiére fois que j'essaie d'ajoutée une série

Si quelqu'un a une idée merci 😀

 

[Pierrot93]

Re : Ajouté des séries sur un graph avec une maccro

Bonjour,

regarde ceci, si cela peut t'aider, à adapter :

Dim c As ChartObject, s As Series
Set c = ActiveSheet.ChartObjects(1)
With c.Chart
    Set s = .SeriesCollection.NewSeries
    With s
        .Values = Feuil6.Range("B9:D9")
        .Name = Feuil6.Range("A9")
    End With
End With

bon après midi
@+

 

[MrBMCi]

Re : Ajouté des séries sur un graph avec une maccro

Merci de ton aide j'ai donc maintenant :

Dim c As ChartObject, s As Series

Set c = ActiveSheet.ChartObjects(1)
With c.Chart
Set s = .SeriesCollection.NewSeries
With s
.Values = Sheet2.Range("A3:A83")
.Name = Sheet2.Range("A1")
End With
End With


End Sub


Mais la premiére ligne pose toujours probléme et cause une erreur 1004 , j'ai pourtant bien un graph sur la feuille 1 , et mes donnés sont sur la feuille 2 ( en A3:A83 et B3:B83 )
De plus dans ce code je ne sélectionne qu'une plage de données , il me faut pourtant les x et les y ?

merci

 

[Pierrot93]

Re : Ajouté des séries sur un graph avec une maccro

Re,

essaye ainsi, attention, dans le code précédant, j'utilisais le "codename" de la feuille :

Option Explicit
Sub test()
Dim c As ChartObject, s As Series
    Set c = Sheets("Feuil1").ChartObjects(1)
    With c.Chart
        Set s = .SeriesCollection.NewSeries
        With s
            .XValues = Sheets("Feuil2").Range("B3:B83")
            .Values = Sheets("Feuil2").Range("A3:A83")
            .Name = Sheets("Feuil2").Range("A1")
        End With
    End With
End Sub

 

[MrBMCi]

Re : Ajouté des séries sur un graph avec une maccro

Merci beaucoup , sa fonctionne parfaitement 🙂

Juste une derniére question en fait ,
Sais tu comment supprimer toute les séries d'un même graph ?

 

[Pierrot93]

Re : Ajouté des séries sur un graph avec une maccro

Re,

code ci-dessous :

Dim s As Series
For Each s In ActiveSheet.ChartObjects(1).Chart.SeriesCollection
    s.Delete
Next s

 

[MrBMCi]

Re : Ajouté des séries sur un graph avec une maccro

Merci pour cette macro elle fonctionne bien elle aussi 😀