Sub Rempli_listview()
' -- Identification des variables
Dim ws As Worksheet
Dim rg As Range
Dim i As Integer
Dim j As Integer
' -- Initialisation des variables
Set ws = ThisWorkbook.Sheets("BD") 'Nom de l'onglet contenant nos données
Set rg = ws.Range("refTab") 'Notre cellule de référence de notre tableau
' -- Construction du tableau
With ufPieces.ListView1 'Nous travaillons avec notre Listview "lvPieces" dans notre userform
' -- Ajout des colonnes
For i = 1 To 7 '7 colonnes à ajouter
'Ajouter une colonne en spécifiant le nom de l'entête seulement, largeur par défaut
'les titres sont sur la même ligne que notre référence (rg)
.ColumnHeaders.Add , , rg.Offset(0, i - 1)
Next i
' -- Ajouter les éléments de la 1re colonne
For i = 1 To 5
'Ajouter un élément en spécifiant la valeur seulement
'les éléments sont dans la même colonne que notre référence (rg)
.ListItems.Add , , rg.Offset(i, 0)
Next i
' -- Ajouter les sous-éléments
For i = 1 To 5 'Nous bouclons sur les 5 éléments (lignes)
For j = 1 To 6 'Nous bouclons sur les 6 colonnes
'Ajouter un sous-élément en spéciant la valeur seulement
.ListItems(i).ListSubItems.Add , , rg.Offset(i, j)
Next j
Next i
' -- Spécifier l'affichage du Listview en mode "Détails"
.View = lvwReport
End With
End Sub