XL 2016 VBA dernière cellule vide.

'----------------------------------------------------------------------
'Calcul de la dernière ligne non vide d'une colonne avec fonction Match
'Colonne: numéro ou lettre
'----------------------------------------------------------------------
Function MatchDernièreLigneEnColonne(ByVal Feuille As Worksheet, ByVal Colonne As Variant) As Long
    Const ChaineMax As String = "zzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzz"
    Const NombreMax As Double = (2 ^ 53 - 1) * 2 ^ 971
    Dim RngColonne As Range
    Dim RngErrors As Range
    Dim ErrorLine As Long
    Dim xlCellType As Integer
 
    Set RngColonne = Feuille.Columns(Colonne)
    
    xlCellType = xlCellTypeFormulas
    GoSub GetErrorLine
    
    xlCellType = xlCellTypeConstants
    GoSub GetErrorLine
 
    With Application
        MatchDernièreLigneEnColonne = .Max(.IfError(.Match(ChaineMax, RngColonne, 1), 0), _
                                           .IfError(.Match(NombreMax, RngColonne, 1), 0), _
                                           ErrorLine)
    End With
    Exit Function

GetErrorLine:
    On Error Resume Next
    Set RngErrors = RngColonne.SpecialCells(xlCellType, xlErrors)
    If Err.Number = 0 Then
        Set RngErrors = RngErrors.Areas(RngErrors.Areas.Count)
        ErrorLine = Application.Max(ErrorLine, RngErrors.Cells(RngErrors.Cells.Count).Row)
    End If
    On Error GoTo 0
    Return
End Function

'---------------------------------------------
'Dernière ligne d'une colonne par SpecialCells
'Colonne: numéro ou lettre
'---------------------------------------------
Function SpecialCellsDernièreLigneEnColonne(ByVal Feuille As Worksheet, ByVal Colonne As Variant)
    Dim DernièreLigne As Long
    Dim WorkbookSavedAtCallTime As Boolean
    Dim TabxlCellType() As Variant
    Dim i As Integer
  
    WorkbookSavedAtCallTime = Feuille.Parent.Saved
    TabxlCellType = Array(xlCellTypeFormulas, xlCellTypeConstants)
  
    For i = LBound(TabxlCellType) To UBound(TabxlCellType)
        On Error Resume Next
        With Feuille.Columns(Colonne).SpecialCells(TabxlCellType(i))
            If Err.Number = 0 Then DernièreLigne = Application.Max(DernièreLigne, .Areas(.Areas.Count).Cells(.Areas(.Areas.Count).Rows.Count).Row)
        End With
        On Error GoTo 0
    Next i
  
    SpecialCellsDernièreLigneEnColonne = DernièreLigne
    Feuille.Parent.Saved = WorkbookSavedAtCallTime
End Function