XL 2016 VBA ListView UserForm - Help !

[Dudu2]

Bonjour,

Je suis paumé avec les ListView.
Je voudrais 1 colonne et j'en ai 2 !

    With ListView
        .ListItems.Clear
        .FullRowSelect = True
        .Gridlines = True
        .HideColumnHeaders = True
        For i = LBound(TabValues) To UBound(TabValues)
            .ListItems.Add i, , TabValues(i)
        Next i
    End With

 

[Gégé-45550]

A mon avis la sélection fonctionne mais c'est l'affichage de ou des éléments sélectionnés qui ne fonctionne pas. Il semblerait que la propriété HideSelection pose des problèmes. Essayer ce code après sélection :

car même si la propriété est déjà à Faux avant , chez moi cela me remet l'affichage des sélections.

Pour connaître l'index de l'item sélectionné appelons-le ind :

ind = ListView1.SelectedItem.index

puis, pour adresser l'item en question :

ListView1.ListItems(ind)

Puis pour les colonnes :

ListView1.ListItems(ind).SubItems(i)

Mille excuses

 

[Dudu2]

J'ai le .MultiSelect = True pas de souci.

@nullosse, cette instruction .HideSelection = False a fait progresser l'affaire de sélection mais bizarrement ça sélectionne en gris !
Quand je sélectionne au tout début du chargement de la ListView, ça sélectionne en bleu.

Et en gris, ça reconnait bien les items comme étant sélectionnés.

 

[ChTi160]

Re
ceci doit fonctionner

With Me.ListView1
    .MultiSelect = True
    .HideSelection = False
    .View = lvwReport
    .SetFocus
    For i = 1 To 3
            .ListItems(i).Selected = True
    Next
End With

Jean marie

 

[Dudu2]

@ChTi160,
Je fais ça mais ça sélectionne en gris, pas en bleu !

 

[ChTi160]

Re
a tu donné le Focus a la Listview Voir modif :

With Me.ListView1
    .MultiSelect = True
    .HideSelection = False
    .View = lvwReport
    .SetFocus
    For i = 1 To 3
            .ListItems(i).Selected = True
    Next
End With

jean marie

 

[Dudu2]

Ok @ChTi160, c'est bien le Focus !

 

[TooFatBoy]

Hello, je n'arrive pas à DL le classeur anonymisé représentatif. 🙁


Comment passe-t-on de ça :

à ça :

?

 

[Dudu2]

@TooFatBoy,
Pas compris "DL". Tu veux un classeur ?
En l'occurrence c'est bien trop complexe pour le placer en exemple.
En plus c'est un développement pour un "utilisateur" et je ne peux pas le rendre public.

Et Merci à vous tous pour m'avoir initié aux arcanes des ListViews.

 

[TooFatBoy]

A défaut de donner un classeur, la bonne syntaxe parmi toutes celles proposées aurait été bien.
Et on aurait aussi peut-être pu savoir ce qu'il y avait en gros dans "TabValues" (par exemple, est-ce un tableau à une seule dimension ?).

Tout ça m'aurait permi de pouvoir suivre le fil de discussion et apprendre des choses sur les ListView.

 

[Dudu2]

Je vais te dire ce que j'ai appris grâce aux colistiers.

• A l'initialisation, il semble que la ListView ait 2 colonnes par défaut, alors voilà comment je l'initialise pour une colonne unique sans titres de colonnes et pour avoir les Scroll Bars (H & V) automatiquement si ça déborde ( .FlatScrollBar = False):
  

     With Me.ListView        .FullRowSelect = True
          .Gridlines = False
          .ColumnHeaders.Add , , "Colonne", .Width - 4
          .HideColumnHeaders = True
          .View = lvwReport
          .MultiSelect = True
          .FlatScrollBar = False
      End With

  
  
• Au chargement initial, le 1er item est sélectioné par défaut, alors il faut ajouter:
  

  ListView.ListItems(1).Selected = False

  
  
• Pour sélectionner des items via le VBA, pour avoir l'affichage des items sélectionnés, il faut préalablement faire:
  

  With ListView
      .HideSelection = False
      .SetFocus
  End ListView

  
  Ensuite on peut valoriser les items sélectionnés:
  

  For i = 1 To .ListItems.Count
      If <Condition> Then ListView.ListItems(i).Selected = True
  Next i

  
  
• La valeur d'un item se récupère ou se définit via:
  

  ValeurItem = ListView.ListItems(i).Text

  
  
• L'item cliqué (sa ligne) se récupère avec:
  

  Private Sub ListView_Click()
      IndexItemCliqué = Me.ListView.SelectedItem.Index
  End Sub

  ou bien:
  

  Private Sub ListView_MouseUp(ByVal Button As Integer, ByVal Shift As Integer, ByVal x As stdole.OLE_XPOS_PIXELS, ByVal y As stdole.OLE_YPOS_PIXELS)
      IndexItemCliqué = Me.ListView.SelectedItem.Index
  End Sub

  
  
• Les items d'une ListView sont éditables et si l'on veut l'empêcher pour que ça se comporte comme une ListBox il faut gérer l'évènement:
  

  Private Sub ListView_BeforeLabelEdit(Cancel As Integer)
      Cancel = True
  End Sub

Voilà, ça m'a permis de gérer mes ListViews.

Edit: Après on peut avoir du multicolonnes qui se gère avec les SubItems, par exemple:

For i = 1 To UBound(T, 1)
    .ListItems.Add , , T(i, 1)
    For j = 2 To UBound(T, 2)
        .ListItems(i).ListSubItems.Add , , T(i, j)
    Next j
Next i

Edit: En cliquant sur un item on le sélectionne s'il n'est pas sélectionné.
Par contre s'il est sélectionné, il reste sélectionné.
Pour désélectionner un item sélectionné c'est un peu complexe.
Voici le code:

Private TabListViewSelected() As Boolean

'----------------------
'MouseDown sur ListView
'----------------------
Private Sub ListView_MouseDown(ByVal Button As Integer, ByVal Shift As Integer, ByVal x As stdole.OLE_XPOS_PIXELS, ByVal y As stdole.OLE_YPOS_PIXELS)
    Call MouseDown(Me.ListView)
End Sub

'--------------------
'MouseUp sur ListView
'--------------------
Private Sub ListView_MouseUp(ByVal Button As Integer, ByVal Shift As Integer, ByVal x As stdole.OLE_XPOS_PIXELS, ByVal y As stdole.OLE_YPOS_PIXELS)
     Call MouseUp(Me.ListView)
End Sub

'----------------------
'MouseDown sur ListView
'----------------------
Private Sub MouseDown(ListView As ListView)
    Dim i As Integer
 
    Erase TabListViewSelected
 
    With ListView
        If .ListItems.Count > 0 Then
            'Mémorise l'état de sélection des items avant leur éventuel changement d'état de sélection
            ReDim TabListViewSelected(1 To .ListItems.Count)
    
            For i = 1 To .ListItems.Count
                TabListViewSelected(i) = .ListItems(i).Selected
            Next i
        End If
    End With
End Sub

'--------------------
'MouseUp sur ListView
'--------------------
Private Sub MouseUp(ListView As ListView)
     Dim i As Integer
     Dim SelectedItem As Integer

     With ListView
        'La table de l'état de sélection des Items n'est pas vide
        If Not (Not TabListViewSelected) Then
        
            'Item cliqué
            SelectedItem = .SelectedItem.Index
        
            'L'item cliqué etait sélectionné
            If TabListViewSelected(SelectedItem) Then
            
                'Le désélectionner en table
                TabListViewSelected(SelectedItem) = False
                .HideSelection = False
                
                'Cette instruction désélectionne tout !!!???
                '.ListItems(.SelectedItem.Index).Selected = False
                
                'Cette boucle positionne la liste à la fin
                For i = 1 To .ListItems.Count
                    .ListItems(i).Selected = TabListViewSelected(i)
                Next i
                
                'Boucle nécessaire pour repositionner la liste
                For i = .ListItems.Count To SelectedItem Step -1
                    .ListItems(i).Selected = TabListViewSelected(i)
                Next i
            End If
        End If
    End With
End Sub

 

[Dudu2]

Bonjour la liste,

Pour info, suite au développement du code j'ai ajouté des infos utiles dans le Post #25:
- ScrollBars
- Prévention de l'édition des items
- Item cliqué
- Dé-sélection unitaire