Aide pour 2 formules-merci

[JJ1]

Bonsoir
J'ai besoin de votre aide pour 2 formules:
En G1:L1 j'ai 6 chiffres (de 0 à 9 car ce sont des unités extraites avec =droite(cellule préc))
je souhaiterais avoir 2 formules qui me renvoient 1 en :

M1 s'il y a au minimum 2 unités identiques dans les 6 cellules G1:L1

N1 s'il y a au minimum 2 unités qui se suivent (ex: 3 et 4) dans les cellules G1;L1

sinon 0

merci beaucoup et bonne nuit à tous

 

[Catrice]

Re : Aide pour 2 formules-merci

Bonsoir,

Je propose une solution dans le fichier joint.

 

[JJ1]

Re : Aide pour 2 formules-merci

Bonsoir Catrice
merci pour ta réponse rapide et ton fichier
Je l'ai un peu modifié car je souhaite uniquement 0 ou 1 en résultat quelque soit le nombre d'occurences.
j'ai réussi pour la 1ère formule, je bloque sur la 2ème...si tu as un moment (je renvoie le fichier modifié)
merci et bonne nuit

 

[Catrice]

Re : Aide pour 2 formules-merci

Re,

Ci-joint le fichier avec cette solution :
=SI(SOMMEPROD(((G1:K1+1)=H1:L1)*1)>0;1;0)

 

[JJ1]

Re : Aide pour 2 formules-merci

Merci beaucoup et bon dimanche à vous tous

 

[JJ1]

Re : Aide pour 2 formules-merci

Re,
je reviens vers toi, je n'arrive pas à faire fonctionner les 2 formules?
je joins l'exemple
merci

 

[Tibo]

Re : Aide pour 2 formules-merci

Salut JJ1,

Deux formules qui fonctionnent (mais qui peuvent être améliorées sans aucun doute) :

Contrainte : Laisser la colonne M libre

En N1 :

=(MAX(NB.SI(G1:L1;G1:L1))>1)*1

à valider en matriciel (CTRL + MAJ + ENTREE)

en O1 :

=(ESTNUM(EQUIV(1;H1:M1-G1:L1;0)))*1

à valider également en matriciel

@+

 

[Monique]

Re : Aide pour 2 formules-merci

Bonjour,

Autre solution

En M :
=(SOMMEPROD(1/NB.SI(G1:L1;G1:L1))<6)*1

Les fonctions Droite(), Gauche(), Stxt() etc renvoient du texte
En N :
=(SOMMEPROD((G1:K1+1=H1:L1+0)*1)>0)*1
+0 ou *1 ou /1 ou -0, le but : rendre numériques les valeurs en G:L

Ou simplement de G à K :
=DROITE(A1)*1

 

[Catrice]

Re : Aide pour 2 formules-merci

Bonjour,

Pour que ça fonctionne il faut que tu extrait l'unité par :
=CNUM(DROITE(A1;1))

Voir fichier joint

 

[JJ1]

Re : Aide pour 2 formules-merci

Bonjour Catrice, Monique, Tibo
Merci pour vos belles formules, effectivement =droite renvoie du texte!!(bizarre non pour un tableur?)
Ca fonctionne maintenant parfaitement-merci
Bon dimanche à tous

 

[JJ1]

Re : Aide pour 2 formules-merci

Re,
j'ai appliqué ta formule qui fonctionne.
J'ai ajouté 2 conditions, +2 et +3, voici ma nouvelle formule modifiée à partir de la tienne:
=SI(SOMMEPROD(((AD8:AH8+1)=AE8:AI8)*1)>0;1;0)+SI(SOMMEPROD(((AD8:AH8+2)=AE8:AI8)*1)>0;1;0)+SI(SOMMEPROD(((AD8:AH8+3)=AE8:AI8)*1)>0;1;0)
la formule fonctionne.
Toutefois, elle ajoute les "vrais" alors que je souhaiterais 1 si une seule des conditions +1,+2 ou +3 est remplie
et pourrait-on la simplifier pour peut être supprimer les "si"?
merci de ton aide

 

[Monique]

Re : Aide pour 2 formules-merci

Re,

Regarde si ça va :
=(SOMMEPROD((G1:K1+1=H1:L1)+(G1:K1+2=H1:L1)+(G1:K1+3=H1:L1))>0)*1

Il n'y a pas besoin de Si() somme ça :
(Formule>0)*1
(Formule>0)/1
(Formule>0)+0
(Formule>0)-0
N(Formule>0)

 

[Monique]

Re : Aide pour 2 formules-merci

Re,

Idem en plus court
=1*(SOMMEPROD((H1:L1-G1:K1>0)*(H1:L1-G1:K1<4))>0)

 

[JJ1]

Re : Aide pour 2 formules-merci

Bonsoir Monique, le Forum
Bien vu le >0 et <4, il fallait y penser!
Ma formule est vraiment raccourcie!!
tu es championne!
bonne soirée et encore merci à tous pour votre aide