aide sur une methode

[pems]

bonsoir tous le monde
je voudrais savoir s' il existe un methode ou une formule pour que je puisse ecrire une phrase ecrite dans une seule cellule sur plusieure celules mais sur la meme ligne
merci

 

[Dranreb]

Re : aide sur une methode

Bonjour.
Il y aurait ça, à retravailler un peu, peut être:

Function Mots(Z As String) As Variant
Mots = Split(Z)
End Function

et en F8:AB8:

=Mots($E8)

validé par Ctrl+Maj+Entrée
À +

 

[mapomme]

Re : aide sur une methode

Bonjour pems,

Un essai par une formule matricielle en F8 à copier vers la droite jusqu’à l’apparition de cellules vides. Attention! la formule ne gère pas les espaces consécutifs (car trop d’imbrication de niveaux pour Excel 2003). Sinon pour Excel >=2007, remplacer $E8 par SUPPRESPACE($E8) dans la formule.

La formule matricielle en F8 à copier vers la droite et vers le bas :

=SI(COLONNE()-COLONNE($F8)+1>NBCAR($E8)-NBCAR(SUBSTITUE($E8; " "; ""))+1; ""; STXT(" "& $E8 & " "; PETITE.VALEUR(SI(STXT(" "& $E8 & " "; LIGNE(INDIRECT("1:" & NBCAR("  "& $E8 & " "))); 1)=" "; LIGNE(INDIRECT("1:" & NBCAR(" "& $E8 & " "))); ""); COLONNE()-COLONNE($F8)+1)+1; PETITE.VALEUR(SI(STXT(" "& $E8 & " "; LIGNE(INDIRECT("1:" & NBCAR("  "& $E8 & " "))); 1)=" "; LIGNE(INDIRECT("1:" & NBCAR(" "& $E8 & " "))); ""); COLONNE()-COLONNE($F8)+2)-PETITE.VALEUR(SI(STXT(" "& $E8 & " "; LIGNE(INDIRECT("1:" & NBCAR("  "& $E8 & " "))); 1)=" "; LIGNE(INDIRECT("1:" & NBCAR(" "& $E8 & " "))); ""); COLONNE()-COLONNE($F8)+1)-1))

Formule matricielle: Elle doit être validée par la combinaison des touches Ctrl+Maj+Entrée au lieu de la seule touche Entrée comme une formule classique.
Si la validation matricielle est correcte, alors Excel entoure la formule d'accolades {=.......}.
Chaque fois que cette formule sera modifiée, la validation devra se faire par Ctrl+Maj+Entrée. Les accolades apparaissent à la validation et ne doivent pas être saisies au clavier.

nb: mais avec un peu de VBA, c'est bien plus clair!

 

[Dull]

Re : aide sur une methode

Salut pems, Bernard🙂, mapomme🙂, le Forum

Une autre formule sans validation matricielle, qui gère les multi-espaces mais avec une colonne vide entre la phrase et la Formule (Made by Monique🙂)

=SI(SOMMEPROD(NBCAR($F11:F11))+COLONNES($F11:F11)>=NBCAR(SUPPRESPACE($E11));"";STXT(SUPPRESPACE($E11);SOMMEPROD(NBCAR($F11:F11))+COLONNES($F11:F11);TROUVE(" ";SUPPRESPACE($E11)&" ";SOMMEPROD(NBCAR($F11:F11))+COLONNES($F11:F11))-SOMMEPROD(NBCAR($F11:F11))-COLONNES($F11:F11)))

A tester

...nb: mais avec un peu de VBA, c'est bien plus clair!

je confirme 😉

Bonne Journée

 

[Staple1600]

Re : aide sur une methode

Bonjour à tous

je voudrais savoir s' il existe un methode ou une formule

La méthode s'appelle: Données/Convertir/Délimité Séparateur: [X] Espace

Et cette méthode est bigrement efficace bien que souvent délaissée ou ignorée 😉

pems:
Alors formule ou méthode ? Question de goût personnel (pour moi ce sera plutôt un inclinaison prononcée vers la méthode 😉 )

 

[Dull]

Re : aide sur une methode

Salut JM🙂, le Fil

Bonjour à tous

La méthode s'appelle: Données/Convertir/Délimité Séparateur: [X] Espace...

Je Confirme à nouveau... 😛

Bonne Journée

 

[david84]

Re : aide sur une methode

Bonjour tout le monde,
formule avec validation classique sans colonne de séparation et avec gestion des multi-espaces :

=SI(COLONNES($A:A)<=NBCAR("/"&SUBSTITUE(SUPPRESPACE($E8);" ";"/")&"/")-NBCAR(SUBSTITUE("/"&SUBSTITUE(SUPPRESPACE($E8);" ";"/")&"/";"/";""))-1;STXT("/"&SUBSTITUE(SUPPRESPACE($E8);" ";"/")&"/";CHERCHE("/";SUBSTITUE(" "&SUPPRESPACE($E8)&" ";" ";"/";COLONNES($A:A)))+1;CHERCHE("/";SUBSTITUE(" "&SUPPRESPACE($E8)&" ";" ";"/";COLONNES($A:B)))-CHERCHE("/";SUBSTITUE(" "&SUPPRESPACE($E8)&" ";" ";"/";COLONNES($A:A)))-1);"")

Mais c'est effectivement plus simple via VBA.
A+

 

[Staple1600]

Re : aide sur une methode

Bonjour david84

Mais c'est effectivement plus simple via VBA.

Certes 😉
Mais c'est encore plus simple (et plus K.I.S.S) avec Données/Convertir 😉 (voir mon précédent message)

 

[david84]

Re : aide sur une methode

Bonjour Jean-Marie,
d'accord avec toi mais j'ai surtout voulu rebondir sur les formules proposées avant mon intervention.
A+

 

[pems]

Re : aide sur une methode

merci è tous