Afficher les : dans une cellule (vba)

[gagnonpeter]

Bonjour,
J'ai un fichier dans le lequel j'entre des heures sans écrire les : mais j'aimerais qu'ils affichent en faisant Enter. Exemple: j'écris 1745 et en faisant Enter, 17:45 s'affiche. Comment faire?

Merci!

 

[Modeste geedee]

Re : Afficher les : dans une cellule (vba)

Bonsour®

voir cette proc événementielle pour la plage A1:A10 :

Private Sub Worksheet_Change(ByVal Target As Excel.Range)
'==================================
'http://www.cpearson.com/Excel/DateTimeEntry.htm
'==================================
 Dim TimeStr As String

 On Error GoTo EndMacro
 If Application.Intersect(Target, Range("A1:A10")) Is Nothing Then
     Exit Sub
 End If
 If Target.Cells.Count > 1 Then
     Exit Sub
 End If
 If Target.Value = "" Then
     Exit Sub
 End If

 Application.EnableEvents = False
 With Target
 If .HasFormula = False Then
     Select Case Len(.Value)
         Case 1 ' e.g., 1 = 00:01 AM
             TimeStr = "00:0" & .Value
         Case 2 ' e.g., 12 = 00:12 AM
             TimeStr = "00:" & .Value
         Case 3 ' e.g., 735 = 7:35 AM
             TimeStr = Left(.Value, 1) & ":" & _
             Right(.Value, 2)
         Case 4 ' e.g., 1234 = 12:34
             TimeStr = Left(.Value, 2) & ":" & _
             Right(.Value, 2)
         Case 5 ' e.g., 12345 = 1:23:45 NOT 12:03:45
             TimeStr = Left(.Value, 1) & ":" & _
             Mid(.Value, 2, 2) & ":" & Right(.Value, 2)
         Case 6 ' e.g., 123456 = 12:34:56
             TimeStr = Left(.Value, 2) & ":" & _
             Mid(.Value, 3, 2) & ":" & Right(.Value, 2)
         Case Else
             Err.Raise 0
     End Select
     .Value = TimeValue(TimeStr)
 End If
 End With
 Application.EnableEvents = True
 Exit Sub
 EndMacro:
 MsgBox "You did not enter a valid time"
 Application.EnableEvents = True
 End Sub

 

[gagnonpeter]

Re : Afficher les : dans une cellule (vba)

Merci c'Est gentil