Ajout feuille => modif macro

[Jiheme]

Bonjour le Forum

La macro suivante fonctionne parfaitement, elle copie sous 3 lignes de titres le contenu d'une douzaine de feuilles sauf les 3 lignes de titres qui sont les mêmes sur toutes les feuilles.

Sub MAJ()
Dim lign As Long
Dim ligne As Long, Nombre As Integer
Dim budget As Range
Dim totbudget As Range
Set totbudget = Range("M4")
Set budget = Range("M4:M" & Range("M65536").End(xlUp).Row)
lign = Sheets("Portefeuille").Range("A65535").End(xlUp).Row
Rows("4:" & lign).Clear
Application.ScreenUpdating = False
For Nombre = 2 To Sheets.Count
If Range("D4") = "" Then
ligne = 4
Sheets(Nombre).Range("A4:EE" & Sheets(Nombre).Range("a65536").End(xlUp).Row).Copy Sheets(1).Range("A" & ligne)
Else
ligne = Range("D65536").End(xlUp).Row + 1
Sheets(Nombre).Range("A4:EE" & Sheets(Nombre).Range("a65536").End(xlUp).Row).Copy Sheets(1).Range("A" & ligne)
End If
Next Nombre
Application.ScreenUpdating = True
Cells(1, 2).Value = "MAJ " & Date & " à " & Time
End Sub

Je souhaite maintenant ajouter une feuille en tête de mon classeur et je n'arrive pas à modifier cette macro pour que la copie soit OK, cela efface mes titres et ne copie rien du tout.

L'un d'entre vous peut il me guider
A+

 

[Pierrot93]

Re : Ajout feuille => modif macro

Bonjour Jiheme,

pas sur d'avoir tout compris, mais si tu veux rajouter une feuille pour qu'elle se retrouve en position 1, regarde le code ci dessous :

Sheets.Add Sheets(1)

bon dimanche
@+

 

[Jiheme]

Re : Ajout feuille => modif macro

Bonjour Pierrot, le forum

Je ne cherche pas à ajouter une feuille avec la macro, j'ai voulu rajouter une feuille en premier et la macro que j'avais eu beaucoup de mal (avec l'aide de plusieurs XLdiens) ne fonctionne plus du tout cela me met un "boxon" pas possible.

 

[pierrejean]

Re : Ajout feuille => modif macro

bonjour Jiheme

Salut Pierrot

modifie

Sheets(Nombre).Range("A4:EE" & Sheets(Nombre).Range("a65536").End(xlUp).Row).Copy Sheets(1).Range("A" & ligne)
en
Sheets(Nombre).Range("A4:EE" & Sheets(Nombre).Range("a65536").End(xlUp).Row).Copy Sheets(2).Range("A" & ligne)

ou mieux

Sheets(Nombre).Range("A4:EE" & Sheets(Nombre).Range("a65536").End(xlUp).Row).Copy Sheets("nom de la feuille").Range("A" & ligne)

 

[Jiheme]

Re : Ajout feuille => modif macro

Bonjour Pierrejean

Merci beaucoup cela marche impec.

Si je comprends bien en mettant le nom de la fauille plutôt que (2) cela me permets d'en inserer avant cette feuille autant que je veux sans problème ?

 

[pierrejean]

Re : Ajout feuille => modif macro

Re

Exact

 

[bqtr]

Re : Ajout feuille => modif macro

Bonjour Jiheme, pierrejean, Pierrot93

Une autre façon: si toutes les feuilles sauf la feuille "Portefeuille 0907" sont à copier tu peux faire comme ceci:

Sub Report()

Dim lign As Long
Dim ligne As Long, Ws As Worksheet

lign = Sheets("Portefeuille 0907").Range("A65535").End(xlUp).Row
If lign = 1 Then lign = 4
Rows("4:" & lign).Clear

Application.ScreenUpdating = False
With Sheets("Portefeuille 0907")
    For Each Ws In ThisWorkbook.Worksheets
      If Ws.Name <> "Portefeuille 0907" Then
        If .Range("A4") = "" Then
           ligne = 4
           Ws.Range("A4:EE" & Ws.Range("a65536").End(xlUp).Row).Copy .Range("A" & ligne)
        Else
           ligne = .Range("a65536").End(xlUp).Row + 1
           Ws.Range("A4:EE" & Ws.Range("a65536").End(xlUp).Row).Copy .Range("A" & ligne)
        End If
      End If
    Next
.Cells(1, 2) = "MAJ " & Date & " à " & Time
End With
Application.ScreenUpdating = True

End Sub

Si tu as d'autres feuilles qui ne doivent pas être copiées, tu rajoutes leurs noms sur cette ligne : Ex pour la feuille "Non attr" (sur la base de ton fichier de l'autre jour)

If Ws.Name <> "Portefeuille 0907" And Ws.Name <> "Non attr" Then

Bonne journée

 

[Jiheme]

Re : Ajout feuille => modif macro

Bonjour btqr, le forum

Merci je vais tester les 2 et je conserve celle qui va bien.

A+