Action sur 2ème double clic

[chris6999]

Bonjour

Sur double clic dans la plage A17 a192
Je souhaiterais que les colonne A à K de la ligne concernée se colorent.
Mais avec la même action (deuxième double clic) il me faudrait revenir en arrière pour supprimer le fond couleur.
J'ai essayé le CANCEL = True mais cela ne fonctionne pas.

Merci de m'aider si vous savez omment procéder.
Merci d'avance


Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)


If Intersect(Target, Range("A17:A192")) Is Nothing Then Exit Sub


Range("A" & Target.Row).Interior.Color = vbYellow
Range("B" & Target.Row).Interior.Color = vbYellow
Range("C" & Target.Row).Interior.Color = vbYellow
Range("D" & Target.Row).Interior.Color = vbYellow
Range("E" & Target.Row).Interior.Color = vbYellow
Range("F" & Target.Row).Interior.Color = vbYellow
Range("G" & Target.Row).Interior.Color = vbYellow
Range("H" & Target.Row).Interior.Color = vbYellow
Range("I" & Target.Row).Interior.Color = vbYellow
Range("J" & Target.Row).Interior.Color = vbYellow
Range("K" & Target.Row).Interior.Color = vbYellow

Cancel = True


End Sub

 

[camarchepas]

Re : Action sur 2ème double clic

Bonjour ,

Comme ceci peut être

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
 

If Intersect(Target, Range("A17:A192")) Is Nothing Then Exit Sub
 
With Range("A" & Target.Row & ":K" & Target.Row)
  If Range("A" & Target.Row).Interior.Color = vbWhite Then
    .Interior.Color = vbYellow
   Else
    .ClearFormats
  End If
End With
 

End Sub

 

[chris6999]

Re : Action sur 2ème double clic

Bonjour CAMARCHEPAS

Ca fonctionne très bien sauf que au double clic cela m'enlèvait aussi les bordures en même temps que la couleur
J'ai juste un peu rectifier le code
Merci encore

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)


If Intersect(Target, Range("A17:A192")) Is Nothing Then Exit Sub

With Range("A" & Target.Row & ":K" & Target.Row)
If Range("A" & Target.Row).Interior.Color = vbWhite Then
.Interior.Color = vbYellow
Else
.Interior.Color = vbWhite
End If
End With


End Sub

Bonjour ,

Comme ceci peut être

 

[Pierrot93]

Re : Action sur 2ème double clic

Bonjour,

une autre approche :

Option Explicit
Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
If Intersect(Target, Range("A17:A192")) Is Nothing Then Exit Sub
With Range("A" & Target.Row).Resize(, 11).Interior
    .Color = IIf(.Color = vbYellow, xlNone, vbYellow)
End With
Cancel = True
End Sub

bon après midi
@+

 

[Pierrot93]

Re : Action sur 2ème double clic

Re,

petite optimisation qui m'avait échappée... :

Option Explicit
Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
If Intersect(Target, Range("A17:A192")) Is Nothing Then Exit Sub
With Target.Resize(, 11).Interior
    .Color = IIf(.Color = vbYellow, xlNone, vbYellow)
End With
Cancel = True
End Sub

 

[chris6999]

Re : Action sur 2ème double clic

Bonjour Pierrot

Je n'avais pas vu tes 2 propositions. Je les ajoute à ma boite à outil.

Merci rncore et bonne journée.