XL 2019 VBA & Find plus leger

[sebastien450]

Bonjour,
J'utilise depuis longtemps cette trame de find mais qui est lourde à insérer car parfois imbriquée plusieurs fois,
Avez-vous une piste pour alléger, la difficulté étant une recherche qui ne s'arrête pas au premier objet trouvé!

Set plage = Range(Cells(6, R2 - 48), Cells(213, R2 + 100)) ' sur ma plage de R2-48h à R2 +1000
                                                          With plage 'defini le range de travail, qui va devenir variable
                                                            Set c = .Find("CIBLE", LookIn:=xlValues, lookat:=False)
                                                            If Not c Is Nothing Then
                                                                Add1 = c.Address
                                                              Do
                                                                    'MsgBox c.Row & c.Column
                                                                Set c = .FindNext(c)
                                                              Loop While Not c Is Nothing And c.Address <> Add1
                                                            End If
                                                          End With

Merci

Sébastien

 

[job75]

Bonjour sebastien450, le forum,

En effet la méthode Find n'est pas très rapide, il vaut mieux utiliser un tableau VBA (matrice) :

Set plage = Range(Cells(6, R2 - 48), Cells(213, R2 + 100))
ncol = plage.Columns.Count
tablo = plage 'matrice, plusrapide
For i = 1 To UBound(tablo)
    For j = 1 To ncol
        If UCase(tablo(i, j)) = "CIBLE" Then
            'code si la valeur est trouvée
        End If
Next j, i

Nota : ici R2 est une variable, si c'est une cellule la remplacer par [R2]

Edit : pour une recherche partielle utiliser If UCase(tablo(i, j)) Like "*CIBLE*" Then

A+

 

[sebastien450]

Bonjour,
Merci,
Mais je ne trouve pas comment récupérer l'adresse, car du coup la position est relative.
J'essaye d'afficher à coup de cells(i,j).value mais rien ne remonte proprement...

 

[job75]

Mais je ne trouve pas comment récupérer l'adresse, car du coup la position est relative.

Une adresse c'est une adresse :

Set plage = Range(Cells(6, R2 - 48), Cells(213, R2 + 100))
ncol = plage.Columns.Count
tablo = plage 'matrice, plusrapide
For i = 1 To UBound(tablo)
    For j = 1 To ncol
        If UCase(tablo(i, j)) = "CIBLE" Then mes = mes & " - " & plage(i, j).Address(0, 0)
Next j, i
MsgBox "'CIBLE' " & IIf(mes = "", "non trouvé", "trouvé en " & Mid(mes, 4))