XL 2016 adapter une formule pour trouver le 1 er vendredi de l'année

dindin · 12 Août 2022

Bonjour le Forum,

depuis ce matin j'essaye d'adapter cette formule , en vain.
mon but est d'afficher une date sous condition :

si le premier jour de l'année tombe un vendredi ,on affiche la date de ce vendredi, sinon on affiche le premier samedi de l'année:

VB:

=SI(DATE(ANNEE(AUJOURDHUI());1;1)=DATE(ANNEE(AUJOURDHUI());1;8)-JOURSEM(DATE(ANNEE(AUJOURDHUI());1;2));DATE(ANNEE(AUJOURDHUI());1;8)-JOURSEM(DATE(ANNEE(AUJOURDHUI());1;2));DATE(ANNEE(AUJOURDHUI());1;8)-JOURSEM(DATE(ANNEE(AUJOURDHUI());1;1)))

Merci pour votre aide.

JHA · 12 Août 2022

Bonjour à tous,

Avec l'année en "A2"

VB:

=SI(JOURSEM(DATE($A$2;1;1);2)=5;DATE($A$2;1;1);DATE($A$2;1;7)-JOURSEM(DATE($A$2;1;1)-6;3))

JHA

dindin · 12 Août 2022

JHA à dit:
Bonjour à tous,

Avec l'année en "A2"

VB:

=SI(JOURSEM(DATE($A$2;1;1);2)=5;DATE($A$2;1;1);DATE($A$2;1;7)-JOURSEM(DATE($A$2;1;1)-6;3))

JHA

Bonjour JHA,
Merci pour ton aide.
je pense que je me suis mal exprimé, et je comprends maintenant pourquoi ta formule donne le même résultat que la mienne.

mon objectif est le suivant :

j'ai un évènement qui se répète tous les ans. le premier vendredi de l'année, sinon je le décale au premier samedi de l'année si le vendredi tombe en décembre.
exemple sur la photo pour 2023, la formule m'affiche samedi 7 janvier, sachant qu'il y a le vendredi 6 janvier qui tombe avant ( résultat erroné aussi pour 2023,2024 et 2025 aussi)

pour 2022 la formule donne un résultat juste, car le vendredi tombe le 31 décembre 2021:

je ne sais pas si mon explication est claire pour toi.

Après une petite modif cela fontionne:

VB:

=SI(JOURSEM(DATE($A$2;1;1);2)=5;DATE($A$2;1;1);SI(JOURSEM(DATE($A$2;1;1);2)=6;DATE($A$2;1;1);DATE($A$2;1;7)-JOURSEM(DATE($A$2;1;1)-5;3)))

Merci pour ton aide

JHA · 12 Août 2022

Bonjour à tous,

A essayer

VB:

=MIN(DATE($A$2;1;7)-JOURSEM(DATE($A$2;1;1)-5;3);DATE($A$2;1;7)-JOURSEM(DATE($A$2;1;1)-6;3))

JHA

TooFatBoy · 12 Août 2022

Bonjour,

Je vois bien que la question est déjà résolue, mais j'ai tout de même une interrogation...

Est-ce que la question pourrait être formulée ainsi :
Si le jour de l'an est un samedi alors on affiche ce samedi, sinon on affiche le premier vendredi à compter du 1er janvier.

dindin · 12 Août 2022

TooFatBoy à dit:
Bonjour,

Je vois bien que la question est déjà résolue, mais j'ai tout de même une interrogation...

Est-ce que la question pourrait être formulée ainsi :
Si le jour de l'an est un samedi alors on affiche ce samedi, sinon on affiche le premier vendredi à compter du 1er janvier.

Bonjour,

exactement ça

dindin · 12 Août 2022

JHA à dit:
Bonjour à tous,

A essayer

VB:

=MIN(DATE($A$2;1;7)-JOURSEM(DATE($A$2;1;1)-5;3);DATE($A$2;1;7)-JOURSEM(DATE($A$2;1;1)-6;3))

JHA

Merci

TooFatBoy · 13 Août 2022

Juste pour le fun :

Code:

=DATE($A$2;1;MAX(1;7-JOURSEM(DATE($A$2;1;1))))

patricktoulon · 13 Août 2022

bonjour à tous
bien vu la réduction @TooFatBoy

dommage qu'elle ne fonctionne pas pour tout les jours de semaine dans tout les mois

TooFatBoy · 13 Août 2022

patricktoulon à dit:
bien vu la réduction @TooFatBoy

Merci.
Eh oui, c'est encore moi qui ai la plus petite...

patricktoulon à dit:
dommage qu'elle ne fonctionne pas pour tout les jours de semaine dans tout les mois

Ce n'est pas ce qui était demandé.
C'est d'ailleurs probablement pour ça que la formule est courte.

XL 2016 adapter une formule pour trouver le 1 er vendredi de l'année

dindin

XLDnaute Occasionnel

JHA

XLDnaute Barbatruc

Pièces jointes

dindin

XLDnaute Occasionnel

JHA

XLDnaute Barbatruc

Pièces jointes

TooFatBoy

XLDnaute Barbatruc

dindin

XLDnaute Occasionnel

dindin

XLDnaute Occasionnel

TooFatBoy

XLDnaute Barbatruc

patricktoulon

XLDnaute Barbatruc

TooFatBoy

XLDnaute Barbatruc

Discussions similaires