VBA Vlookup

[FreeKc]

Bonjour,

J'essaie d'appliquer un Vlookup en VBA, mais celui-ci me retourne soit rien, soit une erreur 1004 que je n'arrive pas à contourner.

Je souhaite effectuer une recherche des valeurs de la sheet tampon dans celle de la sheet réact et placer le retour dans la colonne O de la sheet tampon.

Le code utilisé est le suivant :

Public Sub MyGetData()  
    
    Dim Derligne, Derligne2 As Long
    Dim Dept_Row As Long
    Dim Dept_Clm As Long
                   
    Derligne = Sheets("Tampon").Range("A" & Rows.count).End(xlUp).Row
    Derligne2 = Sheets("Réact").Range("C" & Rows.count).End(xlUp).Row
    
    On Error Resume Next
     
    Table1 = Sheets("Tampon").Range("A2:" & Derligne) ' BP avec Créance
    Table2 = Sheets("Réact").Range("B4:" & Derligne2) ' BP des réactivatons
    Dept_Row = Sheets("Tampon").Range("O2").Row ' Change O2 avec la réact
    Dept_Clm = Sheets("Tampon").Range("O2").Column
       
        
   For Each cl In Table1
        
        Sheets("Tampon").Cells(Dept_Row, Dept_Clm) = Application.VLookup(cl, Table2, 2, False)
        Dept_Row = Dept_Row + 1
        
    Next cl
            
   'Message de clôture
    
    MsgBox ("MàJ finalisée")
    
End Sub

Je joins également le fichier "Test".

Merci d'avance de votre aide,
FreeKc

 

[DoubleZero]

Re : VBA Vlookup

Bonjour, FreeKc, le Forum,

Peut-être ainsi ?

Option Explicit
Sub La_date()
    Dim c As Range, quand
    With Application: .ScreenUpdating = False: .Calculation = xlManual: .EnableEvents = False: End With
    For Each c In Sheets("Tampon").Range("a2:a" & Rows.Count).SpecialCells(xlCellTypeConstants, 23)
        Set quand = Sheets("Réact").Range("b:b").Find(c.Value, LookIn:=xlValues, LookAt:=xlWhole)
        If Not quand Is Nothing Then c.Offset(, 14).Value = quand.Offset(, 1)
    Next
    With Application: .EnableEvents = True: .Calculation = xlAutomatic: .ScreenUpdating = True: End With
End Sub

A bientôt 🙂

 

[FreeKc]

Re : VBA Vlookup

Bonsoir DoubleZero,

Un mot : PARFAIT !

Un tout grand merci et dire que j'ai passé quelques heures pour obtenir ce résultat.

Bonne soirée et bon week-end,
Freekc