Validation sans doublons

Sub Macro1()
Dim O As Object 'déclare la variable O (Onglet)
Dim DL As Long 'déclare la variable DL (Dernière Ligne)
Dim PL As Range 'déclare la variable PL (PLage)
Dim CEL As Range 'déclare la variable CEL (CELlule)
Dim D As Object 'déclare la variable D (Dictionnaire)
Dim TEMP As Variant 'déclare la variable TEMP (tableau TEMPoraire)
Dim Liste As String 'déclare la variable Liste (Liste de validation)

Set O = Sheets("REF") 'définit l'onglet O
DL = O.Cells(Application.Rows.Count, 1).End(xlUp).Row 'définit la dernière ligne éditée DL de la colonne 1 (=A) de l'onglet O
Set PL = O.Range("A2:A" & DL) 'définit la plage PL
Set D = CreateObject("Scripting.Dictionary") 'définit le dictionnaire D
For Each CEL In PL 'boucle sur toutes les cellules CEL de la plage PL
    D(CEL.Value) = "" 'alimente le dictionnaire D
Next CEL 'prochaine cellule de la boucle
TEMP = D.keys 'récupèr dans le tableau temporaire TEMP les données sans doublon
Call Tri(TEMP, LBound(TEMP), UBound(TEMP)) 'tri alphabétique du tableau TEMP
Liste = Join(TEMP, ",") 'définit la liste Liste en plaçant une virgule enrte chaque donnée
With Sheets("Validation").Range("A1").Validation 'prend en compte la validation de la cellule A1 de l'onglet "Validation"
    .Delete 'efface une éventuelle ancienne validation de données
    .Add Type:=xlValidateList, AlertStyle:=xlValidAlertStop, Operator:=xlBetween, Formula1:=Liste 'attribue la variable Liste comme liste de validation de données
End With 'fin de la prose en compte de...
End Sub

Sub Tri(a As Variant, gauc As Integer, droi As Integer) ' Quick sort tiré du site de Jacques BOISGONTIER : http://boisgontierjacques.free.fr/
Dim ref As String
Dim g As Integer: Dim D As Integer
Dim tmp As String

ref = a((gauc + droi) \ 2)
g = gauc: D = droi
Do
    Do While a(g) < ref: g = g + 1: Loop
    Do While ref < a(D): D = D - 1: Loop
    If g <= D Then
        tmp = a(g): a(g) = a(D): a(D) = tmp
        g = g + 1: D = D - 1
    End If
Loop While g <= D
If g < droi Then Call Tri(a, g, droi)
If gauc < D Then Call Tri(a, gauc, D)
End Sub

Private Sub Workbook_Open() 'à l'ouverture du classeur
Module1.Macro1 'lance la procédure "Macro1" du module "Module1"
End Sub

Private Sub Worksheet_Change(ByVal Target As Range)
'si le chagement a lieu dans la colonne 1 (=A), lance la procédure "Macro1" du module "Module1"
If Target.Column = 1 Then Module1.Macro1
End Sub

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
   If Target.Address = "$A$1" Then
     Set d = CreateObject("Scripting.Dictionary")
     For Each c In [Localisation]: d(c.Value) = "": Next c
     Target.Validation.Delete
     Target.Validation.Add xlValidateList, Formula1:=Join(d.keys, ",")
   End If
 End Sub

Option Explicit
Dim D As Dictionary

Private Sub UserForm_Initialize()
Set D = DictionnArbo(Feuil2.[Champ])
CbxVille.List = D.Keys
Me.Left = 10: Me.Top = 75
End Sub

Private Sub CbxVille_Change()
Dim Lignes() As Long, N As Long, L As Long, ECodes(), SCodes()
If CbxVille.ListIndex > -1 Then
   Feuil1.Rows(1).ClearContents
   Feuil1.[A1].Value = CbxVille.Text
   SCodes = D.Items(CbxVille.ListIndex).Keys
   Feuil1.[B1].Resize(, UBound(SCodes) + 1).Value = SCodes
   End If
End Sub