Verifier la forme du contenu d'un cellule (sans VBA)

Macgiy · 28 Février 2014

Bonjour à tous,

J'explique mon problème, j'ai une cellule qui contient la référence d'un dossier et je voudrais mettre en place un contrôle pour être sur que la codification de la référence soit toujours exacte (souci de la recherche rapide après)

Donc ma référence est de la forme suivante (L=lettre,C=chiffre) : LL-CC/CC-LLLL-LC

J'ai trouvé des solutions avec du VBA mais je préfère faire un contrôle simple et donc je veux savoir si il est possible de contrôler que le contenu respecte bien cette forme la

Merci d'avance

Victor21 · 28 Février 2014

Re : Verifier la forme du contenu d'un cellule (sans VBA)

Bonjour, Macgiy.

Sans VBA la formule risque d'être longue...
Un début pour contrôler la longueur de la référence, les chiffres et les caractères non alphanum :

=ET(NBCAR(A1)=17;ESTNUM(STXT(A1;4;2)*STXT(A1;7;3)*STXT(A1;17;1));STXT(A1;3;1)="-";STXT(A1;6;1)="/";STXT(A1;10;1)="-";STXT(A1;15;1)="-")

NB :les 7 caractères alphabétiques ne sont pas contrôlés dans ce premier test.

Victor21 · 28 Février 2014

Re : Verifier la forme du contenu d'un cellule (sans VBA)

Re,

Pour tester également les lettres :

=ET(NBCAR(A1)=17;
ESTNUM(STXT(A1;4;2)*STXT(A1;7;3)*STXT(A1;17;1));
STXT(A1;3;1)="-";STXT(A1;6;1)="/";STXT(A1;10;1)="-";STXT(A1;15;1)="-";
CODE(STXT(A1;1;1))>64;CODE(STXT(A1;2;1))>64;CODE(STXT(A1;11;1))>64;CODE(STXT(A1;12;1))>64;CODE(STXT(A1;13;1))>64;CODE(STXT(A1;14;1))>64;CODE(STXT(A1;16;1))>64;
CODE(STXT(A1;1;1))<123;CODE(STXT(A1;2;1))<123;CODE(STXT(A1;11;1))<123;CODE(STXT(A1;12;1))<123;CODE(STXT(A1;13;1))<123;CODE(STXT(A1;14;1))<123;CODE(STXT(A1;16;1))<123)

renvoie vrai si le n° est valide, et faux dans le cas contraire.

Mais il y a probablement plus simple : attendons la venue des spécialistes des matricielles 🙂

Macgiy · 28 Février 2014

Re : Verifier la forme du contenu d'un cellule (sans VBA)

Merci a toi Victor21 ça me convient très bien et si je comprend bien en la rallongeant un peu je peux en plus contrôler les caractères alphabétiques 🙂

Edite : Tu m'as devancé je te remercie pour avoir fini de la rallonger.

Effectivement si quelqu'un connait plus court mais moi la ça me convient en l'état c est juste pour affiché un Warning si le format n'est pas bon alors pas grave si c'est un peu long

ROGER2327 · 28 Février 2014

Re : Verifier la forme du contenu d'un cellule (sans VBA)

Bonjour à tous.

Une autre formule :

Code:

=SIERREUR(ET(CHERCHE("??-??/??-????-??";A1);
ESTNUM(-(STXT(A1;4;2)&STXT(A1;7;2)&DROITE(A1;1)));
   CODE(STXT(MAJUSCULE(A1);{1;2;10;11;12;13;15};1))>64;
98>CODE(STXT(MAJUSCULE(A1);{1;2;10;11;12;13;15};1)));
FAUX)

À valider normalement par Entrée.

ℝOGER2327
#7180

Vendredi 6 Pédale 141 (Vers Belges - fête Suprême Quarte)
10 Ventôse An CCXXII, 5,4904h - bêche
2014-W09-5T13:10:37Z

Macgiy · 28 Février 2014

Re : Verifier la forme du contenu d'un cellule (sans VBA)

Merci à vous ROGER2327 c est encore plus facile et ça marche parfaitement je viens de l'intégrer à mon excel

ROGER2327 · 28 Février 2014

Re : Verifier la forme du contenu d'un cellule (sans VBA)

Re...

Macgiy à dit:
Merci à vous ROGER2327 c est encore plus facile et ça marche parfaitement je viens de l'intégrer à mon excel

Hélas, hélas...
Je m'a gouré grave.
La formule accepte [\-00/00-]^_x-x0. Chelou !

C'est peut-être mieux avec

Code:

=SIERREUR(ET(CHERCHE("??-??/??-????-??";A1);
  CODE(STXT(A1;{4;5;7;8;16};1))>47;58>CODE(STXT(A1;{4;5;7;8;16};1));
((CODE(STXT(A1;{1;2;10;11;12;13;15};1))>64)=( 91>CODE(STXT(A1;{1;2;10;11;12;13;15};1))))+
((CODE(STXT(A1;{1;2;10;11;12;13;15};1))>96)=(123>CODE(STXT(A1;{1;2;10;11;12;13;15};1))))=1);
FAUX)

ℝOGER2327
#7181

Vendredi 6 Pédale 141 (Vers Belges - fête Suprême Quarte)
10 Ventôse An CCXXII, 6,2068h - bêche
2014-W09-5T14:53:46Z

ROGER2327 · 28 Février 2014

Re : Verifier la forme du contenu d'un cellule (sans VBA)

Suite...

Si, comme c'est souvent le cas dans les codes de référence, on n'accepte que les majuscules :

Code:

=SIERREUR(ET(CHERCHE("??-??/??-????-??";A1);
  CODE(STXT(A1;{4;5;7;8;16};1))>47;58>CODE(STXT(A1;{4;5;7;8;16};1));
((CODE(STXT(A1;{1;2;10;11;12;13;15};1))>64)=( 91>CODE(STXT(A1;{1;2;10;11;12;13;15};1))))=VRAI);
FAUX)

Si, par hasard, on ne veut que des minuscules :

Code:

=SIERREUR(ET(CHERCHE("??-??/??-????-??";A1);
  CODE(STXT(A1;{4;5;7;8;16};1))>47;58>CODE(STXT(A1;{4;5;7;8;16};1));
((CODE(STXT(A1;{1;2;10;11;12;13;15};1))>96)=(123>CODE(STXT(A1;{1;2;10;11;12;13;15};1))))=VRAI);
FAUX)

ℝOGER2327
#7182

Vendredi 6 Pédale 141 (Vers Belges - fête Suprême Quarte)
10 Ventôse An CCXXII, 6,4153h - bêche
2014-W09-5T15:23:48Z

Macgiy · 28 Février 2014

Re : Verifier la forme du contenu d'un cellule (sans VBA)

Encore merci a toi je vais prendre celui qui accepte uniquement les majuscule ça fera des références plus propres

ROGER2327 · 28 Février 2014

Re : Verifier la forme du contenu d'un cellule (sans VBA)

Re...

Macgiy à dit:
Encore merci a toi je vais prendre celui qui accepte uniquement les majuscule ça fera des références plus propres

D'accord, d'autant plus que la formule est plus simple. Mais je m'a encore gouré :
les formules acceptent des chaînes de plus de seize caractères !
Il faut ajouter une condition (Victor21 y avait pensé, lui !) :

Code:

=SIERREUR(ET(CHERCHE("??-??/??-????-??";A1);NBCAR(A1)=16;
  CODE(STXT(A1;{4;5;7;8;16};1))>47;58>CODE(STXT(A1;{4;5;7;8;16};1));
((CODE(STXT(A1;{1;2;10;11;12;13;15};1))>64)=( 91>CODE(STXT(A1;{1;2;10;11;12;13;15};1))))+
((CODE(STXT(A1;{1;2;10;11;12;13;15};1))>96)=(123>CODE(STXT(A1;{1;2;10;11;12;13;15};1))))=1);
FAUX)

Code:

=SIERREUR(ET(CHERCHE("??-??/??-????-??";A1);NBCAR(A1)=16;
  CODE(STXT(A1;{4;5;7;8;16};1))>47;58>CODE(STXT(A1;{4;5;7;8;16};1));
((CODE(STXT(A1;{1;2;10;11;12;13;15};1))>64)=(91>CODE(STXT(A1;{1;2;10;11;12;13;15};1))))=VRAI);
FAUX)

Code:

=SIERREUR(ET(CHERCHE("??-??/??-????-??";A1);NBCAR(A1)=16;
  CODE(STXT(A1;{4;5;7;8;16};1))>47;58>CODE(STXT(A1;{4;5;7;8;16};1));
((CODE(STXT(A1;{1;2;10;11;12;13;15};1))>96)=(123>CODE(STXT(A1;{1;2;10;11;12;13;15};1))))=VRAI);
FAUX)

Quand on veut aller trop vite, on ne va pas bien...

ℝOGER2327
#7183

Vendredi 6 Pédale 141 (Vers Belges - fête Suprême Quarte)
10 Ventôse An CCXXII, 6,7457h - bêche
2014-W09-5T16:11:23Z

P.s. : voir la pièce jointe au message #15.

Macgiy · 28 Février 2014

Re : Verifier la forme du contenu d'un cellule (sans VBA)

Re

L'avant dernier marche il me dit que la référence est bonne mais le dernier il me dit qu'elle est fausse. Etes-vous sur de votre dernière condition concernant la longueur de la chaîne de caractère ?

Victor21 · 28 Février 2014

Re : Verifier la forme du contenu d'un cellule (sans VBA)

Re,

NBCAR(A1)=16 signifie que le nombre total de caractères (ponctuation incluse) est 16.
N'auriez-vous pas testé la dernière proposition de notre ami perfectionniste avec des majuscules ?

Macgiy · 28 Février 2014

Re : Verifier la forme du contenu d'un cellule (sans VBA)

Ah oui si mes références sont avec des lettre majuscules, il aurait fallu écrire en minuscule ?

ROGER2327 · 28 Février 2014

Re : Verifier la forme du contenu d'un cellule (sans VBA)

Re...

Macgiy à dit:
Re

L'avant dernier marche il me dit que la référence est bonne mais le dernier il me dit qu'elle est fausse. Etes-vous sur de votre dernière condition concernant la longueur de la chaîne de caractère ?

Euh...
J'espère que je m'a pas encore gouré !
En fait, je ne comprends pas très-bien ce que vous voulez dire... Pouvez-vous fournir un exemple de ce qui coince ?
Merci d'avance !

ℝOGER2327
#7184

Vendredi 6 Pédale 141 (Vers Belges - fête Suprême Quarte)
10 Ventôse An CCXXII, 6,9907h - bêche
2014-W09-5T16:46:40Z

ROGER2327 · 28 Février 2014

Re : Verifier la forme du contenu d'un cellule (sans VBA)

Re...

Macgiy à dit:
Ah oui si mes références sont avec des lettre majuscules, il aurait fallu écrire en minuscule ?

Exemples :

[table="width: 700, class: grid"]
[tr]
[td]Données[/td]
[td]Formule "toutes lettres"
(1[SUP]ère[/SUP] formule)[/td]
[td]Formule "MAJUSCULES"
(2[SUP]ème[/SUP] formule)[/td]
[td]Formule "minuscules"
(3[SUP]ème[/SUP] formule)[/td]
[/tr]
[tr]
[td]ru-97/24-TUzE-D4[/td]
[td]VRAI[/td]
[td]FAUX
(il y a des minuscules)[/td]
[td]FAUX
(il y a des majuscules)[/td]
[/tr]
[tr]
[td]RU-97/24-TUZE-D4[/td]
[td]VRAI[/td]
[td]VRAI
(il n'y a pas de minuscule)[/td]
[td]FAUX[/td]
[/tr]
[tr]
[td]ru-97/24-tuze-d4[/td]
[td]VRAI[/td]
[td]FAUX[/td]
[td]VRAI
(il n'y a pas de majuscule)[/td]
[/tr]
[tr]
[td]ru-97/24-TUzE-D4ii[/td]
[td]FAUX
(longueur > 16 car.)[/td]
[td]FAUX[/td]
[td]FAUX[/td]
[/tr]
[/table]

Si ce n'est pas ça le problème, précisez...

ℝOGER2327
#7185

Vendredi 6 Pédale 141 (Vers Belges - fête Suprême Quarte)
10 Ventôse An CCXXII, 7,1539h - bêche
2014-W09-5T17:10:10Z

Verifier la forme du contenu d'un cellule (sans VBA)

Macgiy

Guest

Victor21

XLDnaute Barbatruc

Victor21

XLDnaute Barbatruc

Macgiy

Guest

ROGER2327

XLDnaute Barbatruc

Pièces jointes

Macgiy

Guest

ROGER2327

XLDnaute Barbatruc

Pièces jointes

ROGER2327

XLDnaute Barbatruc

Macgiy

Guest

ROGER2327

XLDnaute Barbatruc

Macgiy

Guest

Victor21

XLDnaute Barbatruc

Macgiy

Guest

ROGER2327

XLDnaute Barbatruc

ROGER2327

XLDnaute Barbatruc

Pièces jointes

Discussions similaires

Verifier la forme du contenu d'un cellule (sans VBA)

Macgiy

Guest

XLDnaute Barbatruc

XLDnaute Barbatruc

Macgiy

Guest

XLDnaute Barbatruc

Pièces jointes

Macgiy

Guest

XLDnaute Barbatruc

Pièces jointes

XLDnaute Barbatruc

Macgiy

Guest

XLDnaute Barbatruc

Macgiy

Guest

XLDnaute Barbatruc

Macgiy

Guest

XLDnaute Barbatruc

XLDnaute Barbatruc

Pièces jointes

Discussions similaires

Privacy & Transparency

Privacy & Transparency