Vérifier si Word est ouvert

[Pierre31]

Bonjour à toutes et tous,

Voici mon problème à partir d’Excel

1- Vérifier que l’application Word est ouverte, si elle est ouverte je copie une photo de la manière suivante :


Dim AdrIm As String, WordApp As Object
AdrIm = Sheets("ENTREE").Range("G1").Value & "\" & ListPhotos.Value
Set WordApp = GetObject(, "Word.Application")
WordApp.Selection.InlineShapes.AddPicture Filename:=AdrIm, LinkToFile:=False _
, SaveWithDocument:=True

2- Si l’application n’est pas ouverte j’ouvre un document Word non nommé puis je repasse à l’item 1

D’avance merci pour vos réponses

Cordialement
Pierre

 

[tototiti2008]

Re : Vérifier si Word est ouvert

Bonjour Pierre,

Tu veux vérifier que Word est lancé, ou qu'il y a un document ouvert dans Word, ou les deux ?

 

[Pierre31]

Re: Re : Vérifier si Word est ouvert

Bonjour Toto ... !!

Les 2 mon capitaine, si cela est possible bien sur.

Merci à toi
Bonne journée.
Cordialement
Pierre

 

[tototiti2008]

Re : Vérifier si Word est ouvert

Re,

un essai

Sub test()
Dim AdrIm As String, WordApp As Object
AdrIm = Sheets("ENTREE").Range("G1").Value & "\" & ListPhotos.Value
On Error Resume Next
Set WordApp = GetObject(, "Word.Application")
On Error GoTo 0
If WordApp Is Nothing Then
Set WordApp = CreateObject("Word.Application")
WordApp.Visible = True
End If
If WordApp.Documents.Count = 0 Then
WordApp.Documents.Add
End If
WordApp.Selection.InlineShapes.AddPicture Filename:=AdrIm, LinkToFile:=False _
, SaveWithDocument:=True
Set WordApp = Nothing
End Sub

 

[Pierre31]

Re bonjour à toi TotoTiti,
Je suis à nouveau très content de te retrouver sur mon chemin car ta réponse répond parfaitement à mon besoin.

Encore merci et bonne journée.

Très cordialement
Pierre

 

[tototiti2008]

Re : Vérifier si Word est ouvert

Re,

de rien,

il ne reste plus qu'à gérer les erreurs sur l'absence d'image dans ton userform, je suppose 😉