Affichage conditionne

[Ilino]

Bonjour Forum
je vous solicye encore 😱
J’au un tableau qui commence de la ligne 12 et se termine ligne 33 ( ligne 11 c’est l’entete du tableau les titres) ,dans ma colonne G(fusionnée G-K) c’est une colonne des dates , je souhaite préparer un code VBA qui affiche un MsgBox si une des dates de la colonne G12 dépasse une date de référence ( cellule AQ7) alors afficher « la date Ob a dépassée la date DES »
A+

 

[Staple1600]

Re : Affichage conditionne

Bonjour à tous_______________________EDITION:Bonjour Gardien de phare


Ilino
Il faudra te conseiller combien de fois de joindre un fichier exemple pour que cela devienne un automatisme chez toi quand tu poses une question sur le forum ?

 

[Gardien de phare]

Re : Affichage conditionne

Bonjour tous et l’agrafe,
... et de reconsidérer le fait d'avoir partout des cellules fusionnées tout en continuant à vouloir gérer par Vba

 

[JCGL]

Re : Affichage conditionne

Bonjour à tous,

L'ami Ilino, peux-tu essayer :

Option Explicit

Sub Test()
Dim X%
For X = 12 To 33
If Cells(X, "G") > Range("AQ7") Then
MsgBox "La date Ob " & Cells(X, "G") & " en " & Cells(X, "G").Address & " a dépassé la date DES", vbCritical, "Information"
End If
Next X
End Sub

Comme déjà écrit, con un file, è meglio...

A+ à tous

 

[job75]

Re : Affichage conditionne

Bonjour Ilino, Jean-Marie, Gardien de phare,

@ Jean-Marie : un fichier exemple n'est vraiment pas nécessaire pour si peu...

@ Gardien de phare : toi aussi tu succombes à la phobie (courante sur XLD) des cellules fusionnées 🙄

@ Ilino : sur l'autre fil je t'ai fourni une macro Worksheet_Change, tu peux la compléter de 2 manières :

1) manière autoritaire :

Private Sub Worksheet_Change(ByVal Target As Range)
Dim c As Variant, r As Range
c = [AQ7] 'référence de date, à adapter
Set r = Intersect(Target, [G12:G33])
If r Is Nothing Then Exit Sub
For Each r In r
  If r = "" Then Union(r(1, -4), r(1, 6).Resize(, 9)) = ""
  If c <> "" And r > c Then _
    MsgBox "Date non valide en " & r.Address(0, 0) & _
      ", elle va être effacée...": r = ""
Next
End Sub

2) manière diplomatique comme les aiment les italiens :

Private Sub Worksheet_Change(ByVal Target As Range)
Dim c As Variant, r As Range
c = [AQ7] 'référence de date, à adapter
Set r = Intersect(Target, [G12:G33])
If r Is Nothing Then Exit Sub
For Each r In r
  If r = "" Then Union(r(1, -4), r(1, 6).Resize(, 9)) = ""
  If c <> "" And r > c Then _
    If MsgBox("Date non valide en " & r.Address(0, 0) & _
      ", voulez-vous l'effacer ?", 4) = 6 Then r = ""
Next
End Sub

Edit : hello Jean-Claude, heureux de te croiser 🙂

A+

 

[job75]

Re : Affichage conditionne

Re,

On peut aussi, et c'est mieux, utiliser une macro Worksheet_SelectionChange :

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
Dim d As Variant, r As Range
d = [AQ7] 'référence de date, à adapter
For Each r In [G12:G33]
  If d <> "" And r > d Then _
    If MsgBox("Date non valide en " & r.Address(0, 0) & _
      ", voulez-vous l'effacer ?", 4) = 6 Then r = ""
  If r = "" Then Union(r(1, -4), r(1, 6).Resize(, 9)) = ""
Next
End Sub

Pas besoin de tester Target, vu qu'il y a très peu de cellules traitées la macro s'exécute en quelques millièmes de seconde.

A+

 

[Ilino]

Re : Affichage conditionne

Bonjour Ilino, Jean-Marie, Gardien de phare,


2) manière diplomatique comme les aiment les italiens :

Private Sub Worksheet_Change(ByVal Target As Range)
Dim c As Variant, r As Range
c = [AQ7] 'référence de date, à adapter
Set r = Intersect(Target, [G12:G33])
If r Is Nothing Then Exit Sub
For Each r In r
  If r = "" Then Union(r(1, -4), r(1, 6).Resize(, 9)) = ""
  If c <> "" And r > c Then _
    If MsgBox("Date non valide en " & r.Address(0, 0) & _
      ", voulez-vous l'effacer ?", 4) = 6 Then r = ""
Next
End Sub

Edit : hello Jean-Claude, heureux de te croiser 🙂

A+

@ Job : Questa è la soluzione migliore.😎
@ JCGL : Sì, hai ragione.😱

In ogni caso, grazie a tutti.
A+