XL 2010 VBA - Contrainte lettre + chiffre

[brunos31]

Bonjour,

Je cherche à simplifier mes lignes de codes et surtout à parer à toutes nouvelles éventualité.
Dans une colonne j'ai plusieurs référence, la seule que je veux garder est celle aui commence par la lettre "E" suivi d'un numéros.
De base je me suis dit que juste un

IF left(####, 1) = "E" And IsNumeric (Mid(####, 2, 1)) = true then

Suffirait mais cela ne marche pas.... Trop simple je sais pas lol.
Pour le moment j'utilise ce code:

 With ThisWorkbook.Sheets("Feuil1")
            For i = .Range("A" & .Rows.Count).End(xlUp).Row To 2 Step -1

                        If .Range("A" & i) Like "A*" Then
                                   .Rows(i).Delete
                        End If
            Next i
 End With

Sauf que j'ai du prendre en compte toutes les variables, et je viens de m'apercevoir que si la lettre A est en minuscule, il le prend pas, du coup je dois tout anticiper ce qui alourdi le code...

Mon but serait juste de dire, si sur une cellule, la première lettre est "E" et suivi par un chiffre je garde cette ligne et supprime tout le reste.

Je pensais être proche de la réflexion, mais au vu des tests j'en suis loin.
Si vous avez des idées je suis preneur ^^

Merci pour vos lumières.
Bruno

 

[job75]

Bonsoir brunos31,

Voyez le fichier joint et la macro affectée au bouton :

Sub test()
Dim tablo, i&, x$, n&
tablo = Sheets("Feuil1").[A1].CurrentRegion.Resize(, 2) 'matrice, plus rapide, au moins 2 éléments
For i = 2 To UBound(tablo)
    x = tablo(i, 1)
    If x Like "E" & String(Len(x) - 1, "#") Then
        n = n + 1
        tablo(n, 1) = x
    End If
Next
'---restitution---
With Sheets("Save")
    If .FilterMode Then .ShowAllData 'si la feuille est filtrée
    If n Then .[A2].Resize(n) = tablo
    .[A2].Offset(n).Resize(.Rows.Count - n - 1).ClearContents 'RAZ en dessous
    With .UsedRange: End With 'actualise la barre de défilement verticale
    .Activate 'facultatif
End With
End Sub

A+

 

[brunos31]

Merci pour ton retour, c'est parfait, je regarde cette approche pour mieux comprendre et apprendre lol.

 

[patricktoulon]

bonsoir @job75 , @brunos31
le motif du like pourrait être simplifié
exemple

Sub test()
MsgBox "a22" Like "[E,e0-9]*"
MsgBox "e22" Like "[E-e][0-9]*" ' le bon
MsgBox "ee22" Like "[E-e][0-9]*"
End Sub

 

[job75]

Bonjour brunos31, patricktoulon,

Bien sûr si on s'intéresse uniquement aux 2 premiers caractères de la chaîne voyez ce fichier (2) :

For i = 2 To UBound(tablo)
    If UCase(tablo(i, 1)) Like "E#*" Then
        n = n + 1
        tablo(n, 1) = tablo(i, 1)
    End If
Next

La lettre minuscule "e" est acceptée grâce à UCase.

A+

 

[brunos31]

Yes parfait merci, c'est nickel, merci de votre aide