VBA qu'est-ce qui cloche dans mon code

Softmama à dit:

Bonsoir,

Je suis navré, mais je peine à comprendre ce que tu demandes. T'est-il possible de me mettre ds un fichier joint un exemple de tes 2 feuilles avec ce que tu souhaiterais avoir comme résultat ?

Cliquez pour agrandir...

Arpette à dit:

Bonjour Softmama, voici un fichier qui représente mon souhait. Dans la feuille 5-9-12, j'ai des valeurs sur colonne B ( elles sont uniques). Sur la Feuille 5-17, je retrouve ou pas ces valeurs. Le problème c'est que dans cette feuille je peux les avoir plusieurs fois. Dans ce cas je souhaite renvoyer la somme de K13 et K15 dans la cellule F8 de la feuille 5-9-12 et si la valeur n'est pas trouvée on renvoi 0. En jaune un cas bien concret. J'essaie de faire une boucle avec une rechercheV. Tant que la valeur est trouvée je cumule, quand la recherche est terminée je pose le résultat et je passe à la valeur suivante. Facile à dire, mais pas facile à écrire.
Merci de ton aide.

Cliquez pour agrandir...

Softmama à dit:

Bonjour Arpette,

comme promis, le code que tu attendais. Tu n'étais pas loin de la solution. J'ai préféré utiliser un .find au lieu de boucler sur toutes les cellules de la 2ème feuille : tu gagneras beaucoup de temps si tu traites bcp de cellules.

cf. fichier joint.

VB:

Sub testV2()
Dim Départ As String
Dim c As Range
Dim d As Range
Dim Somme&
For Each c In Worksheets("5-9-12").Range("B2:B" & Worksheets("5-9-12").Range("B65536").End(xlUp).Row)
Somme& = 0
With Worksheets("5-17").Range("F2:F" & Worksheets("5-17").Range("F65536").End(xlUp).Row)
    Set d = .Find(c)
        If Not d Is Nothing Then
            Départ = d.Address
            Do
                Somme& = d(1, 6) + Somme&
                Set d = .FindNext(d)
        Loop While Not d Is Nothing And d.Address <> Départ
        End If
End With
c(1, 5) = Somme&
Next
End Sub

Cliquez pour agrandir...

Softmama à dit:

Bonsoir,

Voici les modifs ici :

VB:

Sub testV2()
Dim Départ As String
Dim c As Range
Dim d As Range
Dim Somme&
Set c = Worksheets("5-9-12").Range("B" & Worksheets("5-9-12").Range("B65536").End(xlUp).Row)
Do While c.Row > 1
Somme& = 0
With Worksheets("5-17").Range("F2:F" & Worksheets("5-17").Range("F65536").End(xlUp).Row)
    Set d = .Find(c)
        If Not d Is Nothing Then
            Départ = d.Address
            Do
                Somme& = d(1, 6) + Somme&
                c(2, 1).EntireRow.Insert
                c(2, 1) = d(1, 2)
                c(2, 2) = d(1, 5)
                c(2, 5) = d(1, 6)
                Set d = .FindNext(d)
        Loop While Not d Is Nothing And d.Address <> Départ
        End If
End With
c(1, 5) = Somme&
Set c = c(0, 1)
Loop
End Sub

Je ne sais pas si tu veux les données ainsi, détaille mieux ta demande pour savoir ce que tu veux que je conserve dans les lignes rajoutées.

Cliquez pour agrandir...