Valeur dune cellule d'apres deux autres colonnnes

[XGuarden]

MErci poru votre aide.

Voici une explication de ce que je fait..
J'ai trois colonne

La colonne NomEleveGarde garde
La colonne SemaineGarde
La colonnne PayePar (Père ou Mère)

Il ne peut y avoir deux paiement par semaine pour un éleve...
Ni deux garde pour un éleve la meme semaine.

Je veut simplement récupéré qui a payer pour faire garder l'Enfant a partir de la semaine et du nom de l'éleve.

J'ai une formule pour le faire mais elle ne fonctionne pas corectement. La voici:

=SI($B7='';'';SOMME(SI(ET(NomEleveGarde=$B7;PayePar='Mère');GrandTotal)))

ICI un equivalent mais contien des colonne suplémentaire et calcul le nombre plutot
=SI($B6='';'';NB(SI(ET(NomEleveGarde=$B6;PayePar='Mère');GardeLundi);SI(ET(NomEleveGarde=$B6;PayePar='Mère');GardeMardi);SI(ET(NomEleveGarde=$B6;PayePar='Mère');GardeMercredi);SI(ET(NomEleveGarde=$B6;PayePar='Mère');GardeJeudi);SI(ET(NomEleveGarde=$B6;PayePar='Mère');GardeVendredi)))

Pourquoi sa ne fonctionne pas.

 

[XGuarden]

Re:Valeur dune cellule d'apres deux autres colonnn

En aucun cas je peu pogner en desou de 50 k meme en enlevant presque tout...

 

[XGuarden]

Re:Valeur dune cellule d'apres deux autres colonnn

Merci beaucoup pour le truc de F9 , ya moyen de le parametrer pour qu'il recalcul tout de meme la forme active?

 

[Monique]

Re:Valeur dune cellule d'apres deux autres colonnn

Re,

Une formule que tu valides est calculée ou recalculée.
Pas les autres.
Paramétrer, je ne sais pas

 

[XGuarden]

Re:Valeur dune cellule d'apres deux autres colonnn

Il me reste un gros probleme a résoudre

=SI($B6='';'';NB(SI(ET(NomEleveGarde=$B6;PayePar='Mère');GardeLundi);SI(ET(NomEleveGarde=$B6;PayePar='Mère');GardeMardi);SI(ET(NomEleveGarde=$B6;PayePar='Mère');GardeMercredi);SI(ET(NomEleveGarde=$B6;PayePar='Mère');GardeJeudi);SI(ET(NomEleveGarde=$B6;PayePar='Mère');GardeVendredi)))

Cette formule me retourne toujours 5
pourquoi?

 

[Monique]

Re:Valeur dune cellule d'apres deux autres colonnn

Re,

A essayer (tu remplaces A8 par ta référence):
=SOMMEPROD((NomEleveGarde=A8)*(PayePar='Mère')*((GardeLundi>0)+(GardeMardi>0)+(GardeMercredi>0)+(GardeJeudi>0)+(GardeVendredi>0)))

Et voilà l'intérêt des 5 plages à nommer ('Garde5Jours' par exemple)
=SOMMEPROD((NomEleveGarde=A8)*(PayePar='Mère')*(Garde5Jours>0))

Pour la formule qui te renvoie toujours 5
Tu prends une seule partie de ta formule :
=(SI(ET(NomEleveGarde=$A$8;PayePar='Mère');GardeLundi))
Elle te renvoie FAUX

Tu tapes :
=NB(FAUX;FAUX;FAUX;FAUX;FAUX)
ça te donne 5

 

[XGuarden]

Re:Valeur dune cellule d'apres deux autres colonnn

Merci, la premeire formule fonctione tres bien.
Je n'utilise par contre pas Garde5Jours par peur de ralentir le programme vue que j'ai déja chacun des jours en tableau... Dit le moi si je me trompe...

Sa fonctionne tres bien pour faire le NB
mais si je veut faire la somme?

Exemple
=SOMME(SI(ET(NomEleveGarde=$B6;PayePar='Mère');GrandTotal))
Ne fonctionne pas non plus lol


J'avoue ne pas avoir compris la deuxieme partie de ton explication.

 

[Monique]

Re:Valeur dune cellule d'apres deux autres colonnn

Re,

La somme :
=SOMMEPROD((NomEleveGarde=A8)*(PayePar='Mère')*(GardeLundi+GardeMardi+GardeMercredi+GardeJeudi+GardeVendredi))

ou bien :
=SOMMEPROD((NomEleveGarde=A8)*(PayePar='Mère')*Garde5Jours)

Tu devrais nommer les 5 plages ensemble

La tienne fonctionne comme ça, validée en matriciel :
=SOMME(SI(NomEleveGarde=A8;SI(PayePar='Mère';Garde5Jours)))
=SOMME(SI((NomEleveGarde=A8)*(PayePar='Mère');Garde5Jours))

Le * équivaut au ET et le + au OU, si on veut

Pour le message précédent
Tu tapes :
=NB(FAUX;FAUX;FAUX;FAUX;FAUX)
ça te donne 5
FAUX équivaut à 0

Tu tapes :
=NB(0;0;0;0;0)
ça te donne 5,
5 fois le nombre 0