Aide sur procédure Worksheet Change

[hypo78]

Bonsoir à tous,

j'ai le code suivant qui me permet de masquer des lignes en fonction d'un choix en "K6", et de mettre en majuscule les saisies des cellules de la plage (D45😀54)

le code :

Private Sub Worksheet_Change(ByVal Target As Range)
Application.ScreenUpdating = False
If Target.Address = "$K$6" Then
ActiveSheet.Unprotect
    Rows("16:42").Hidden = False
    Select Case Target
    Case "1/2 Journée FO"
        Rows("16:23").Hidden = True
        Rows("32:42").Hidden = True
    Case "Journée FO / TDL"
        Rows("32:42").Hidden = True
    Case "1/2 Journée TDL"
        Rows("24:42").Hidden = True
    Case "1/2 Journée FF"
        Rows("16:31").Hidden = True
    End Select
ActiveSheet.Protect
End If

If Intersect(Target, [D45:D54]) Is Nothing Then Exit Sub
 Application.EnableEvents = False
 Target = UCase(Target)
 Application.EnableEvents = True
Application.ScreenUpdating = True

End Sub

Je voudrais ajouter la mise en Proper pour les cellules des plages (J45:J54) et (AG45:AG54)

Quand j'ajoute avant le End Sub

 If Intersect(Target, [J45:J54]) Is Nothing Then Exit Sub
 Application.EnableEvents = False
 Target = UCase(Target)
 Application.EnableEvents = True
Application.ScreenUpdating = True

pour tester avant même de me lancer dans le code Proper, çà ne fonctionne pas.

Pourquoi?

 

[hypo78]

Re : Aide sur procédure Worksheet Change

à lire de plus près mon code je crois que c'est le Then Exit Sub qui devrait être remplacé par then Go To non?

 

[jpb388]

Re : Aide sur procédure Worksheet Change

Bonjour

Target = StrConv(Target.Text, vbUpperCase) ' tout en majuscule
Target = StrConv(Target.Text, vbProperCase) ' première lettre en majuscule

ou

Target = UCase(Target.Text)
Target = Application.WorksheetFunction.Proper(Target.Text)

ce qui te donne

Private Sub Worksheet_Change(ByVal Target As Range)
 Application.ScreenUpdating = False
 If Target.Address = "$K$6" Then
 ActiveSheet.Unprotect
     Rows("16:42").Hidden = False
     Select Case Target
     Case "1/2 Journée FO"
         Rows("16:23").Hidden = True
         Rows("32:42").Hidden = True
     Case "Journée FO / TDL"
         Rows("32:42").Hidden = True
     Case "1/2 Journée TDL"
         Rows("24:42").Hidden = True
     Case "1/2 Journée FF"
         Rows("16:31").Hidden = True
     End Select
 ActiveSheet.Protect
 End If
  Application.EnableEvents = False
 If Not Intersect(Target, [D45:D54]) Is Nothing Then
  Target = StrConv(Target.Text, vbUpperCase)
   ElseIf Not Intersect(Target, [J45:J54,AG45:AG54]) Is Nothing Then
  Target = StrConv(Target.Text, vbProperCase)
End If
  Application.EnableEvents = True
 Application.ScreenUpdating = True
 End Sub

a+

 

[hypo78]

Re : Aide sur procédure Worksheet Change

Bonjour jpb,

merci pour ton code très efficace.
Bonne fin de WE.