verrouiller des feuilles du classeur en fonction de la valeur d'une cellule

[charles2b]

Bonjour à tous,
je pense que tout est indiqué dans le titre.

Dans le cadre de mon travail, je voudrais verrouiller ou même masquer certaines feuilles du classeur en fonction de la valeur d'une cellule sur la feuille1.

Si dans la cellule A1 de la feuille1 j'ai la valeur "feuille2", alors seule la feuille2 est accessible, la feuille 3,4,5 sont verrouiller (pourquoi pas avec un petit mess du style "saisie non autorisée" sur ces feuilles)

Je pense que tout cela est possible mais en VBA et je suis encore assez limité dans ce domaine (j'ai un stage de prévu par mon entreprise d'ici le moi de Juin).

En espérant que quelqu'un ai la solution à mon problème.

 

[Robert]

Re : verrouiller des feuilles du classeur en fonction de la valeur d'une cellule

Bonjour Charles, bonjour le forum,

Je te propose la macro événementielle Change ci dessous. Les onglet ne sont pas verrouillés mais masqués :

Private Sub Worksheet_Change(ByVal Target As Range)
Dim ong As Worksheet 'déclare la variable ong (ONGlet)
 
If Target.Address <> "$A$1" Then Exit Sub 'si le changement a lieu ailleurs qu'en A1, sort de la procédure
 
For Each ong In Sheets 'boucle sur tous les onglets du classeur
    If ong.Name <> "Feuil1" Then 'condition 1 : si le nom de l'onglet est différent de "Feuil1"
        If ong.Name = Target.Value Then 'condition 2 : si le nom de l'onglet est égal à la valeur de la cellule A1
            ong.Visible = xlSheetVisible 'longlet est visible
        Else 'sinon
            ong.Visible = xlSheetHidden 'longlet est masqué
        End If 'fin de la condition 2
    End If 'fin de la condition 1
Next ong 'prochain onglet du classeur
End Sub

 

[charles2b]

Re : verrouiller des feuilles du classeur en fonction de la valeur d'une cellule

Salut, merci Robert ça à l'air de correspondre à ce que je veux