Valeur du jour pour lequel le max est atteint

[Dogde]

Bonjour!

Dans ma feuille Excel, j'ai deux colonnes: la 1ere avec des jours et la seconde avec des valeurs.
J'essaie de creer une macro qui permet de demander pour quel jour le maximum des valeurs de la colonne B est atteint (seulement pour les 6 premiers mois).

J'ai code mais je ne comprend pas pourquoi la valeur du jour retourne est en fait la derniere valeur de mon compteur et non pas celle du max.

Quelqu'un pourrait me dire ce qui ne va pas ?

Code:

Sub days()

Dim j As Integer, k As Integer

For j = 2 To 182
    For k = j To 182
        If Worksheets("Sheet1").Range("B" & j).Value >= Worksheets("Sheet1").Range("B" & k).Value Then
            Worksheets("Sheet1").Range("D" & 1) = Worksheets("Sheet1").Range("A" & k).Value
        End If
    Next k
Next j


End Sub

Mon fichier est en piece jointe.

 

[GIBI]

Re : Valeur du jour pour lequel le max est atteint

Bonjour,

si tu veux détecter la plus grande valeur c'est plus simple :

Sub days()

Dim j As Long

Dim Maxi

For j = 2 To Worksheets("Sheet1").Range("B100000").End(xlUp).Row
  If Worksheets("Sheet1").Range("B" & j).Value >= Maxi Then
            Maxi = Worksheets("Sheet1").Range("B" & j).Value
            Worksheets("Sheet1").Range("D" & 1) = Worksheets("Sheet1").Range("A" & j).Value
  End If
Next j


End Sub

Remarque : la formule {=MAX(SI(B2:B341=MAX(B2:B400);LIGNE(B2:B341)-1;""))} à valider avec Ctrl+Shift+entrée donne le même résultat

 

[Legolas]

Re : Valeur du jour pour lequel le max est atteint

Bonjour,

Pour détecter le jour ayant la plus grande valeur :

Sub days()

Dim j As Integer

Max = Cells(2, 2)

For j = 2 To 182
    If Cells(j, 2) >= Max Then
        Max = Cells(j, 2)
        Cells(1, 4) = Cells(j, 1)
    End If
Next j


End Sub

A plus

 

[Robert]

Re : Valeur du jour pour lequel le max est atteint

Bonjour Dodge, bonjour le forum,

Peut-être comme ça :

Sub days()
Dim pl As Range 'déclare la variable pl (PLage)
Dim r As Range 'déclare la variable R (Recherche)

Set pl = Range("B2:B182") 'définit la plage pl
Set r = pl.Find(Application.WorksheetFunction.Max(pl), , xlFormulas, xlWhole) 'définit la recherche r (recherche la valeur maximale dans la plage pl)
Range("D1").Value = r.Offset(0, -1) 'place en D1 le jour de l'occurrence touvée
End Sub

 

[Dogde]

Re : Valeur du jour pour lequel le max est atteint

En effet, vos solutions sont bien plus simples!

Merci a vous!